Question

我发现这篇关于在正则表达式中使用活动模式的有用文章： http://www.markhneedham.com/blog/2009/05/10/f-regular-expressionsactive-patterns/

文章中使用的原始代码段是：

open System.Text.RegularExpressions

let (|Match|_|) pattern input =
    let m = Regex.Match(input, pattern) in
    if m.Success then Some (List.tl [ for g in m.Groups -> g.Value ]) else None

let ContainsUrl value = 
    match value with
        | Match "(http:\/\/\S+)" result -> Some(result.Head)
        | _ -> None

如果找到至少一个网址以及该网址是什么（如果我正确理解了该代码段），那么会告诉您

然后在评论部分，Joel提出了这个修改：

替代方案，因为给定的组可以或者可能不是一场成功的比赛：
List.tail [ for g in m.Groups -> if g.Success then Some g.Value else None ]
或许你给你的标签组和您想要访问它们名：
(re.GetGroupNames()
 |> Seq.map (fun n -> (n, m.Groups.[n]))
 |> Seq.filter (fun (n, g) -> g.Success)
 |> Seq.map (fun (n, g) -> (n, g.Value))
 |> Map.ofSeq)

在尝试将所有这些结合起来之后，我想出了以下代码：

let testString = "http://www.bob.com http://www.b.com http://www.bob.com http://www.bill.com"

let (|Match|_|) pattern input =
    let re = new Regex(pattern)
    let m = re.Match(input) in
    if m.Success then Some ((re.GetGroupNames()
                                |> Seq.map (fun n -> (n, m.Groups.[n]))
                                |> Seq.filter (fun (n, g) -> g.Success)
                                |> Seq.map (fun (n, g) -> (n, g.Value))
                                |> Map.ofSeq)) else None

let GroupMatches stringToSearch = 
    match stringToSearch with
        | Match "(http:\/\/\S+)" result -> printfn "%A" result
        | _ -> ()


GroupMatches testString;;

当我在交互式会话中运行我的代码时，这就是输出：

map [("0", "http://www.bob.com"); ("1", "http://www.bob.com")]

我想要实现的结果看起来像这样：

map [("http://www.bob.com", 2); ("http://www.b.com", 1); ("http://www.bill.com", 1);]

基本上是找到每个唯一匹配的映射，然后是在文本中找到特定匹配字符串的次数的计数。

如果您认为我走错了路，请随意提出完全不同的方法。我对Active Patterns和Regular Expressions都不熟悉，所以我不知道从哪里开始尝试解决这个问题。

我也想出了这个，这基本上就是我在C＃翻译成F＃时所做的。

let testString = "http://www.bob.com http://www.b.com http://www.bob.com http://www.bill.com"

let matches =
    let matchDictionary = new Dictionary<string,int>()
    for mtch in (Regex.Matches(testString, "(http:\/\/\S+)")) do
        for m in mtch.Captures do
            if(matchDictionary.ContainsKey(m.Value)) then
                matchDictionary.Item(m.Value) <- matchDictionary.Item(m.Value) + 1
            else
                matchDictionary.Add(m.Value, 1)
    matchDictionary

运行时会返回此信息：

val matches : Dictionary = dict [("http://www.bob.com", 2); ("http://www.b.com", 1); ("http://www.bill.com", 1)]

这基本上是我正在寻找的结果，但我正在尝试学习这种功能的方法，我认为应该包括活动模式。如果它比我的第一次尝试更有意义，请随意尝试“功能化”。

提前致谢，

鲍勃

Answer 1

有趣的东西，我认为你在这里探索的一切都是有效的。（部分）正则表达式匹配的活动模式确实非常有效。特别是当你有一个字符串，你想要匹配多个替代案例。对于更复杂的正则表达式活动模式，我唯一建议的是，为它们提供更具描述性的名称，可能会构建一组具有不同用途的不同正则表达式活动模式。

至于你的C＃到F＃的例子，你可以在没有活动模式的情况下使用功能解决方案，例如。

let testString = "http://www.bob.com http://www.b.com http://www.bob.com http://www.bill.com"

let matches input =
    Regex.Matches(input, "(http:\/\/\S+)") 
    |> Seq.cast<Match>
    |> Seq.groupBy (fun m -> m.Value)
    |> Seq.map (fun (value, groups) -> value, (groups |> Seq.length))

//FSI output:
> matches testString;;
val it : seq<string * int> =
  seq
    [("http://www.bob.com", 2); ("http://www.b.com", 1);
     ("http://www.bill.com", 1)]

<强>更新

这个特定示例在没有活动模式的情况下正常工作的原因是因为1）您只测试一个模式，2）您正在动态处理匹配。

对于活动模式的真实示例，让我们考虑一种情况：1）我们正在测试多个正则表达式，2）我们正在测试一个与多个组的正则表达式匹配。对于这些场景，我使用以下两个活动模式，这些模式比您显示的第一个Match活动模式更通用（我不会丢弃匹配中的第一个组，并返回Group对象的列表，而不仅仅是它们的值 - 一个使用编译的正则表达式选项用于静态正则表达式模式，一个使用解释的正则表达式选项用于动态正则表达式模式）。因为.NET regex API是如此功能填充，所以从活动模式返回的内容实际上取决于您认为有用的内容。但是返回某事的list是好的，因为那样你就可以在该列表上进行模式匹配。

let (|InterpretedMatch|_|) pattern input =
    if input = null then None
    else
        let m = Regex.Match(input, pattern)
        if m.Success then Some [for x in m.Groups -> x]
        else None

///Match the pattern using a cached compiled Regex
let (|CompiledMatch|_|) pattern input =
    if input = null then None
    else
        let m = Regex.Match(input, pattern, RegexOptions.Compiled)
        if m.Success then Some [for x in m.Groups -> x]
        else None

另请注意这些活动模式如何将null视为不匹配，而不是抛出异常。

好的，我们假设我们要解析名称。我们有以下要求：

必须有名字和姓氏
可能有中间名
首先，可选的中间名和姓氏按顺序用一个空格分隔
名称的每个部分可以包含至少一个或多个字母或数字的任意组合
输入可能格式不正确

首先我们将定义以下记录：

type Name = {First:string; Middle:option<string>; Last:string}

然后我们可以在解析名称的函数中非常有效地使用我们的正则表达式活动模式：

let parseName name =
    match name with
    | CompiledMatch @"^(\w+) (\w+) (\w+)$" [_; first; middle; last] ->
        Some({First=first.Value; Middle=Some(middle.Value); Last=last.Value})
    | CompiledMatch @"^(\w+) (\w+)$" [_; first; last] ->
        Some({First=first.Value; Middle=None; Last=last.Value})
    | _ -> 
        None

注意我们在这里获得的一个关键优势，一般是模式匹配的情况是，我们能够同时测试输入是否匹配正则表达式模式，并且如果确实如此，则分解返回的组列表。

F＃使用活动模式映射正则表达式匹配

1 个答案: