Question

我正在将字符串和哈希传递给子例程，在该子例程中，哈希被接受为对该子例程的引用。在子例程调用的结尾，我希望我的哈希值被填充。快照：

#!/usr/local/bin/perl5.8

sub passHashAndFile {
  my ($file, $hashRef) = @_;
  open(HANDLE, $file) or die("Can not open file $file \n");
    while(<HANDLE>) {
      my @splitted_values = split("--", $_);
      $hashRef->{$spllited_values[0]} = $hashRef->{$spllited_values[1]};
    }
  close(HANDLE);
}

my %hash;
passHashAndFile("test.txt", %hash);
foreach my $elem (keys %hash) {
  print "Key = $elem, Value = $hash{$elem}\n";
}

我的test.txt看起来像这样：

1--2
3--4
5--6
7--8

我捕获哈希作为参考，然后对其取消引用以填充值。怎么了？

Answer 1

passHashAndFile("test.txt", %hash);

应该是

passHashAndFile("test.txt", \%hash);

此外，您使用了错误的变量名，分配了错误的值，使用的是未本地化的全局变量，并且使用了有问题的2-arg open。而且，大多数人都会让sub返回一个哈希引用，而不是将引用带到一个空哈希。

#!/usr/local/bin/perl5.8

use strict;
use warnings;

sub parse_file {
   my ($qfn) = @_;
   open(my $fh, '<', $qfn)
      or die("Can't open file \"$qfn\": $!\n");

   my %hash;
   while (my $line = <$fh>) {
      my ($key, $val) = split(/--/, $line);
      $hash{$key} = $val;
   }

   return \%hash;
}

my $hash = parse_file("test.txt");
for my $key (keys %$hash) {
   print "Key = $key, Value = $hash->{$key}\n";
}

我们通常不回答，但总是使用use strict; use warnings;。它将发现至少一个问题。

将字符串和哈希引用传递给子例程

1 个答案: