Question

可能重复：
Get just the Date from grouping in select from DateTime column in SQL Server

如何才能获得DateTime的Date部分？我正在寻找像year（）函数这样的东西但是整个日期。

Answer 1

这也可能有所帮助：

SELECT convert(varchar, getdate(), 100) -- mon dd yyyy hh:mmAM (or PM)
                                        -- Oct  2 2008 11:01AM
SELECT convert(varchar, getdate(), 101) -- mm/dd/yyyy - 10/02/2008                  
SELECT convert(varchar, getdate(), 102) -- yyyy.mm.dd – 2008.10.02           
SELECT convert(varchar, getdate(), 103) -- dd/mm/yyyy
SELECT convert(varchar, getdate(), 104) -- dd.mm.yyyy
SELECT convert(varchar, getdate(), 105) -- dd-mm-yyyy
SELECT convert(varchar, getdate(), 106) -- dd mon yyyy
SELECT convert(varchar, getdate(), 107) -- mon dd, yyyy
SELECT convert(varchar, getdate(), 108) --  hh:mm:ss
SELECT convert(varchar, getdate(), 109) -- mon dd yyyy hh:mm:ss:mmmAM (or PM)
                                        -- Oct  2 2008 11:02:44:013AM   
SELECT convert(varchar, getdate(), 110) -- mm-dd-yyyy
SELECT convert(varchar, getdate(), 111) -- yyyy/mm/dd
SELECT convert(varchar, getdate(), 112) -- yyyymmdd
SELECT convert(varchar, getdate(), 113) -- dd mon yyyy hh:mm:ss:mmm
                                        --  02 Oct 2008 11:02:07:577     
SELECT convert(varchar, getdate(), 114) -- hh:mm:ss:mmm(24h)
SELECT convert(varchar, getdate(), 120) -- yyyy-mm-dd hh:mm:ss(24h)
SELECT convert(varchar, getdate(), 121) --  yyyy-mm-dd hh:mm:ss.mmm
SELECT convert(varchar, getdate(), 126) -- yyyy-mm-ddThh:mm:ss.mmm
                                        --  2008-10-02T10:52:47.513
-- SQL create different date styles with t-sql string functions
SELECT replace(convert(varchar, getdate(), 111), '/', ' ') -- yyyy mm dd
SELECT convert(varchar(7), getdate(), 126)                 -- yyyy-mm
SELECT right(convert(varchar, getdate(), 106), 8)          -- mon yyyy

The Source

Answer 2

您想要的解决方案是这里提出的解决方案：

https://stackoverflow.com/a/542802/50776

基本上，你这样做：

cast(floor(cast(@dateVariable as float)) as datetime)

链接中有一个功能定义，允许您合并功能并在任何地方调用它（而不是必须记住它）。

Answer 3

另一种漂亮的方式是：

DATEADD(dd, 0, DATEDIFF(dd, 0, [YourDate]))

从第0天到YourDate获取天数，并将其添加到第0天再次设置基线。此方法（或其“衍生物”）可用于一堆其他日期操作。

编辑 - 其他日期计算：

每月的第一天：

DATEADD(mm, DATEDIFF(mm, 0, getdate()), 0)

年度第一天：

DATEADD(yy, DATEDIFF(yy, 0, getdate()), 0)

本季度的第一天：

DATEADD(qq, DATEDIFF(qq, 0, getdate()), 0)

上个月的最后一天：

DATEADD(ms, -3, DATEADD(mm, DATEDIFF(mm, 0, getdate()), 0))

本月最后一天：

DATEADD(ms, -3, DATEADD(mm, DATEDIFF(m, 0, getdate()) + 1, 0))

本年度的最后一天：

DATEADD(ms, -3, DATEADD(yy, DATEDIFF(yy, 0, getdate()) + 1, 0))

本月的第一个星期一：

DATEADD(wk, DATEDIFF(wk, 0, DATEADD(dd, 6 - DATEPART(day, getdate()), getdate())), 0)

编辑：是的，乔，它没有将它添加到第0天，它将0（天）添加到基本上只是将其转换回日期时间的天数。

Answer 4

我们可以使用这种方法：

CONVERT(VARCHAR(10), GETDATE(), 120)

最后一个参数将格式更改为仅以特定格式获取时间或日期。

Answer 5

这可能不像单行，但我用它来主要为报告执行日期操作：

DECLARE @Date datetime
SET @Date = GETDATE()

-- Set all time components to zero
SET @Date = DATEADD(ms, -DATEPART(ms, @Date), @Date) -- milliseconds = 0
SET @Date = DATEADD(ss, -DATEPART(ss, @Date), @Date) -- seconds = 0
SET @Date = DATEADD(mi, -DATEPART(mi, @Date), @Date) -- minutes = 0
SET @Date = DATEADD(hh, -DATEPART(hh, @Date), @Date) -- hours = 0

-- Extra manipulation for month and year
SET @Date = DATEADD(dd, -DATEPART(dd, @Date) + 1, @Date) -- day = 1
SET @Date = DATEADD(mm, -DATEPART(mm, @Date) + 1, @Date) -- month = 1

我用它来获取用于报告和绩效指标等的每小时，每日，每月和每年的日期。

在mssql中只获取DateTime的Date部分

5 个答案: