Question

我正在学习sml，却陷入了运动中。他们给了我这样的数据类型

datatype Expr =  X
                |Y
                | Avg of Expr * Expr
                | Mul of Expr * Expr

并且我需要编写一个称为compute的函数，以便我可以在函数类型为的地方进行平均或乘法运算

Expr -> int -> int -> int

所以我做到了

val rec compute =   fn X => (fn x => fn y => x)
                | Y => (fn x => fn y => y)
                | Avg(e1,e2) => ( fn x => fn y => ((compute e1 x y) + (compute e2 x y)) div 2)
                | Mul(e1,e2) => ( fn x => fn y => (compute e1 x y ) * (compute e2 x y))

现在我需要从终端调用它，但是我不知道如何调用该函数。我尝试了

compute Avg 4 2;

但这给了我

    poly: : error: Type error in function application.
   Function: compute : Expr -> int -> int -> int
   Argument: Avg : Expr * Expr -> Expr
   Reason: Can't unify Expr to Expr * Expr -> Expr (Incompatible types)
Found near compute Avg 4 2
Static Errors

有人可以指导我进行此操作吗？谢谢大家附言有没有办法让这个变得有趣

Answer 1

Avg不是类型Expr的值，它是根据一对Expr创建Expr的构造函数。
您的编译器还会在错误消息中指出这一点：

Avg : Expr * Expr -> Expr

您应该这样使用它：

compute (Avg(Y,X)) 4 2

等于3。

您的函数已经正确，但是使用fun使其更具可读性：

fun compute X x y = x
  | compute Y x y = y
  | compute (Avg (e1, e2)) x y = ((compute e1 x y) + (compute e2 x y)) div 2
  | compute (Mul (e1, e2)) x y = (compute e1 x y) * (compute e2 x y)

Answer 2

编写该函数的另一种方法是：

fun compute e x y =
    case e of
        X => x
      | Y => y
      | Avg (e1, e2) => (compute e1 x y + compute e2 x y) div 2
      | Mul (e1, e2) => compute e1 x y * compute e2 x y

SML从数据类型调用函数

2 个答案: