Question

我正在编写一个Excel VBA代码，该代码将循环遍历Outlook中的指定文件夹并获取“ MailItem”以进行进一步处理。在将MS Office套件升级到2016之前，它运行良好。现在，当循环开始时，它将选择Office升级之前的邮件。为什么它不以文件夹中的最新邮件开头？

在此处添加代码。

我试图创建一个启用了宏的新excel文件，然后键入代码并运行它。结果是一样的。

Sub sortexcelPrintLog()
Dim olApp As Outlook.Application
Dim ns As Outlook.Namespace
Dim folder As Outlook.folder
Dim mitem As MailItem
Dim item As Object
Dim i As Long
Dim dirPath As String
Dim s_directory As String
Dim wb As Workbook
Dim ws As Worksheet
Dim checkDate As Date
Dim ws2 As Worksheet
Dim j As Integer
Dim printLogs As Collection
Dim plog As pClass
Dim temptime As Date
Dim printlogName As String
Dim CDlogName As String
Dim logFlag As String
Dim dayname As String
Dim comparerecall As String
Dim lrow As Long

Set printLogs = New Collection


Set wb = ThisWorkbook
checkDate = Format(Now(), "mm/dd/yyyy")
dayname = Format(checkDate, "dddd")
Set olApp = New Outlook.Application

Set ns = olApp.GetNamespace("MAPI")
Set folder = ns.GetDefaultFolder(olFolderInbox) '.Folders("printlog")
i = 1

If dayname = "Monday" And CDate(Format(Now(), "hh:mm:ss AM/PM")) - 
TimeValue("01:00:00") > TimeValue("10:00:00 AM") Then
MsgBox folder.Name
For Each item In folder.Items
If TypeName(item) = "MailItem" Then
Set mitem = item

If Format(item.ReceivedTime, "mm/dd/yyyy") = checkDate - 3 Then


                If (CDate(Format(mitem.ReceivedTime, "hh:mm:ss AM/PM")) - 
TimeValue("01:00:00")) >= TimeValue("03:00:00 PM") Then
                        If LCase(mitem.Subject) Like LCase("Portland Claims*") Or _
                                LCase(mitem.Subject) Like LCase("Property Letter Trident Claim_TNT*") Or _
                                LCase(mitem.Subject) Like LCase("Property Letter Denver Claims*") Or _
                                LCase(mitem.Subject) Like LCase("Portland Claims*") Or _
                                LCase(mitem.Subject) Like LCase("Property Letter Alteris Claims*") Or _
                                LCase(mitem.Subject) Like LCase("Portland Claim*") Or _
                                LCase(mitem.Subject) Like LCase("recall*") Then
                            Set plog = New pClass
                            plog.Name = WorksheetFunction.VLookup(mitem.Sender, Worksheets("Agents").Range("A:B"), 2, 0)
                            plog.Subject = mitem.Subject
                            plog.SDate = Format(mitem.ReceivedTime, "mm/dd/yyyy")
                            plog.Docs = Docs(mitem.Subject)
                            plog.pages = pages(mitem.Subject)
                            plog.DTim = mitem.ReceivedTime

                            printLogs.Add plog
                        End If
                End If



        ElseIf Format(item.ReceivedTime, "mm/dd/yyyy") < checkDate - 3 
Then
            Exit For
        ElseIf Format(item.ReceivedTime, "mm/dd/yyyy") > checkDate - 3 Then
            GoTo nextbreak
        End If
         End If
nextbreak:
    Next
End If
End sub

我需要知道为什么它不以文件夹中的最新邮件开头。

Answer 1

您很幸运，以前最晚处理的邮件优先。要确定必须排序的顺序。

Option Explicit

Sub sortItems()

    Dim olApp As Outlook.Application
    Dim olNs As Outlook.Namespace
    Dim olFldr As Outlook.folder

    Dim olItem As Object
    Dim olFldrItems As items
    Dim mItem As MailItem

    Set olApp = New Outlook.Application
    Set olNs = olApp.GetNamespace("MAPI")
    Set olFldr = olNs.GetDefaultFolder(olFolderInbox)

    ' Do not attempt to sort items in the folder, olFldr.items, directly
    ' Sort a collection of items
    Set olFldrItems = olFldr.items
    olFldrItems.Sort "[ReceivedTime]", True

    For Each olItem In olFldrItems
        If TypeName(olItem) = "MailItem" Then
            Set mItem = olItem
            Debug.Print Format(mItem.ReceivedTime, "mm/dd/yyyy") & " " & mItem.Subject
        End If
    Next

End Sub

对于每个循环，不是以收件箱中的最新电子邮件开头，而是以较旧的电子邮件开头

1 个答案: