Question

我有使用此方法的套接字服务器：

@impl true
def handle_call({:tcp, socket, packet}, state) do
  Logger.info("Received packet: \x02#{packet}\x03 and send response")
  {:reply, {:ok, packet}, state}
end

我用python编写了向套接字发送“ \ x02Test \ x03”的脚本：

import socket
s = socket.socket(socket.AF_INET, socket.SOCK_STREAM)
s.connect(("127.0.0.1", port))
s.send("\x02Test\x03".encode())
print(s.recv(1024))

但是python打印的响应是b'\ x02 \ x02Test \ x03 \ x03'

Answer 1

handle_call()与gen_tcp有什么关系？

可以将

gen_tcp配置为从套接字和send()消息中读取任何称为:gen_tcp.accept()的进程，即所谓的控制进程。 gen_server;但是gen_server处理通过handle_info()而不是handle_call()发送到其邮箱的邮件。 handle_call()处理:gen_server.call()发送的邮件。

这里是an example：

defmodule TcpServer do
  use GenServer
  require Logger

  def start_link() do
    ip = Application.get_env :gen_tcp, :ip, {127,0,0,1}
    port = Application.get_env :gen_tcp, :port, 6666
    IO.puts "gen_tcp is listening on port: #{port}"
    GenServer.start_link(__MODULE__, {ip, port},[])
  end

  def init({ip, port}) do
    {:ok, listen_socket}= :gen_tcp.listen(
      port,
      [:binary, {:packet,0}, {:active,true}, {:ip,ip}]
    )

    {:ok, socket } = :gen_tcp.accept listen_socket
    {:ok, %{ip: ip, port: port, socket: socket} }
  end

  def handle_call({:tcp, _socket, packet}, state) do
    Logger.info("handle_call(): Received packet: #{inspect packet}")
    {:reply, {:ok, packet}, state}
  end

  def handle_info({:tcp,socket,packet},state) do
      Logger.info "handle_info(:tcp, ...): incoming packet: #{inspect packet}"
      :gen_tcp.send(socket, "****#{packet}*****")
      {:noreply,state}
  end   
  def handle_info({:tcp_closed, _socket}, state) do
    Logger.info("handle_info({:tcp_closed, ...): Client closed socket.")
    {:noreply, state}
  end   
  def handle_info({:tcp_error, socket, reason}, state) do
    Logger.info("Connection closed due to #{reason}: #{socket}")
    {:noreply,state}
  end

end

要启动服务器：

~/elixir_programs/tcp_server$ iex -S mix
Erlang/OTP 20 [erts-9.3] [source] [64-bit] [smp:4:4] [ds:4:4:10] [async-threads:10] [hipe] [kernel-poll:false]
Interactive Elixir (1.8.2) - press Ctrl+C to exit (type h() ENTER for help)

iex(1)> TcpServer.start_link()
gen_tcp is listening on port: 6666

在另一个终端窗口中：

~/python_programs$ cat 5.py

import socket

port = 6666
s = socket.socket(socket.AF_INET, socket.SOCK_STREAM)
s.connect(("127.0.0.1", port))
s.send("\x02Test\x03".encode())
print(s.recv(1024))

~/python_programs$ p36 5.py 
b'****\x02Test\x03*****'

~/python_programs$

如您所见，\x02和\x03字符没有重复。

返回服务器窗口：

{:ok, #PID<0.123.0>}
iex(2)> 
21:54:18.363 [info]  handle_info(:tcp, ...): incoming packet: <<2, 84, 101, 115, 116, 3>>

21:54:18.369 [info]  handle_info({:tcp_closed, ...): Client closed socket.

您是否还有另一个进程是控制进程并且正在调用:gen_server.call({:tcp, socket, packet})？

顺便说一下，在这段代码中：

def handle_info({:tcp,socket,packet},state) do

packet可以是整个数据包，1/2数据包或1/10。这就是套接字的工作方式。配置选项{packet, 0}告诉gen_tcp数据包的开头没有长度头（0字节），而{packet, 1|2|4}告诉gen_tcp数据包的长度为分别包含在第一个字节，前2个字节或前4个字节中。这样，gen_tcp可以读取前1|2|4个字节来获取数据包长度，例如L，然后继续从套接字读取直到接收到L个字节。然后gen_tcp将这些片段打包成一条消息，然后将整个消息发送到gen_server。另一方面，当您指定{packet, 0}时，您是在告诉gen_tcp数据包没有长度头。并且由于套接字将单个数据包拆分为不确定数量的块，因此gen_tcp不知道数据包的末尾在哪里，因此gen_tcp的唯一选择是从套接字读取一个数据块并将块发送给gen_server;然后读取另一个块，并将该块发送到gen_server等，以此类推。这意味着gen_server必须找出数据包的末尾在哪里。

因此，您的服务器和客户端必须在协议上达成共识，以信号通知数据包结束；并且handle_info(:tcp, ...)必须将数据包的各个部分存储在state（或db中），直到读取构成数据包的所有块为止。

您可以用来表示数据包结束的一种协议是：客户端关闭套接字。在这种情况下，

def handle_info({:tcp_closed, _socket}, state)

将被调用，并且在该函数子句中，您可以将存储在state（或db中）中的块组装成完整的消息，然后执行必要的操作，例如将消息发送回客户端。

如果您将STX和ETX用作开始消息，结束消息协议，则handle_info(:tcp, ...)仍将不得不寻找STX字符以表明它应该开始将块存储在state中，并且当handle_info(:tcp, ...)在其中找到带有ETX字符的块时，则必须汇编整个消息。

Elixir套接字在响应中复制了STX和ETX

1 个答案: