Question

如何将haxe.Int64转换为Float？

我有类似的东西

var x = haxe.Int64.parseString("1000000000000");

，我想将其转换为Float。我看过the Int64 api docs，发现了fromFloat，ofInt和toInt，但是里面没有toFloat方法。

Answer 1

我检查了Int64和Int64Helper，也看不到Haxe标准库中的功能。

但是MIT许可的thx.core库确实包含一个实现，请参见下文：https://github.com/fponticelli/thx.core/blob/master/src/thx/Int64s.hx#L137

using haxe.Int64;

class Int64s {

  static var zero = Int64.make(0, 0);
  static var one = Int64.make(0, 1);
  static var min = Int64.make(0x80000000, 0);

/**
Converts an `Int64` to `Float`;
Implementation by Elliott Stoneham.
*/
  public static function toFloat(i : Int64) : Float {
    var isNegative = false;
    if(i < 0) {
      if(i < min)
        return -9223372036854775808.0; // most -ve value can't be made +ve
      isNegative = true;
      i = -i;
    }
    var multiplier = 1.0,
        ret = 0.0;
    for(_ in 0...64) {
      if(i.and(one) != zero)
        ret += multiplier;
      multiplier *= 2.0;
      i = i.shr(1);
    }
    return (isNegative ? -1 : 1) * ret;
  }
}

使用对我有用的库方法，并在JavaScript目标上进行了如下测试：

import haxe.Int64;
import thx.Int64s;

class Main {    
    public static function main():Void {
        var x:Int64 = haxe.Int64.parseString("1000000000000");
        var f:Float = thx.Int64s.toFloat(x);
        trace(f); // Prints 1000000000000 to console (on js target)
    }
}

Answer 2

您可能想尝试使用FPHelper类。它包含一组将Int类型转换为Float / Double的方法。

import haxe.io.FPHelper;

class Test {
    static function main() {
        var x = haxe.Int64.parseString("1000000000000");
        var f = FPHelper.i64ToDouble(x.low, x.high);
        trace(f);
    }
}

请参见https://try.haxe.org/#CDa93

Answer 3

或者，您可以通过组合上半部分/下半部分将Int64转换为Float：

class Test {
  static function main() {
    var x = haxe.Int64.parseString("1000000000000");
    var f = x.high * 4294967296. + (x.low >>> 0);
    trace("" + x);
    trace(f);
  }
}

在这里， 4294967296.是无符号2 ^ 32的浮点文字；
>>> 0是必需的，因为下半部分可以签名。

Answer 4

或者，对于天真的转换方法，您可以使用：

var f = Std.parseFloat(haxe.Int64.toStr(x));

将haxe.Int64转换为Float吗？

4 个答案: