Question

我有一个随Visual Studio 2019打开的CMake项目。我的代码需要c ++ 17功能，因此我在CMakeLists.txt

中设置了相应的标志

cmake_minimum_required (VERSION 3.10.0)

project (datalog)

message (STATUS "Building project ${PROJECT_NAME}")

find_package(stxxl CONFIG REQUIRED)

include_directories (${CMAKE_SOURCE_DIR}/src)

set (PROJECT_SRC
  main.cpp
  )

add_executable (${PROJECT_NAME} ${PROJECT_SRC})
target_compile_features(${PROJECT_NAME} PRIVATE cxx_std_17)

target_link_libraries(${PROJECT_NAME} stxxl)

构建时，我会遇到很多错误，因为要链接的库stxxl与vcpkg一起安装，具有以下代码段：

STXXL_BEGIN_NAMESPACE

template <class Type>
struct compat_unique_ptr {
#if __cplusplus >= 201103L && ((__GNUC__ * 10000 + __GNUC_MINOR__ * 100) >= 40400)
    typedef std::unique_ptr<Type> result;
#else
    // auto_ptr is inherently broken and is deprecated by unique_ptr in c++0x
    typedef std::auto_ptr<Type> result;
#endif
};

STXXL_END_NAMESPACE

问题在于__cplusplus的值为199711L而不是正确的值201703L，因此代码尝试使用在C ++ 17标准中已删除的auto_ptr。 / p>

我还尝试在Visual Studio中手动设置该标志，并将此部分添加到CmakeLists.txt

if(MSVC)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /std:c++17 /Zc:__cplusplus")
endif()

但是没有任何变化。我还使用了一些C ++ 17功能，因此暂时不可以选择。

我可以手动更新stxxl头文件以摆脱宏，但这是一种解决方法，每个开发人员都应创建相同的修复程序。相反，我想知道为什么会出现错误，以及如何使用Visual Studio和CMake将宏设置为正确的值。你有什么建议吗？

Answer 1

我认为您需要的是target_compile_definitions，您可以在其中定义CMake中的任意宏并将其传递给编译器。

Answer 2

据我从this得知，您需要手动添加/Zc:__cplusplus（至少现在）。

您的CMakeList代码段对我有用，您确定__cplusplus实际上设置不正确，而不仅仅是__GNUC__宏，丢失了吗？

也就是说，我建议您测试一下VisualStudio版本是否真的足够新：

# /Zc:__cplusplus is required to make __cplusplus accurate
# /Zc:__cplusplus is available starting with Visual Studio 2017 version 15.7
# (according to https://docs.microsoft.com/en-us/cpp/build/reference/zc-cplusplus)
# That version is equivalent to _MSC_VER==1914
# (according to https://docs.microsoft.com/en-us/cpp/preprocessor/predefined-macros?view=vs-2019)
# CMake's ${MSVC_VERSION} is equivalent to _MSC_VER
# (according to https://cmake.org/cmake/help/latest/variable/MSVC_VERSION.html#variable:MSVC_VERSION)
if ((MSVC) AND (MSVC_VERSION GREATER_EQUAL 1914))
    target_compile_options(stxxl INTERFACE "/Zc:__cplusplus")
endif()

注意：我使用target_compile_options向您的库目标界面添加了必要的选项。这样，所有依赖该库（通过target_link_libraries）的目标都将使用该标志进行编译，但是不需要（可能与之不兼容）的目标将无法获得该标志。

如果要将标志添加到自己的目标之一，则可以使用target_compile_options(stxxl PUBLIC "/Zc:__cplusplus")（PUBLIC代替INTERFACE）。 INTERFACE表示在其他目标依赖该目标时使用该选项，PRIVATE表示该选项本身用于目标，而PUBLIC表示两者。（恕我直言this artical解释得很好。）

除此之外，您不应该通过编译标志设置c ++标准版本，而是如果需要更新版本，则使用target_compile_features并使用
set_target_properties(your_target_name PROPERTIES CXX_STANDARD 17)（如果您只想使用较新的版本）。

在您的情况下，后者可能就足够了，因为如果c ++版本较旧，您的代码段将具有备用功能。

如果可以选择更改stxxl的代码（通过拉取请求等），则该代码可以测试_MSVC_LANG和_MSC_VER。这样一来，无需/Zc:__cplusplus就可以工作。

无法使用Visual Studio和CMake将__cplusplus设置为C ++ 17标准

2 个答案: