Question

我想在ID列中找到给定的ID，然后从同一行返回Date值。

这需要使用标题行名称来完成，因为用户将添加和删除列。

电子表格示例

标题始终位于第1行，但标题列的数量将有所不同。

Answer 1

让我们假设：

Headers出现在第一行

代码：

Option Explicit

Sub test()

    Dim LastColumn As Long, LastRow As Long
    Dim IDColumnNo As Range, DateColumnNo As Range, IDposition As Range
    Dim strID As String
    Dim dtDate As Date

    'Set the ID you want to search for. Change to fullfil you needs
    strID = "w"

    With ThisWorkbook.Worksheets("Sheet1")

        'Find the last row of the first column
        LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        'Find the last column of the first row
        LastColumn = .Cells(1, .Columns.Count).End(xlToLeft).Column

        'Find which is the column with the IDs searching for the Header "ID"
        Set IDColumnNo = .Range(.Cells(1, 1), .Cells(LastRow, LastColumn)).Find("ID", LookIn:=xlValues, Lookat:=xlWhole)

        'Find which is the column with the Dates searching for the Header "Date"
        Set DateColumnNo = .Range(.Cells(1, 1), .Cells(LastRow, LastColumn)).Find("Date", LookIn:=xlValues, Lookat:=xlWhole)

        If Not IDColumnNo Is Nothing And Not DateColumnNo Is Nothing Then

            'Find which the Id we want"
            Set IDposition = .Range(.Cells(2, IDColumnNo.Column), .Cells(LastRow, IDColumnNo.Column)).Find(strID, LookIn:=xlValues, Lookat:=xlWhole)

            If Not IDposition Is Nothing Then
                dtDate = .Cells(IDposition.Row, DateColumnNo.Column).Value
            Else
                MsgBox "ID is missing!"
            End If

        Else

            MsgBox "ID, Date or both headers are missing!"

        End If

    End With

End Sub

Answer 2

假设您需要查找名为“ ID”的列并从“状态”列返回值，则可以使用以下公式

=OFFSET(INDIRECT(ADDRESS(1,MATCH("ID",A1:E1,0))),MATCH(K1,OFFSET(INDIRECT(ADDRESS(1,MATCH("ID",A1:E1,0))),1,0,100,1),0),MATCH("Status",A1:E1,0)-MATCH("ID",A1:E1,0),1,1)

要查找的值在单元格K1

中