Question

由于我可能会粗略化术语，我将通过实例解释。

我的XML源文档包含以下元素：

<paragraph>
    This paragraph has things like <link><xref label="lbl1">this</xref></link>
    and things like <emphasis type="bold">this</emphasis>
    and <emphasis type="italic">this</emphasis>.
</paragraph>

需要使用XSLT将其转换为：

<p>
    This paragraph has things like <a href="[lbl1]">this</a>
    and things like <b>this</b>
    and <i>this</i>.
</p>

谢谢！

Answer 1

目前的两个解决方案太长了，其中一个解决方案甚至没有格式良好的XML ......

这是一个简短而完整的解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="link">
  <a href="[{xref/@label}]">
   <xsl:apply-templates/>
  </a>
 </xsl:template>

 <xsl:template match="emphasis">
  <xsl:element name="{substring(@type,1,1)}">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>
 <xsl:template match="xref">
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<paragraph>This paragraph has things like <link><xref label="lbl1">this</xref></link> and things like <emphasis type="bold">this</emphasis> and <emphasis type="italic">this</emphasis>.
</paragraph>

产生了想要的正确结果：

<paragraph>This paragraph has things like <a href="[lbl1]">this</a> and things like <b>this</b> and <i>this</i>.
</paragraph>

Answer 2

这应该可以解决问题：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">

  <xsl:output method="xml" indent="yes" />

  <xsl:template match="/">
    <xsl:apply-templates />
  </xsl:template>

  <xsl:template match="paragraph">
    <xsl:element name="p">
      <xsl:apply-templates />
    </xsl:element>
  </xsl:template>

  <xsl:template match="link">
    <xsl:apply-templates />
  </xsl:template>

  <xsl:template match="xref">
    <xsl:element name="a">
      <xsl:attribute name="href">
        <xsl:text>[</xsl:text><xsl:value-of select="@label" /><xsl:text>]</xsl:text>
      </xsl:attribute>
      <xsl:apply-templates />
    </xsl:element>
  </xsl:template>

  <xsl:template match="emphasis">
    <xsl:variable name="elementName">
      <xsl:choose>
        <xsl:when test="@type='bold'">
          <xsl:text>b</xsl:text>
        </xsl:when>
        <xsl:when test="@type='italic'">
          <xsl:text>i</xsl:text>
        </xsl:when>
      </xsl:choose>    
    </xsl:variable>
    <xsl:if test="string-length($elementName)>0">
      <xsl:element name="{$elementName}">
        <xsl:apply-templates />
      </xsl:element>
    </xsl:if>
  </xsl:template>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

使用XSLT修改嵌入在其他元素的文本中的元素

2 个答案: