Question

我正在尝试使用XSLT从平面XML文件创建分层XML文件，并且不确定最佳方法是什么。

e.g。我需要转换

<root>
<inventory bag="1" fruit="apple"/>
<inventory bag="1" fruit="banana"/>
<inventory bag="2" fruit="apple"/>
<inventory bag="2" fruit="orange"/>
</root>

到

<inventory>
<baglist>
<bag id="1"/>
<bag id="2"/>
</baglist>

<bag id="1">
<fruit id="apple"/>
<fruit id="banana"/>
</bag>

<bag id="2">
<fruit id="apple"/>
<fruit id="orange"/>
</bag>
</inventory>

N袋/水果

Answer 1

xsl：for-each你的节点两次，或者使用不同模式的xsl：template。

Answer 2

根据inventory属性的值组成bag个元素：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="byBag" match="root/inventory" use="@bag" />
    <xsl:template match="/">
        <inventory>
            <baglist>
                <xsl:apply-templates mode="baglist" />
            </baglist>
            <xsl:apply-templates />
        </inventory>
    </xsl:template>
    <xsl:template
        match="root/inventory[generate-id() =
                             generate-id(key('byBag', @bag)[1])]" 
                        mode="baglist">
        <bag id="{@bag}" />
    </xsl:template>

    <xsl:template
        match="root/inventory[generate-id() =
                            generate-id(key('byBag', @bag)[1])]">
        <bag id="{@bag}">
            <xsl:apply-templates select="key('byBag', @bag)"
                mode="details" />
        </bag>
    </xsl:template>

    <xsl:template match="inventory" mode="details">
        <fruit id="{@fruit}" />
    </xsl:template>
</xsl:stylesheet>

使用XSLT将平面XML结构更改为层次结构

2 个答案: