VBA Dictionary.Exists方法从字符串数组返回错误的负负给定字符串

时间：2019-06-11 17:58:25

标签： excel vba

我正在将位于字符串数组中的字符串类型的键传递给scripting.dictionary.exists（key）方法，该方法返回假否定值。我希望它正确地返回一个布尔值，以便可以确定每个业务流程密钥是否有效。有效值存储在字典中。

我已经检查以确保字典的比较模式为TextCompare，这没有关系，因为事实证明字典和数组中字符串的大小写是相同的。我还确保变量类型都是字符串（8）。另外，我确保字符串数组和字典中的字符串相同。最后，我检查以确保如果直接将字符串输入到参数中而不是通过数组的引用将其传递给参数，则该方法也将返回假阳性结果。

Function fvalidatedata(saInput() As String) As String()

    Dim dInvalidRecords As Scripting.Dictionary, _
        dValidDisputeStatuses As Scripting.Dictionary, dDisputeStatusErrorMap As Scripting.Dictionary, _
        dValidReasonCodes As Scripting.Dictionary, dReasonCodeAbbrevMap As Scripting.Dictionary, _
        saListBoxValues() As String, i As Long, ii As Long, frmIRC As New ufInvalidReasonCode

    Set dInvalidRecords = New Scripting.Dictionary
    Set dValidDisputeStatuses = New Scripting.Dictionary
    Set dDisputeStatusErrorMap = New Scripting.Dictionary
    Set dValidReasonCodes = New Scripting.Dictionary
    Set dReasonCodeAbbrevMap = New Scripting.Dictionary

    dInvalidRecords.CompareMode = BinaryCompare
    dValidDisputeStatuses.CompareMode = TextCompare
    dDisputeStatusErrorMap.CompareMode = TextCompare
    dValidReasonCodes.CompareMode = BinaryCompare
    dReasonCodeAbbrevMap.CompareMode = BinaryCompare

    Set dValidDisputeStatuses = fValidDisputeStatusMap
    Set dDisputeStatusErrorMap = fDisputeStatusErrorMap
    Set dValidReasonCodes = fValidReasonCodes
    Set dReasonCodeAbbrevMap = fReasonCodeAbbrevMap

    For i = 2 To UBound(saInput, 1)
        'Dispute Status Validation
            If Not dValidDisputeStatuses.Exists(saInput(i, 12)) Then
                Debug.Print dValidDisputeStatuses.Exists(saInput(i, 12))
                If dDisputeStatusErrorMap.Exists(saInput(i, 12)) Then
                    saInput(i, 12) = dDisputeStatusErrorMap(saInput(i, 12))
                Else
                    ReDim saListBoxValues(0 To dValidDisputeStatuses.Count - 1)
                    For ii = 0 To dValidDisputeStatuses.Count - 1
                        saListBoxValues(ii) = dValidDisputeStatuses.Keys(ii)
                    Next ii
                    frmIRC.ListBox1.List = saListBoxValues
                    frmIRC.l1 = "Please select valid dispute status from the list below for record " & saInput(i, 3) & " and submit once complete."
                    frmIRC.Show vbModeless

                End If
            End If
        'Reason Code Validation
    Next i

End Function
Function fValidDisputeStatusMap() As Scripting.Dictionary

    Dim dMap As Scripting.Dictionary, lo As ListObject, i As Long

    Set dMap = New Scripting.Dictionary
    dMap.CompareMode = TextCompare

    Set lo = Application.Workbooks("RnR_Dispute_Process_Workbook.xlsx").Sheets("Update Dictionary").ListObjects("Valid_Statuses")

    For i = 1 To lo.ListColumns("Valid Statuses").DataBodyRange.Count
        If Not dMap.Exists(lo.ListColumns("Valid Statuses").DataBodyRange(i)) Then
            dMap.Add lo.ListColumns("Valid Statuses").DataBodyRange(i), vbNullString
        End If
    Next i

    Set fValidDisputeStatusMap = dMap

    Set dMap = Nothing

End Function

如果字典中不存在saInput（i，12），我希望（Not dValidDisputeStatuses.Exists（saInput（i，12）））的输出为TRUE，但是确实如此。

2 个答案:

答案 0 :(得分：2)

  

我正在传递字符串类型的键

但是您不是:)实际上是在这里传递Range对象：

If Not dMap.Exists(lo.ListColumns("Valid Statuses").DataBodyRange(i))

碰巧的情况是，Range对象在大多数情况下（例如，在给分配给一个范围时）返回其默认属性（ Cells）返回其默认属性（Value），但是当获取范围时，它并不是那么可靠。

您偶然发现了一个有趣的案例！正如您不经意间观察到的那样，虽然字典中的Keys可以除数组之外的任何东西，但是当您将复杂对象用作Keys时，似乎会发生奇怪的事情。 / p>

  

Dictionary对象等效于PERL关联数组。项目可以是任何形式的数据，都存储在数组中。每个项目都与唯一键相关联。该键用于检索单个项目，通常是整数或字符串，但可以是除数组之外的任何东西。

这是个怪癖：每次引用Range对象时，它都会被分配一个不同的存储位置。您可以很容易地验证这一点：

Dim i as Long
Dim r as Range
For i = 1 to 3
    Set r = Range("A1")
    Debug.Print(ObjPtr(r))
Next

在您的情况下，这意味着Exists方法显然会 失败（即，当它似乎应该返回False时返回True），例如，在上面进行扩展：

Dim i As Long
Dim r As Range
Dim d as Object
Set d = CreateObject("Scripting.Dictionary")
For i = 1 to 3
    Set r = Range("A1")
    d.Add r, i
Next

这将产生一个包含3个唯一键的字典，这些键都是指向 same Range对象的指针！

如果相反，Set分配在循环外部中，则它将在第二次迭代中按预期失败，因为它现在正在尝试添加字典中已经存在的指针。 

Set r = Range("A1")
For i = 1 to 3
    d.Add r, i
Next

这个故事的寓意是：在Object中将Keys类型分配为Dictionary时要小心。

我们可以将Object类型用作Dictionary.Keys吗？

是的，但这似乎是一个更复杂的实现。可能还有其他方法，但是一个显而易见的解决方案（至少对我而言）是先将键构建为数组或集合，然后在测试Dictionary.Exists时遍历该列表。

Sub foo2()

Dim d As Dictionary
Dim r As Range, w As Worksheet
Dim i As Long
Dim keys(1 To 3) As Range
Set d = CreateObject("Scripting.Dictionary")

Set r = Range("A1:A3")
' Create our keys in one place
For i = 1 To r.Cells.Count
    Set keys(i) = r.Cells(i)
Next

' Iterate the KEYS rather than the range
For i = LBound(keys) To UBound(keys)
    d.Add keys(i), i
Next
Debug.Print "The dictionary initially contains " & d.Count & " keys."
'If we test Exist against our keys array, results are as expected:
For i = LBound(keys) To UBound(keys)
    If Not d.Exists(keys(i)) Then
        d.Add r.Cells(i), i
    End If
Next
Debug.Print "The dictionary still contains " & d.Count & " keys."

' Iterate the RANGE now and no error occurs!
For i = 1 To r.Cells.Count
    If Not d.Exists(r.Cells(i)) Then
        d.Add r.Cells(i), i
    End If
Next
' But, our dictionary now has 6 keys, instead of 3!!!
Debug.Print "The dictionary now contains " & d.Count & " keys!"
End Sub

答案 1 :(得分：1)

我知道了：

For i = 1 To lo.ListColumns("Valid Statuses").DataBodyRange.Count
    If Not dMap.Exists(lo.ListColumns("Valid Statuses").DataBodyRange(i)) Then
        dMap.Add lo.ListColumns("Valid Statuses").DataBodyRange(i), vbNullString
    End If
Next i

应该是

For i = 1 To lo.ListColumns("Valid Statuses").DataBodyRange.Count
    If Not dMap.Exists(lo.ListColumns("Valid Statuses").DataBodyRange(i).value2) Then
        dMap.Add lo.ListColumns("Valid Statuses").DataBodyRange(i).value2, vbNullString
    End If
Next i

我引用的是范围而不是值。显然，vartype（）在给定范围值的情况下测试范围内的值。

相关问题
最新问题