Question

我正在使用xsl：for-each循环根据元素的@id属性对元素进行排序。我需要获取循环中上一个和下一个元素的@id属性。

我一直在尝试使用前兄弟::和后兄弟轴，但无济于事。我也尝试过

<xsl:variable name="current_pos" select="position()"/>
<xsl:value-of select="(//chapter)[($current_pos - 1)]/id>

但这将返回未排序数据的属性值。

示例XML数据：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <chapter id="t19"/>
    <chapter id="a23"/>
    <chapter id="c-0"/>
    <chapter id="d42"/>
    <chapter id="c-1"/>
</root>

XSLT样式表示例：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="3.0">

    <xsl:template match="/root">
        <xsl:for-each select="chapter">
            <xsl:sort select="@id"/>
            <xsl:variable name="current_id" select="@id"/>
            Chapter id: <xsl:value-of select="$current_id"/>
            Sorted position: <xsl:value-of select="position()"/>
            Sorted predecessor chapter id: ? <!-- no idea but most important -->
            Sorted follower chapter id: ? <!-- no idea but most important -->
            <xsl:text>&#xa;</xsl:text>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

我需要的结果：

Chapter id: a23
Sorted position: 1
Sorted predecessor chapter id: none 
Sorted follower chapter id: c-0

Chapter id: c-0
Sorted position: 2
Sorted predecessor chapter id: a23 
Sorted follower chapter id: c-1     

Chapter id: c-1
Sorted position: 3
Sorted predecessor chapter id: c-0 
Sorted follower chapter id: d42

Chapter id: d42
Sorted position: 4
Sorted predecessor chapter id: c-1 
Sorted follower chapter id: t19

Chapter id: t19
Sorted position: 5
Sorted predecessor chapter id: d42 
Sorted follower chapter id: none

Answer 1

您无法在xsl:for-each循环中获取前一个和/或后一个元素，因为严格来说xsl:for-each并不是一个循环，而是一个映射构造。

您可以做的是将排序结果保存在变量中，就像这样。...

<xsl:variable name="chapters" as="element()*">
     <xsl:perform-sort select="chapter">
        <xsl:sort select="@id"/>
    </xsl:perform-sort>
</xsl:variable>

然后您可以对此使用xsl:for-each，并访问chapters变量本身中的上一个和下一个值。

<xsl:value-of select="$chapters[position() = $current_pos - 1]/@id" />

尝试使用此XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="3.0">

    <xsl:template match="/root">
        <xsl:variable name="chapters" as="element()*">
            <xsl:perform-sort select="chapter">
                <xsl:sort select="@id"/>
            </xsl:perform-sort>
        </xsl:variable>
        <xsl:for-each select="$chapters">
            <xsl:variable name="current_id" select="@id"/>
            <xsl:variable name="current_pos" select="position()"/>
            Chapter id: <xsl:value-of select="$current_id"/>
            Sorted position: <xsl:value-of select="position()"/>
            Sorted predecessor chapter id: <xsl:value-of select="$chapters[position() = $current_pos - 1]/@id" />
            Sorted follower chapter id: ? <xsl:value-of select="$chapters[position() = $current_pos + 1]/@id" />
            <xsl:text>&#xa;</xsl:text>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

如何从已排序的xsl：for-each循环中的上一个和下一个元素访问值

1 个答案: