如何将clang-tidy集成到CMake和GCC？

时间：2019-07-17 18:23:03

标签： c++ gcc cmake clang clang-tidy

我想将clang-tidy集成到我们的C和C ++，基于CMake的项目中，该项目使用自定义GCC工具链进行编译。

我尝试按照this tutorial设置CMAKE_CXX_CLANG_TIDY。我还尝试通过将CMAKE_EXPORT_COMPILE_COMMANDS设置为ON并将run-clang-tidy.py指向其目录来生成编译数据库。

在两种情况下，我都遇到（相同）一些可能与Clang和GCC之间的差异有关的错误：

  1. Clang不支持某些在CMake文件中启用的警告标志，但GCC支持（例如-Wlogical-op）。由于编译器是GCC，因此文件可以正确构建，并且标志被写入编译数据库，但是clang-tidy对此有所抱怨。
  2. clang-tidy抱怨一些定义，并且功能不可用，即使代码可以很好地编译。例如，android-cloexec-open check建议使用O_CLOEXEC来提高安全性并强制关闭文件，但是尝试使用此定义会导致未定义的标识符错误（即使我们的GCC编译了代码）。 作为找不到的函数的示例，有clock_gettime。

我们的代码使用C11标准和C ++ 14标准进行编译，而没有GNU扩展：

set(CMAKE_C_STANDARD 11)
set(CMAKE_CXX_STANDARD 14)

set(CMAKE_C_EXTENSIONS OFF)
set(CMAKE_CXX_EXTENSIONS OFF)

定制工具链是一种交叉编译工具链，可在Linux上运行并编译为FreeBSD。

  1. 是否有办法禁止CMake将某些标志传递给clang-tidy？我使用clang-tidy错了吗？
  2. 我怀疑此问题与使用交叉编译工具链禁用GNU扩展以及一些功能测试宏有关，这些宏未在Clang中默认定义，而是由GCC定义（例如_GNU_SOURCE / { {1}}）。如果是这种情况，我该如何检查？如果没有，我应该另外使用clang-tidy吗？

1 个答案:

答案 0 :(得分：2)

好的，我想我有一个解决方案。经过几个晚上，我得以使它工作。

总的来说，我是这样编译的

rm -rf build
mkdir build
cd build
cmake -C ../cmake-scripts/clang-tidy-all.cmake .. && make

cmake-scripts目录包含：

clang-tidy-all.cmake
toolchain_arm_clang.cmake

下面列出了两个重要文件。 但是更重要的是，您需要如何编译它。

首先，toolchain_arm_clang.cmake是通过clang-tidy-all.cmake从set(CMAKE_TOOLCHAIN_FILE ...)直接引用的。但是，必须从建筑目录的角度来引用它，因此，如果您使用多个构建目录级别，例如：build/x86，build/arm，build/darwin等。 ，那么您必须相应地修改该路径。

第二，set(CONFIG_SCRIPT_PRELOADED ...)的目的是确保配置脚本已预先加载，即cmake -C ../cmake-scripts/clang-tidy-all.cmake .. 通常，您会希望在CMakeLists.txt文件中的某处有这样的内容：

message(STATUS "CONFIG_SCRIPT_PRELOADED: ${CONFIG_SCRIPT_PRELOADED}")
if(NOT CONFIG_SCRIPT_PRELOADED)
    message(FATAL_ERROR "Run cmake -C /path/to/cmake.script to preload a config script!")
endif()

第三，在/lib/ld-musl-armhf.so.1中有set(CMAKE_LINKER_ARM_COMPAT_STATIC ...)个硬编码；在我使用的开发框中，它指向/lib/libc.so，因此可以确定使用/lib/libc.sh代替。我从未尝试过。

第四，使用set(CMAKE_C_LINK_EXECUTABLE ...)和set(CMAKE_LINKER_ARM_COMPAT_STATIC ...)是因为CMake在检查编译器时（即，甚至在运行make之前，抱怨某些链接问题。

第五，我只编译C++代码，因此，如果您需要编译一些C，则可能还需要正确配置set(CMAKE_C_CREATE_SHARED_LIBRARY ...)，但是我不知道是否有这样的配置选项。

一般建议

请勿立即将其集成。首先使用一个库（最好是C++一个库）测试一个简单的CMake项目并使其工作，然后添加第二个库，但是在C中再次对其进行调整。并且只有在此之后，才将其合并到代码库中。

工具链

我将自定义工具链与GCC 8.3.0和musl C库一起使用，因此某些文件的位置对于其他工具链可能会有所不同。

自定义CMake

某些变量，例如（已经提到）CONFIG_SCRIPT_PRELOADED，EXPORT_PACKAGE_TO_GLOBAL_REGISTRY，DO_NOT_BUILD_TESTS或DO_NOT_BUILD_BENCHMARKS是非通用CMake选项，即我只在CMakeLists.txt中使用它们，因此您可以放心地忽略它们。

在每个*.cmake文件末尾未设置的变量，例如build_test，extra_clang_tidy_unchecks_for_tests_only，不需要出现在项目的主CMakeLists.txt中。

C语

$ clang --version
clang version 10.0.0 (https://github.com/llvm/llvm-project.git 4650b2f36949407ef25686440e3d65ac47709deb)
Target: x86_64-unknown-linux-gnu
Thread model: posix
InstalledDir: /opt/local/bin

文件

clang-tidy-all.cmake：

set(ALL_CXX_WARNING_FLAGS --all-warnings -Weverything -Wno-c++98-compat -Wno-c++98-c++11-compat -Wno-c++98-c++11-c++14-compat -Wno-padded -Wno-c++98-compat-pedantic)
set(CXX_COMPILE_OPTIONS "-std=c++17;-O3;${ALL_CXX_WARNING_FLAGS}" CACHE INTERNAL "description")


set(CMAKE_CROSSCOMPILING True)
set(CMAKE_TOOLCHAIN_FILE "../cmake-scripts/toolchain_arm_clang.cmake" CACHE FILEPATH "CMake toolchain file")

set(CONFIG_SCRIPT_PRELOADED true CACHE BOOL "Ensures that config script was preloaded")


set(build_test False)

if(build_test)
    message(STATUS "Using test mode clang-tidy checks!")
    set(extra_clang_tidy_unchecks_for_tests_only ",-google-readability-avoid-underscore-in-googletest-name,-cppcoreguidelines-avoid-magic-numbers,-cppcoreguidelines-special-member-functions")
endif()

set(CMAKE_CXX_CLANG_TIDY "clang-tidy;--enable-check-profile;--checks=-*,abseil-string-find-startswith,bugprone-*,cert-*,clang-analyzer-*,cppcoreguidelines-*,google-*,hicpp-*,llvm-*,misc-*,modernize-*,-modernize-use-trailing-return-type,performance-*,readability-*,-readability-static-definition-in-anonymous-namespace,-readability-simplify-boolean-expr,portability-*${extra_clang_tidy_unchecks_for_tests_only}" CACHE INTERNAL "clang-tidy")

message(STATUS "build_test: ${build_test}")
message(STATUS "extra_clang_tidy_unchecks_for_tests_only: ${extra_clang_tidy_unchecks_for_tests_only}")
message(STATUS "CMAKE_CXX_CLANG_TIDY: ${CMAKE_CXX_CLANG_TIDY}")

# We want to skip building tests when clang-tidy is run (it takes too much time and serves nothing)
if(DEFINED CMAKE_CXX_CLANG_TIDY AND NOT build_test)
    set(DO_NOT_BUILD_TESTS true CACHE BOOL "Turns OFF building tests")
    set(DO_NOT_BUILD_BENCHMARKS true CACHE BOOL "Turns OFF building benchmarks")
endif()



unset(build_test)
unset(extra_clang_tidy_unchecks_for_tests_only)
set(EXPORT_PACKAGE_TO_GLOBAL_REGISTRY "OFF" CACHE INTERNAL "We don't export clang-tidy-all version to global register")

toolchain_arm_clang.cmake：

set(CMAKE_SYSTEM_NAME Linux)
set(CMAKE_SYSTEM_VERSION 4.14.0)
set(CMAKE_SYSTEM_PROCESSOR arm)


set(gcc_version 8.3.0)
set(x_tools "/opt/zynq/xtl")

set(CMAKE_C_COMPILER "clang" CACHE INTERNAL STRING)
set(CMAKE_CXX_COMPILER "clang++" CACHE INTERNAL STRING)
set(CMAKE_RANLIB "llvm-ranlib" CACHE INTERNAL STRING)
set(CMAKE_AR "llvm-ar" CACHE INTERNAL STRING)
set(CMAKE_AS "llvm-as" CACHE INTERNAL STRING)
set(CMAKE_LINKER "ld.lld" CACHE INTERNAL STRING)

execute_process(
    COMMAND bash -c "dirname `whereis ${CMAKE_LINKER} | tr -s ' ' '\n' | grep ${CMAKE_LINKER}`"
    OUTPUT_VARIABLE cmake_linker_dir
)
string(REGEX REPLACE "\n$" "" cmake_linker_dir "${cmake_linker_dir}")
set(cmake_linker_with_dir "${cmake_linker_dir}/${CMAKE_LINKER}" CACHE INTERNAL STRING)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -iwithsysroot /include/c++/${gcc_version} -iwithsysroot /include/c++/${gcc_version}/arm-linux-musleabihf" CACHE INTERNAL STRING)


set(CMAKE_SYSROOT ${x_tools}/arm-linux-musleabihf)
set(CMAKE_FIND_ROOT_PATH ${x_tools}/arm-linux-musleabihf)
set(CMAKE_INSTALL_PREFIX ${x_tools}/arm-linux-musleabihf)

set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY BOTH)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE BOTH)
set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE NEVER)



set(triple arm-linux-musleabihf)
set(CMAKE_LIBRARY_ARCHITECTURE ${triple})
set(CMAKE_C_COMPILER_TARGET ${triple})
set(CMAKE_CXX_COMPILER_TARGET ${triple})


set(lib_path_arm ${x_tools}/arm-linux-musleabihf/lib)

## Bootstrap library stuff:
set(Scrt1_o ${lib_path_arm}/Scrt1.o)
set(crti_o ${lib_path_arm}/crti.o)
set(crtn_o ${lib_path_arm}/crtn.o)

set(lib_path_gcc ${x_tools}/lib/gcc/${triple}/${gcc_version})
set(crtbeginS_o ${lib_path_gcc}/crtbeginS.o)
set(crtendS_o ${lib_path_gcc}/crtendS.o)


# Clang as linker
# --no-pie disable position independent executable, which is required when building
# statically linked executables.
set(CMAKE_CXX_LINK_EXECUTABLE "clang++ --target=${triple} -Wl,--no-pie --sysroot=${CMAKE_SYSROOT} ${CMAKE_CXX_FLAGS} -fuse-ld=${cmake_linker_with_dir} <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET> ")
set(CMAKE_CXX_CREATE_SHARED_LIBRARY "clang++ -Wl, --target=${triple} --sysroot=${CMAKE_SYSROOT} ${CMAKE_CXX_FLAGS} -fuse-ld=${cmake_linker_with_dir} -shared <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET> ")
#
# Do not use CMAKE_CXX_CREATE_STATIC_LIBRARY -- it is created automatically
# by cmake using ar and ranlib
#
#set(CMAKE_CXX_CREATE_STATIC_LIBRARY "clang++ -Wl,--no-pie,--no-export-dynamic,-v -v --target=${triple} --sysroot=${CMAKE_SYSROOT} ${CMAKE_CXX_FLAGS} -fuse-ld=ld.lld <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET> ")


## Linker as linker
set(CMAKE_LINKER_ARM_COMPAT_STATIC "-pie -EL -z relro -X --hash-style=gnu --eh-frame-hdr -m armelf_linux_eabi -dynamic-linker /lib/ld-musl-armhf.so.1 ${Scrt1_o} ${crti_o} ${crtbeginS_o} -lstdc++ -lm -lgcc_s -lgcc -lc ${crtendS_o} ${crtn_o}")
set(CMAKE_C_LINK_EXECUTABLE "${CMAKE_LINKER} ${CMAKE_LINKER_ARM_COMPAT_STATIC} <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS> -o  <TARGET>")


# Debian bug 708744(?)
#include_directories("${CMAKE_SYSROOT}/usr/include/")
#include_directories("${CMAKE_SYSROOT}/usr/include/c++/${gcc_version}")
#include_directories("${CMAKE_SYSROOT}/usr/include/c++/${gcc_version}/${triple}")

## Clang workarounds:
set(toolchain_lib_dir_0 "${CMAKE_SYSROOT}/lib")
set(toolchain_lib_dir_1 "${CMAKE_SYSROOT}/../lib")
set(toolchain_lib_dir_2 "${CMAKE_SYSROOT}/../lib/gcc/${triple}/${gcc_version}")
set(CMAKE_TOOLCHAIN_LINK_FLAGS "-L${toolchain_lib_dir_0} -L${toolchain_lib_dir_1} -L${toolchain_lib_dir_2}")

## CMake workarounds
set(CMAKE_EXE_LINKER_FLAGS ${CMAKE_TOOLCHAIN_LINK_FLAGS} CACHE INTERNAL "exe link flags")
set(CMAKE_MODULE_LINKER_FLAGS ${CMAKE_TOOLCHAIN_LINK_FLAGS} CACHE INTERNAL "module link flags")
set(CMAKE_SHARED_LINKER_FLAGS ${CMAKE_TOOLCHAIN_LINK_FLAGS} CACHE INTERNAL "shared link flags")



unset(cmake_linker_with_dir)
unset(cmake_linker_dir)
相关问题
最新问题