Question

我有一个带有两个多方法（multi submit）的类。

我这样叫我的多人游戏：

$perspective.submit(:message($message.content));

哪个班级要下课？

my $perspective-api = API::Perspective.new(:api-key(%*ENV<PERSPECTIVE_API_KEY>));

proto method submit (|) {*}

multi method submit(Str :$message!, MODEL :@models = TOXICITY) {
    my $score = $perspective-api.analyze(:@models, :comment($message));
    say @models Z=> $score<attributeScores>{@models}.map: *<summaryScore><value>;

multi method submit(Str :$name!, MODEL :@models = TOXICITY) {
    my $score = $perspective-api.analyze(:@models, :comment($name));
    say @models Z=> $score<attributeScores>{@models}.map: *<summaryScore><value>;
}

但是我总是收到以下答复：

Died because of the exception:
    Cannot resolve caller AUTOGEN(Rose::ContentAnalysis::Perspective:D: :message(Str)); none of these signatures match:
        (Rose::ContentAnalysis::Perspective: Str :$message!, MODEL :@models = MODEL::TOXICITY, *%_)
        (Rose::ContentAnalysis::Perspective: Str :$name!, MODEL :@models = MODEL::TOXICITY, *%_)

尽管我的命名参数（:message）根据需要是Str，并且@models具有默认声明。

Answer 1

多个调度工作分两个阶段进行：

考虑位置参数的数量及其类型
如果有任何where子句，命名参数或子签名，请对签名进行测试绑定以查看其是否匹配

如果候选者由于任何原因未能绑定，第二阶段将拒绝该候选者。这样的原因之一，我相信是造成此问题的原因，是默认值输入错误。例如，在：

multi m(:@x = "not-an-array") { }
m()

我们收到一个错误：

Cannot resolve caller m(...); none of these signatures match:
    (:@x = "not-an-array")
  in block <unit> at -e line 1

但是将其更改为：

multi m(:@x = ["an-array"]) { }
m()

工作正常。（请注意，尽管默认值使用=，但实际上是绑定，而不是赋值。）

问题中的情况是这样的：

MODEL :@models = TOXICITY

看一下从中获取代码的模块源代码，

enum MODEL is export (
        <TOXICITY SEVERE_TOXICITY TOXICITY_FAST IDENTITY_ATTACK
        INSULT PROFANITY SEXUALLY_EXPLICIT THREAT FLIRTATION
        ATTACK_ON_AUTHOR ATTACK_ON_COMMENTER INCOHERENT INFLAMMATORY
        LIKELY_TO_REJECT OBSCENE SPAM UNSUBSTANTIAL>
);

因此，毒性只是Int，但是期望的是MODEL值的类型化数组。

因此，如果您这样做：

multi method submit(Str :$message!, MODEL :@models = Array[MODEL](TOXICITY)) {

应该可以。

Answer 2

我看到两个问题。

一个是您有两个方法相同，只是一个命名参数的名称相同。

命名参数可以具有别名：

#                       V--------------V
multi method submit(Str :name(:$message)!, MODEL :@models = TOXICITY) {
    my $score = $perspective-api.analyze(:@models, :comment($message));
    say @models Z=> $score<attributeScores>{@models}.map: *<summaryScore><value>;
}

请注意，:$message实际上是:message($message)的缩写

现在要解决实际上使您的代码无法正常工作的问题。

@models是 Positional ，但是您在签名中为其分配了单数。

为其分配一个 Positional ，它可以正常工作：
（在这种情况下，由于必须使用Array[MODEL]类型声明，因此必须为MODEL类型。）

#                                                           V---------------------V
multi method submit(Str :name(:$message)!, MODEL :@models = Array[MODEL](TOXICITY,)) {
    my $score = $perspective-api.analyze(:@models, :comment($message));
    say @models Z=> $score<attributeScores>{@models}.map: *<summaryScore><value>;
}

Perl 6多种方法永远不会匹配预期的签名

2 个答案: