PowerQuery将记录列表转换为定界字符串

Question

鉴于以下JSON，我正尝试将其加载到Excel中。我想将“评级”部分格式化为单个分​​隔的字符串/单元格。我对PowerQuery来说还很陌生，所以我很难做到这一点。我已经设法将“记录”列表格式化为自己的表，但是将其连接成字符串并将其重新添加到源表中就是我在此处绘制空白的地方。任何帮助将不胜感激。

PowerQuery

let
    Source = Json.Document(File.Contents("C:\filename.json")),
    Ratings1 = Source[Ratings],
    #"Converted to Table" = Table.FromList(Ratings1, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    LastStep = Table.ExpandRecordColumn(#"Converted to Table", "Column1", { "Source", "Value" })
in
    LastStep

JSON

{
    "Title": "Iron Man",
    "Year": "2008",
    "Rated": "PG-13",
    "Ratings": [{
            "Source": "Internet Movie Database",
            "Value": "7.9/10"
        }, {
            "Source": "Rotten Tomatoes",
            "Value": "93%"
        }, {
            "Source": "Metacritic",
            "Value": "79/100"
        }
    ]
}

最终，像下面这样会很理想。

Answer 1

怎么样？

let
    Source = Json.Document(File.Contents("C:\filename.json")),
    #"Converted to Table" = Record.ToTable(Source),
    #"Transposed Table" = Table.Transpose(#"Converted to Table"),
    #"Promoted Headers" = Table.PromoteHeaders(#"Transposed Table", [PromoteAllScalars=true]),
    #"Changed Type" = Table.TransformColumnTypes(#"Promoted Headers",{{"Title", type text}, {"Rated", type text}, {"Year", Int64.Type}}),
    #"Expanded Ratings" = Table.ExpandListColumn(#"Changed Type", "Ratings"),
    #"Expanded Ratings1" = Table.ExpandRecordColumn(#"Expanded Ratings", "Ratings", {"Source", "Value"}, {"Source", "Value"}),
    #"Added Custom" = Table.AddColumn(#"Expanded Ratings1", "Custom", each [Source] & "=" & [Value]),
    #"Grouped Rows" = Table.Group(#"Added Custom", {"Title", "Year", "Rated"}, {{"Ratings", each Text.Combine([Custom],"#(lf)"), type text}})
in
    #"Grouped Rows"

merge

这里的大多数步骤从名称上都非常清楚，并且是通过GUI控件生成的。一个棘手的步骤是在进行分组时使用自定义聚合器。如果使用GUI，则“分组依据”对话框中的选项不是Text.Combine，因此我选择了Max（在代码中变为List.Max），并用Text.Combine代替了换行符作为分隔符。

Answer 2

与管道字符连接到列中。那是你想要的吗？

let
Source = Json.Document(File.Contents("C:\temp\filename.json")),
Ratings1 = Source[Ratings],
#"Converted to Table" = Table.FromList(Ratings1, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
LastStep = Table.ExpandRecordColumn(#"Converted to Table", "Column1", { "Source", "Value" }),
#"Added Custom" = Table.AddColumn(LastStep, "Concat", each [Source]&"|"&[Value]),
#"Removed Other Columns" = Table.SelectColumns(#"Added Custom",{"Concat"})
in #"Removed Other Columns"