Question

我从互联网上搜索过，但我只找到了解决这个问题的php解决方案。如果您知道如何在perl中执行此操作，请提供帮助。

我正在尝试生成一个显示服务器本地磁盘上目录内容的网页。例如，包含以下内容的页面将执行工作

<file name="file1" href="file1" /> <dir name="dir1" href="dir1/" /> <dir name="dir2" href="dir2/" />

感谢您的帮助。

Answer 1

必须进行修改以确保脚本安全并且还可以保护脚本。但是，这个想法可以实现如下：

#!/usr/bin/perl -T

use strict;
use warnings;

use CGI;
use File::Basename;
use File::Spec;
use Path::Trim;

my $cgi = CGI->new();

if ( my $file = $cgi->param('file') ) {
    open my $fh, '<', $file or die $!;

    print $cgi->header(
        '-type'           => 'application/octet-stream',
        '-attachment'     => basename($file),
        '-Content_Length' => -s $file,
    );

    binmode $fh;
    print while <$fh>;
}
else {
    my $path = $cgi->param('path');                                                                

    print $cgi->header(), $cgi->start_html();                                                                                               

    # remove redundant current directory and parent directory entries                                                                       
    my $pt = Path::Trim->new();                                                                                                             
    $pt->set_directory_separator('/');                                                                                                      
    $path = $pt->trim_path($path);                                                                                                          

  # remove all ../ and ./ that have accumulated at the beginning of the path and                                                            
  # make the path absolute by prepending a /                                                                                                
    $path =~ s{^ (\.\.? /)+ }{}x;                                                                                                           
    $path = "/$path" unless $path =~ m{^ / }x;                                                                                              

    print $cgi->h1($path);                                                                                                                  

    opendir my $dh, $path or die $!;                                                                                                        
    my @entries = grep { $_ !~ /^ \. $/x } readdir $dh;
    closedir $dh;

    print $cgi->start_ul();
    for my $entry ( sort { $a cmp $b } @entries ) {
        if ( -d File::Spec->catfile( $path, $entry ) ) {
            my $abs_entry = File::Spec->catfile( $path, $entry );
            my $anchor = $cgi->a( { 'href' => "?path=$abs_entry" }, $entry );
            print $cgi->li($anchor);
        }
        else {
            my $abs_entry = File::Spec->catfile( $path, $entry );
            my $anchor = $cgi->a( { 'href' => "?file=$abs_entry" }, $entry );
            print $cgi->li($anchor);
        }
    }
    print $cgi->end_ul(), $cgi->end_html();
}

Answer 2

这应该让你开始：

#!/usr/bin/perl -Tw

use 5.008_001;
use strict;
use warnings;

print "Content-Type: text/html; charset=utf-8\r\n\r\n";

print <<EOF;
<html>
<head>
<title>Directory Listing</title>
</head>
<body>
<pre>
EOF

opendir(my $dir, ".");
foreach(sort readdir $dir) {
    my $isDir = 0;
    $isDir = 1 if -d $_;

    $_ =~ s/&/&amp;/g;
    $_ =~ s/"/&quot;/g;
    $_ =~ s/</&lt;/g;
    $_ =~ s/>/&gt;/g;

    my $type = "[ ]";
    $type = "[D]" if $isDir;
    print "$type<a href=\"$_\" title=\"$_\">$_</a>\n";
}

print <<EOF;
</pre>
</body>
</html>
EOF

cgi perl脚本列出子目录和文件

2 个答案: