Question

我花了很长时间才知道为什么这段代码对某些网址“悬空”：

let getImage (imageUrl:string) =
    async {
        try
            let req = WebRequest.Create(imageUrl) :?> HttpWebRequest
            req.UserAgent <- "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1; .NET CLR 1.1.4322)";
            req.Method <- "GET";
            req.AllowAutoRedirect <- true;
            req.MaximumAutomaticRedirections <- 4;
            req.Timeout <- 3000; //HAHAHA, nice try!
            let! response1 = req.AsyncGetResponse()
            let response = response1 :?> HttpWebResponse
            use stream = response.GetResponseStream()
            let ms = new MemoryStream()
            let bytesRead = ref 1
            let buffer = Array.create 0x1000 0uy
            while !bytesRead > 0 do
                bytesRead := stream.Read(buffer, 0, buffer.Length)
                ms.Write(buffer, 0, !bytesRead)
            return SuccessfulDownload(imageUrl, ms.ToArray())

        with
            ex -> return FailedDownload(imageUrl, ex.Message)
    }

在设法追踪3000个网址中的哪一个被挂起之后，我了解到AsyncGetResponse没有注意到HttpWebRequest.Timeout。我做了一些搜索，它抛出了在带有计时器的线程中包装异步请求的建议。这对C＃来说很棒，但是如果我通过Async.Parallel |> Async.RunSynchronously运行其中的3000个，那么处理这个问题的最佳方法是什么？

Answer 1

我只是大致测试了这个，但它应该有正确的行为：

type System.Net.WebRequest with
  member req.AsyncGetResponseWithTimeout () =
    let impl = async {
      let iar = req.BeginGetResponse (null, null)
      let! success = Async.AwaitIAsyncResult (iar, req.Timeout)
      return if success then req.EndGetResponse iar
             else req.Abort ()
                  raise (System.Net.WebException "The operation has timed out") }
    Async.TryCancelled (impl, fun _ -> req.Abort ())

在您的代码中，请致电req.AsyncGetResponseWithTimeout()而不是req.AsyncGetResponse()。

如何在F＃Async.Parallel中处理HttpWebRequest超时

1 个答案: