Question

Julia具有在结构上运行的setter函数setproperty!和setfield!以及getter函数getproperty和getfield。 Julia中的属性和字段有什么区别？

例如，以下内容似乎表明它们做了相同的事情：

julia> mutable struct S
           a
       end

julia> s = S(2)
S(2)

julia> getfield(s, :a)
2

julia> getproperty(s, :a)
2

julia> setfield!(s, :a, 3)
3

julia> s
S(3)

julia> setproperty!(s, :a, 4)
4

julia> s
S(4)

Answer 1

fields只是结构的“组件”。结构

struct A
   b
   c::Int
end

具有字段b和c。调用getfield会返回绑定到该字段的对象：

julia> a = A("foo", 3)
A("foo", 3)

julia> getfield(a, :b)
"foo"

在Julia的早期版本中，语法a.b用来“降低”，即与写getfield(a, :b)相同。现在发生的变化是，a.b降低为getproperty(a, :b)，并具有默认后备广告

getproperty(a::Type, v::Symbol) = getfield(a, v)

因此，默认情况下，什么都没有改变。但是，结构的作者可以重载getproperty（不可能重载getfield）以为点语法提供额外的功能：

julia> function Base.getproperty(a::A, v::Symbol)
           if v == :c
               return getfield(a, :c) * 2
           elseif v == :q
               return "q"
           else
               return getfield(a, v)
           end
       end

julia> a.q
"q"

julia> getfield(a, :q)
ERROR: type A has no field q

julia> a.c
6

julia> getfield(a, :c)
3

julia> a.b
"foo"

因此，我们可以为点语法添加额外的功能（如果需要，可以动态地添加）。举个有用的具体示例，对于PyCall.jl包，您曾经必须编写pyobject[:field]，而现在可以实现它，以便您可以编写pyobject.field.

setfield!和setproperty!之间的区别类似于上面解释的getfield和getproperty之间的区别。

此外，可以挂接到函数Base.propertynames中，以在REPL中提供属性的制表符补全。默认情况下，仅显示字段名称：

julia> a.<TAB><TAB>
b c

但是通过重载propertynames，我们可以使它也显示额外的属性q：

julia> Base.propertynames(::A) = (:b, :c, :q)

julia> a.<TAB><TAB>
b c q

Julia中的字段和属性有什么区别？

1 个答案: