.NET事件不可见/无法与vb6（vba）一起使用？

Question

我写了一个vb.net类，我想使VB6对COM可见。我有一个用VB6开发的旧应用程序，并且正在完全为.net重写它，但是与此同时，我需要使此类工作并使其与VB6一起使用。

所有暴露给COM的方法似乎都可以正常工作，但是我无法使该事件与VB6一起使用。我已经搜寻了数周的网络，并且发现了很多信息，这些信息已经帮助我达到了现在的境地。问题是，当我尝试在VB6 IDE的下拉列表中选择类时，IDE直接创建一个事件处理程序（在我的情况下为tc_Pls_changeprice（））。奇怪的是，我无法选择或标记实际的班级，然后从事件下拉列表中选择事件。

如果我不尝试首先选择类，而是直接从事件下拉列表中选择事件，则可以选择它（但它的名称是tc_Pls_changeprice，而不是我期望的Pls_changeprice）

如果选择两次或多次，IDE将生成新的事件处理程序，而不是跳转到已创建的事件处理程序中。

当我尝试将代码放入事件处理程序中时，我的vb6测试应用程序会编译并运行，但事件不会触发。

我已经附加了.net代码和vb6测试应用程序代码。

.dll已被激活ComVisible编译，但未注册为com-interop（因为我需要在其他计算机上注册dll）。我使用regasm / TLB / codebase选项在主机上注册了dll，并且生成的TLB与DLL一起位于与vb6源目录相同的目录中。

重复的事件处理程序：

此图显示事件下拉事件列表有问题，我无法首先从左侧下拉列表中选择类：

有人对出什么问题有任何想法吗？

这是我的该类的.net代码：

Imports System.IO.Ports
Imports System.Timers

<Guid("ABEF0C71-17CE-4d38-BEFD-71770E7D50B4")>
<InterfaceType(ComInterfaceType.InterfaceIsDual)>
<ComVisible(True)>
Public Interface Itaxcomm
    <DispId(1)> Property commport As String
    <DispId(2)> ReadOnly Property taxstatus As String
    <DispId(3)> Function open() As Integer
    <DispId(4)> Function close() As Integer

    <DispId(5)> Sub testevent()

    <DispId(6)> Sub Reset()
    <DispId(7)> Sub ChangepriceOK()
    <DispId(8)> Sub Triggerstartbutton()
    <DispId(9)> Sub TaxState()

End Interface

<Guid("A68C5882-21B2-4827-AA0F-A8D6538D1AE3")>
    <InterfaceType(ComInterfaceType.InterfaceIsIDispatch)>
    <ComVisible(True)>
    Public Interface ItaxcommEvents
    <DispId(10)> Sub Pls_changeprice()
    End Interface


    <ComVisible(True)>
    <ClassInterface(ClassInterfaceType.None)>
    <ComDefaultInterface(GetType(Itaxcomm))>
    <ComSourceInterfaces(GetType(ItaxcommEvents))>
    <Guid("0F998406-B0CF-440a-8A78-262015480C90")>
    <ProgId("Taxcomm.taxcomm")>
    Public Class taxcomm
    Implements Itaxcomm
    Public Status As String
    <ComVisible(False)>
    Public Delegate Sub pls_changepricedelegate()
    Public Event Pls_changeprice As pls_changepricedelegate
    Private _comport As String
    Private _taxmode As String
    Private rxByte(4096) As Byte
    Private WithEvents statetimer As New Timer
    Private WithEvents sp As New SerialPort

        Private Property Itaxcomm_commport As String Implements Itaxcomm.commport

            Get
                Return _comport

            End Get

            Set(ByVal value As String)
                _comport = value

            End Set
        End Property

        Private ReadOnly Property Itaxcomm_taxstatus As String Implements Itaxcomm.taxstatus

            Get
                Return _taxmode


            End Get


        End Property

        Private Sub sp_DataReceived(sender As Object, e As SerialDataReceivedEventArgs) Handles sp.DataReceived
            Dim s As String = ""
            If sp.BytesToRead < 7 Then Exit Sub

            sp.Read(rxByte, 0, 7)
            For i = 0 To 20
                s = s + (rxByte(i).ToString) & " "
            Next i

        If rxByte(0) = &H48 And rxByte(6) = &H54 And rxByte(5) = (rxByte(0) Xor rxByte(1) Xor rxByte(2) Xor rxByte(3) Xor rxByte(4)) Then
                Select Case rxByte(3)
                    Case 0
                        Select Case rxByte(4)
                            Case 0              ''Normal_mode(with tax)
                                _taxmode = 1
                            Case 1              ''!Normal_mode(Ex tax)
                                _taxmode = 0
                        End Select

                    Case 1
                        Select Case rxByte(4)
                            Case 0              ''Pls_changeprice
                                RaiseEvent Pls_changeprice()

                            Case 1
                        End Select
                    Case 253
                        Select Case rxByte(4)
                            Case 0              ''Buffer overflow
                                Status = "Tax rx:Buffer overflow"

                        End Select

                    Case 255
                        Select Case rxByte(4)
                            Case 0

                            Case 1              ''Command unknown
                                Status = "Tax rx:Command unknown"


                            Case 2             ''ERROR_CRC
                                Status = "Tax rx:ERROR or CRC error"

                        End Select
                End Select

            End If
        End Sub
        Private Sub TestEvent() Implements Itaxcomm.testevent
            RaiseEvent Pls_changeprice()

        End Sub
        Private Sub sp_Disposed(sender As Object, e As EventArgs) Handles sp.Disposed

        End Sub

        Private Sub sp_ErrorReceived(sender As Object, e As SerialErrorReceivedEventArgs) Handles sp.ErrorReceived
            Status = "TAX commerror:" & e.ToString
        End Sub

        Private Sub Taxstate() Implements Itaxcomm.TaxState
            Dim txarray = New Byte() {&H16, &H6, &H63, &H1, &H72, &H54}
            sptx(txarray)
        End Sub
        Public Sub Triggerstartbutton() Implements Itaxcomm.Triggerstartbutton
            Dim txarray = New Byte() {&H16, &H6, &H63, &H4, &H77, &H54}
            sptx(txarray)
        End Sub
        Public Sub ChangepriceOK() Implements Itaxcomm.ChangepriceOK
            Dim txarray = New Byte() {&H16, &H6, &H63, &H2, &H71, &H54}
            sptx(txarray)
        End Sub

        Public Sub Reset() Implements Itaxcomm.Reset

            Dim txarray = New Byte() {&H16, &H6, &H63, &H3, &H70, &H54}
            sptx(txarray)
        End Sub

        Private Sub statetimer_Elapsed(sender As Object, e As ElapsedEventArgs) Handles statetimer.Elapsed
            If sp.IsOpen Then Taxstate()
        End Sub
        Private Sub sptx(a() As Byte)
            Do Until sp.BytesToWrite = 0

            Loop
            sp.Write(a, 0, a.Count)
        End Sub

        Public Function open() As Integer Implements Itaxcomm.open
            Try

                sp.BaudRate = 9600
                sp.DataBits = 8
                sp.Handshake = IO.Ports.Handshake.None
                sp.Parity = IO.Ports.Parity.None
                sp.RtsEnable = True
                sp.ReceivedBytesThreshold = 1

                sp.StopBits = IO.Ports.StopBits.One

                If _comport <> "" And Not sp.IsOpen Then
                    sp.PortName = _comport
                    sp.Open()
                    statetimer.Interval = 1000
                    statetimer.Enabled = True
                    Return 0

                Else
                    Return 1
                End If


            Catch ex As Exception
                Status = "Serialport open:" & Err.Description
                Return 1
            End Try
        End Function

        Public Function close() As Integer Implements Itaxcomm.close
            Try
                If sp.IsOpen Then sp.Close()
                statetimer.Enabled = False

                Return 0
            Catch ex As Exception
                Status = "Serialport close:" & Err.Description
                Return 1

            End Try
        End Function
        Public Sub New()
            MyBase.New()
        End Sub
    End Class:

这是我的vb6测试应用程序代码：

Option Explicit

Private WithEvents tc As taxcomm.taxcomm

Private Sub Command1_Click()
On Error GoTo errhandler

tc.Triggerstartbutton
Exit Sub
errhandler:
Text1.Text = Err.Number & Err.Description

End Sub

Private Sub Command2_Click()
On Error GoTo errhandler
tc.Reset
Exit Sub
errhandler:
Text1.Text = Err.Number & Err.Description

End Sub

Private Sub Command3_Click()
tc.testevent

End Sub

Private Sub Form_Load()
On Error GoTo errhandler

Set tc = CreateObject("Taxcomm.taxcomm")

tc.commport = "COM5"
If tc.Open = 0 Then
    MsgBox "Active"

Else
    MsgBox "Not active"
    tc.Close

End If
Exit Sub
errhandler:
MsgBox Err.Number & " " & Err.Description
Resume Next

End Sub


Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
tc.Close

End Sub

Private Sub Form_Terminate()
tc.Close

End Sub


Private Sub tc_Pls_changeprice()
MsgBox "test"
End Sub

Private Sub Timer1_Timer()
On Error GoTo errhandler

Text1.Text = tc.taxstatus
Exit Sub
errhandler:
Text1.Text = Err.Number & Err.Description

tc.Close

End Sub

.net类和vb6测试应用程序应进行编译，但是TLB的生成似乎有问题（由于我的.net代码有问题），因此该事件不会触发，和/或暴露的事件未在VB6 IDE中正确注册。

Answer 1

最初是在评论中，但将其放在此处以明确答案是什么：

令人惊讶的是，我发现在进行一些更高级的COM组件/ COM互操作类型的工作时，VB6在处理方法和事件名称的下划线时有一些限制。这是几年前的事，所以我不记得我具体遇到的痛苦点。有点远，但是只是为了它，尝试重命名事件以避免下划线

Answer 2

我想添加一条评论，但是我缺少必需的声誉点。无论如何，我注意到您的ProgID是“ Taxcomm.taxcomm”，并且您从VB6调用它的方式也与“ taxcomm.taxcomm”不同。我不确定是否区分大小写，但是使用大写T不会丢失任何内容。

除此之外，您还可以尝试将您的库安装到GAC。如果要将应用程序移动到其他计算机，则可以使用安装程序（安装项目/ .msi）将库及其依赖项安装到GAC。下一步是从VB6调用它，就像调用user32.dll，内核等一样。

希望您能找到解决方案！