访问父项值中包含的项的属性

Question

是否可以访问另一个项目的属性中存在的项目的值。例如，对于Matterhorn。有一个属性“重大事件” P793。该属性的值是项目“首次上升” Q1194369，其属性为“时间点” P585和“参与者” P710。

我希望能够返回这些山峰的值，但是我不知道如何使用SPARQL访问这些值。我尝试将“首次上升”定义为参数，但未产生任何结果。我还尝试了检查“首次上升”的所有可用属性，但看不到这些值的存储位置。我尝试过的代码是：

 SELECT ?mountainLabel ?date ?climbers 
WHERE 
{
  ?mountain wdt:P31 wd:Q8502. # instance of mountain
  ?mountain wdt:P17 wd:Q39.  # country Switzerland
  ?mountain wdt:P935 "Matterhorn". # name
  ?mountain wdt:P793/wd:Q1194369* ?firstAss. # first ascent

  ?firstAss wdt:P585 ?date . #date of ascent 
  ?firstAss wdt:P710 ?climbers . #climbername 

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en, de". }
}

Answer 1

第一次使用语句限定符并不简单...

解决方案：

PREFIX bd: <http://www.bigdata.com/rdf#> 
PREFIX p: <http://www.wikidata.org/prop/> 
PREFIX pq: <http://www.wikidata.org/prop/qualifier/> 
PREFIX ps: <http://www.wikidata.org/prop/statement/> 
PREFIX wd: <http://www.wikidata.org/entity/> 
PREFIX wdt: <http://www.wikidata.org/prop/direct/> 
PREFIX wikibase: <http://wikiba.se/ontology#> 


SELECT ?mountainLabel ?firstAssLabel ?date ?climberLabel 
    WHERE 
    {
      ?mountain wdt:P31 wd:Q8502. # instance of mountain
      ?mountain wdt:P17 wd:Q39.  # country Switzerland
      ?mountain wdt:P935 "Matterhorn". # name
      ?mountain wdt:P793/wd:Q1194369* ?firstAss. # first ascent

      ?mountain p:P793 ?firstAssStat .
      ?firstAssStat ps:P793 ?firstAss .
       ?firstAssStat pq:P585 ?date . #date of ascent 
       ?firstAssStat pq:P710 ?climber . #climbername 

      SERVICE wikibase:label {
           bd:serviceParam wikibase:language "en,de" .
      }
} 

演示：http://linkedwiki.com/query/Climbers_of_first_ascents

文档：https://www.wikidata.org/wiki/Wikidata:SPARQL_tutorial#Qualifiers

就个人而言，我观察项目的RDF / Turtle来构建我的查询： https://www.wikidata.org/wiki/Special:EntityData/Q1374.ttl