Question

当尝试在没有FPU的情况下实现正弦函数时，我意识到所有输入都是合理的，因此我决定尝试一种全理性的方法。可能较慢，但是：为什么不呢？该序列是线性收敛的，因此可以通过二进制拆分进行运行时优化。甚至还有highly detailed literature以及如何使用的信息。

到目前为止，很好。

我用于数值算法的原型工具是Pari / GP，因此我将上述论文中的代码移植到了Pari / GP，正如您可能已经从我在此处发布问题的事实中猜到的那样，它没有用。好了，它确实起作用了，但是不可能将错误最小化。该文件还有其他几种针对不同功能的配方，但是都显示出相同的行为。假设论文有错字，我在CLN中检查了作者的实现。经过大量优化，但完全基于本文的代码，甚至逐字记录。

要获得MWE，我将其配方用于exp(p/q)（除阶乘之外最简单的配方），并简化了Pari / GP代码。

exp_bin_split_rat_internal(n1, n2, x) = {
  \\ R, L, r = [P, Q, B, T]
  \\ a       = [p, q, b, a]
  local(diff, mn, L, R, r = vector(4));

  diff = n2 - n1;
  if(diff == 0,
     \\ no actual error-handling here
     print("Error in bin_split_rat_internal: n2-n1 is zero.");
  );
  if( diff == 1,
    \\ x = u/v
    if(n1 == 0,
      \\ r.P = 1;
      r[1] = 1;
      \\ r.Q = 1;
      r[2] = 1;
      \\ r.B = b(0) = 1;
      r[3] = 1;
      \\ r.T = a(0) * r.P = 1 * u;
      r[4] = 1 * r[1];
      return(r);
    , \\ else
      \\ r.P = u;
      r[1] = numerator(x);
      \\ r.Q = n1 * v;
      r[2] = n1 * denominator(x);
      \\ r.B = b(n) =  1;
      r[3] =  1;
      \\ r.T = a(n) * r.P = 1 * u;
      r[4] = 1 * r[1];
      return(r);
    );
  );
  \\ floor((n1 + n2)/2)
  nm = (n1 + n2)\2;
  L = exp_bin_split_rat_internal(n1, nm, x);
  R = exp_bin_split_rat_internal(nm, n2, x);
  \\            1  2  3  4
  \\ R, L, r = [P, Q, B, T]
  \\ r.P = L.P * R.P;
  r[1] = L[1] * R[1];
  \\r.Q = L.Q * R.Q;
  r[2] = L[2] * R[2];
  \\r.B = L.B * R.B;
  r[3] = L[3] * R[3];
  \\r.T = R.B  * R.Q  * L.T   +  L.B  * L.P  * R.T;
  r[4] = (R[3] * R[2] * L[4]) + (L[3] * L[1] * R[4]);

  return(r);
}

exp_bin_split_rat(x, n) = {
  local(r, ret);
  r = exp_bin_split_rat_internal(0, n, x);
  \\ r = [P, Q, B, T]
  \\ S = T/(B*Q)
  ret = r[4]/(r[3] * r[2]);
  return(ret);
}

k = 1/1234;
tmp = exp_bin_split_rat(k, 10) * 1.0;print(tmp);tmp= exp(k);print(tmp);
tmp = exp_bin_split_rat(k, 100) * 1.0;print(tmp);tmp= exp(k);print(tmp);
tmp = exp_bin_split_rat(k, 1000) * 1.0;print(tmp);tmp= exp(k);print(tmp);
tmp = exp_bin_split_rat(k, 10000) * 1.0;print(tmp);tmp= exp(k);print(tmp);

（最后一个可能要花一些时间，如果要运行它，可以跳过它。）

如您所见，经过十几步后，无法进一步减少错误。

因此，就我而言，算法的工作方式或Pari / GP的工作方式都令人误解。是哪一个？为什么？

Answer 1

您会为此而讨厌自己/ PARI（但喜欢堆栈溢出）。

在第一行中，您有：

local(diff, mn, L, R, r = vector(4));

代替：

local(diff, nm, L, R, r = vector(4));

我建议使用my而不是local。

my(diff, nm, L, R, r = vector(4));

Answer 2

请注意，从 2.13 版开始，它可以作为 Pari/GP 中的内置函数使用：请参阅 trans1.c:expQ()。该函数用于计算小高度有理数的exp(p/q)。

通用驱动程序是私有的，但总有一天会被导出，参见 trans1.c: abpq_sum()。

Pari / GP

2 个答案: