Question

我要使用QueryDef创建两个查询。

此插入查询工作正常，我可以分配参数：

Dim qryAddPackage As String: qryAddPackage = "" & _
    "INSERT INTO `RMF_tblPackages` " & _
    "(`SystemID`, `DoD`, `DateCreated`, `LastModified`, `LastUpdatedBy`) " & _
    "VALUES ([SystemID], [DoD], NOW(), NOW(), [UID])"

With CurrentDb.CreateQueryDef(vbNullString, qryAddPackage)
    .Parameters!SystemID.Value = cbbSystems.Value
    .Parameters!DoD.Value = Me.txtDoD.Value
    .Parameters!UID.Value = strGetUserID()
    .Execute
End With

但是，在此更新查询中，我只能访问WHERE语句中的参数UID：

Dim qryUpdatePkg As String: qryUpdatePkg = "" & _
"UPDATE `RMF_tblPackages` " & _
"SET " & _
    "`SystemID` = [SystemID], `DoD` = [DoD], `LastModified` = NOW(), `LastUpdatedBy` = [UID] " & _
" WHERE `PackageID` = [PackageID]"

With CurrentDb.CreateQueryDef(vbNullString, qryUpdatePkg)
    .Parameters("SystemID").Value = cbbSystems.Value
    .Parameters!DoD.Value = Me.txtDoD.Value
    .Parameters!UID.Value = strGetUserID()
    .Parameters!PackageID.Value = Me.lbxPackages.Value
    .Execute dbSeeChanges
End With

在每行尝试分配参数的行中，它仅表明参数名称不在集合中。

我尝试过这样分配他们：

.Parameters("PackageID").Value = Me.lbxPackages.Value

同样，但这也不起作用。

我尝试仅使用一些数据运行更新查询，但它运行良好，因此查询有效。

.Params.count会返回1，正如您期望的那样，因为它只能识别一个参数。

关于为什么更新查询无法识别参数的任何其他想法？

Answer 1

使用[ ]引用标识符。在Access中，反引号无效（与MySQL不同）。此外，列名和参数名使用相同的引号字符，因此您必须为参数选择不同的名称。仅当名称与保留字或函数名称（例如Date，From，By，Order等发生冲突时，才需要引用标识符。

Dim qryUpdatePkg As String

qryUpdatePkg = "UPDATE RMF_tblPackages " & _
"SET " & _
  "SystemID = prmSystemID, DoD = prmDoD, LastModified = Now(), LastUpdatedBy = prmUID " & _
" WHERE PackageID = prmPackageID"

With CurrentDb.CreateQueryDef(vbNullString, qryUpdatePkg)
    .Parameters("prmSystemID").Value = cbbSystems.Value
    .Parameters!prmDoD.Value = Me.txtDoD.Value
    .Parameters!prmUID.Value = strGetUserID()
    .Parameters!prmPackageID.Value = Me.lbxPackages.Value
    .Execute dbSeeChanges
End With

在第一个查询中进行相同的更改。

找不到访问更新QueryDef参数

1 个答案: