Question

我有两个二阶ODE，我想使用（与Maple一起）计算它们之间的误差

|| B(t) - A(w*t) || = sqrt(int(B(t) - A(w*t) )^2), t = 0..T)

其中A（t）是对输入没有任何时间变换的系统的解，而B（t）是对输入有时间变换的系统的解（时间变换是wt（w通常很小），T是一个数字，而不是变量。我将更改T以研究不同时间跨度的误差）。

例如（为帮助解释我的问题）：

原始ODE为：

diff(g(t), t, t) = -(diff(g(t), t))-sin(g(t))*cos(g(t))+sin(t)

让A（t）成为原始ODE的NUMERIC解决方案（因为maple无法象征性地解决它）。

现在，ODE在输入中带有时间转换：

diff(y(t), t, t) = -(diff(y(t), t))-sin(y(t))*cos(y(t))+sin(w*t)

让B（t）成为此ODE的NUMERIC解决方案（因为maple无法象征性地解决它）。

我的问题是：对于w的不同值，有什么办法可以解决该错误？为此，我需要在数值求解A（t）之后将A（t）的数值解更改为A（wt）。我的最终目标是绘制误差与频率，即w。当w为1时，应该没有错误，因为系统没有变化。

我对编码还是比较陌生的。因为Maple不能用符号方式求解，所以我要做的是用数值方法求解每个坐标（但是要有一个特定的w。但是，我想对[0..1.5]范围内的w进行求解）。然后我将它们绘制在同一图上。但是，这给了我A（t）而不是A（wt）的数值。而且，我不知道如何减去它们。

sol1 := dsolve([diff(g(t), t, t) = -(diff(g(t), t))- sin(g(t))*cos(g(t))+sin(t), g(0) = 0, (D(g))(0) = 0], numeric);

sol2 := dsolve([diff(y(t), t, t) = -(diff(y(t), t))-sin(y(t))*cos(y(t))+sin(.5*t), y(0) = 0, (D(y))(0) = 0], numeric);

S1 := plots[odeplot](sol1, 0 .. 10, color = red);
S2 := plots[odeplot](sol2, 0 .. 10, color = blue);
display(S1, S2);

但是，这没有帮助，因为它仅绘制A（t），而不绘制A（wt）。同样，它仅作图，并没有显示它们之间的错误。

我希望误差随着频率w接近0而接近0。我确实希望当w在0和1之间时误差会增加。

Answer 1

有多种方法可以做到这一点。有些比其他的更有效率。有些更方便。我会展示一些。

第一种基本方法涉及两次调用dsolve，类似于您的原始代码，但带有额外的output=listprocedure选项。这使得dsolve返回标量值过程的列表，而不是单个过程（后者将返回值的列表）。这使我们可以选择y(t)和g(t)的各个过程，并分别使用它们。

restart;
sol1 := dsolve([diff(g(t), t, t)
                = -(diff(g(t), t))- sin(g(t))*cos(g(t))+sin(t),
                g(0) = 0, (D(g))(0) = 0], numeric,
                output=listprocedure):
sol2 := dsolve([diff(y(t), t, t)
                = -(diff(y(t), t))-sin(y(t))*cos(y(t))+sin(.5*t),
                y(0) = 0, (D(y))(0) = 0], numeric,
                output=listprocedure):

如果愿意，您仍可以在此处使用plots:-odeplot。

S1 := plots:-odeplot(sol1, 0 .. 20, color = red, numpoints=200):
S2 := plots:-odeplot(sol2, 0 .. 20, color = blue, numpoints=200):
plots:-display(S1, S2, size=[400,150]);

但是您也可以提取各个过程，对其进行绘图或对它们的差异进行绘图。

G := eval(g(t),sol1):
Y := eval(y(t),sol2):

plot([G,Y], 0..20, color=[red,blue], size=[400,150]);

它们之间的区别现在更容易绘制。

plot(G-Y, 0..20, color=black, size=[400,150]);

我们可以计算一个范数（您的积分）

sqrt(evalf(Int( t -> ( G(t) - Y(t) )^2, 0..20, epsilon=1e-5)));
         8.74648880831735

但是现在让我们更加方便地将w视为我们即时调整的参数。（我们不想为每个dsolve的值调用w带来成本或不便。）

solgen := dsolve([diff(y(t), t, t)
                 = -(diff(y(t), t))-sin(y(t))*cos(y(t))+sin(w*t),
                 y(0) = 0, (D(y))(0) = 0], numeric,
                 parameters = [w],
                 output=listprocedure):

 Ygen := eval(y(t),solgen):

 # set the parameter value
 Ygen(parameters=[w=0.5]);
                       [w = 0.5]

 # we could query the parameter value
 Ygen(parameters);
                       [w = 0.5]

 # Now call it at a particular value of t
 Ygen(3.2);
                   0.864744459594622

现在，我们构造一个w和t的过程。当不带数字参数调用时，它将返回未评估的值。当使用数字参数调用时，它将检查w值是否与当前存储的参数值匹配，如果不同，它将设置存储的值。然后，它以给定的Ygen值调用计算过程t。

Yw := proc(t,w)
  if not [t,w]::list(numeric) then
    return 'procname'(args);
  end if;
  if w - eval(':-w',Ygen(parameters)) <> 0.0 then
    Ygen(':-parameters'=[':-w'=w]);
  end if;
  Ygen(t);
end proc:

这可以产生与以前相同的图。

plots:-display(
  plot(Yw(t,0.5), t=0..20, color=red),
  plot(Yw(t,1.0), t=0..20, color=blue),
  size=[400,150]
);

# somewhat inefficient since for each t value it
# switches the value of the w parameter.
plot(Yw(t,1.0)-Yw(t,0.5), t=0..20, size=[400,150]);

我们也可以在点图中做（连接线），这是更有效的，因为对于任何给定的t值，所有w值都是按顺序计算的。（即，它不会在w个值之间反弹。）

a,b := 0,20:
xpts := Vector(100,(i)->a+(b-a)*(i-1)/(100-1),datatype=float[8]):
plots:-display(
  plot(<xpts | map(t->Yw(t,0.5), xpts)>, color=red),
  plot(<xpts | map(t->Yw(t,1.0), xpts)>, color=blue),
  size=[400,150]
);

# more efficient since all the Yw values for w=1.0 are
# computed together, and all the Yw values for w=0.5 are
# computed together.
plot(<xpts | map(t->Yw(t,1.0), xpts) - map(t->Yw(t,0.5), xpts)>,
     size=[400,150]);

evalf([seq( ['w'=w, sqrt(Int( unapply( (Yw(t,1.0)
                                         - Yw(t,w))^2, t),
                              0..20, epsilon=1e-1))],
             w=0..1.0, 0.1 )]);

    [[w = 0., 2.97123678486962], [w = 0.1, 20.3172660599286], 

     [w = 0.2, 21.8005838723429], [w = 0.3, 13.0097728518328], 

     [w = 0.4, 9.28961600039575], [w = 0.5, 8.74643983270251], 

     [w = 0.6, 6.27082651159143], [w = 0.7, 5.38965679479886], 

     [w = 0.8, 5.21680809275065], [w = 0.9, 3.19786559349464], 

     [w = 1.0, 0.]]


plot(w->sqrt(Int( (Yw(t,1.0) - Yw(t,w))^2, t=0..20,
                  epsilon=1e-3, method=_d01ajc )),
     0..1, size=[400,150]);

plot3d( Yw(t,w), w=0..1.0, t=0..50, grid=[179,179] );

# For 3D plotting it's also faster to compute all t-values
# for each given w-value, rather than the other way round.
CodeTools:-Usage(
  plot3d( Yw(t,w), w=0..1.0, t=0..50, grid=[49,49] )
):

   memory used=37.51MiB, alloc change=0 bytes, cpu time=504.00ms,
   real time=506.00ms, gc time=127.31ms

CodeTools:-Usage(
  plot3d( Yw(t,w), t=0..50, w=0..1.0, grid=[49,49] ) ):

   memory used=124.13MiB, alloc change=0 bytes, cpu time=2.66s,
   real time=2.66s, gc time=285.47ms

[已编辑] 该规范上方的图并不很快。为了更好的性能，我在下面进行了三项调整： 1）对于w = 1.0，使用专用过程Yw1，以便不会调用Yw来为每次对被积物的求值（在规范中）两次设置参数w。 2）在该过程Yw1上使用“记住选项”。 3）在两个compile=true调用中使用选项dsolve。

我也将规范中的公式更正为Yw1(w*t)，以匹配所讨论的原始公式。

restart;
solw1 := dsolve([diff(y(t), t, t)
             = -(diff(y(t), t))-sin(y(t))*cos(y(t))+sin(t),
             y(0) = 0, (D(y))(0) = 0], numeric,
             compile=true,
             output=listprocedure):
Yw1raw := eval(y(t),solw1):
Yw1 := proc(t)
  option remember;
  if not t::numeric then return 'procname'(args); end if;
  []; # evalhf error that plot will catch
  Yw1raw(t);
end proc:
solgen := dsolve([diff(y(t), t, t)
             = -(diff(y(t), t))-sin(y(t))*cos(y(t))+sin(w*t),
             y(0) = 0, (D(y))(0) = 0], numeric,
             parameters = [w],
             compile=true,
             output=listprocedure):
Ygen := eval(y(t),solgen):
Yw := proc(t,w)
  if not [t,w]::list(numeric) then
    return 'procname'(args);
  end if;
  if w - eval(':-w',Ygen(parameters)) <> 0.0 then
    Ygen(':-parameters'=[':-w'=w]);
  end if;
  Ygen(t);
end proc:

CodeTools:-Usage(
  plot(w->sqrt(Int( (Yw1(w*t) - Yw(t,w))^2, t=0..20,
                    epsilon=1e-3, method=_d01ajc )),
       0..1, size=[400,150])
);

    memory used=0.76GiB, alloc change=205.00MiB,
    cpu time=8.22s, real time=7.78s, gc time=761.80ms

解决了ODE的数值解决方案后如何进行更改？

1 个答案: