Question

在Scilab 6.0.2的帮助文档中，我可以阅读重载条目上的以下指令，有关该条目表中显示的最后一个操作代码“ iext”：

“ 6个字符的代码可用于某些复杂的插入算法，例如xb（2）= 33，其中在结构x中未定义b字段。插入将自动分解为temp = xb; temp（2）= 33; xb = temp。此算法的第一步使用6个字符的代码。6个重载函数与e的函数非常相似。”

但是我找不到关于如何使用此“ char 6代码”重载功能的完整示例。我正在尝试使用它，但没有成功。有没有人举过一个例子？

Answer 1

下面的代码创建一个普通的“ mlist”作为示例。哪些需要重载功能

A = rand(5,3)
names = ["colA" "colB" "colC"]
units = ["ft"   "in"     "lb"]
M = mlist(["Mlog" "names" "units" names],names,units,A(:,1),A(:,2),A(:,3))

以下是重载函数：

//define display
function %Mlog_p(M)
    n = size(M.names,"*")
    formatStr = strcat(repmat("%10s   ",1,n)) + "\n"
    formatNum = strcat(repmat("%0.10f   ",1,n)) + "\n"
    mprintf(formatStr,M.names)
    mprintf(formatStr,M.units)
    disp([M(M.names(1)),M(M.names(2)),M(M.names(3))])
end

//define extraction operation
function [Mat]=%Mlog_e(varargin)
    M    = varargin($)
    cols = [1:size(M.names,"*")] // This will also work
    cols = cols(varargin($-1))   // when varargin($-1) = 1:1:$
    Mat = []
    if length(varargin)==3 then
        for i = M.names(cols)
            Mat = [Mat M(i)(varargin(1))]
        end     
    else
        for i=1:size(M.names(cols),"*")
            Mat(i).name = M.names(cols(i))
            Mat(i).unit = M.units(cols(i))
            Mat(i).data  = M(:,cols(i))
        end
    end
endfunction

//define insertion operations (a regular matrix into a Mlog matrix)
function ML=%s_i_Mlog(i,j,V,M)
    names = M.names
    units = M.units
    A = M(:,:) // uses function above 
    A(i,j) = V
    ML = mlist(["Mlog" "names" "units" names],names,units,A(:,1),A(:,2),A(:,3))
endfunction

//insertion operation with structures (the subject of the question)
function temp = %Mlog_6(j,M)
    temp = M(j) // uses function %Mlog_e
endfunction

function M = %st_i_Mlog(j,st,M)
    A = M(:,:) // uses function %Mlog_e
    M.names(j) = st.name // uses function above
    M.units(j) = st.unit // uses function above
    A(:,j)     = st.data // uses function above  
    names = M.names
    units = M.units    
    M = mlist(["Mlog" "names" "units" names],names,units,A(:,1),A(:,2),A(:,3))
endfunction

第一个重载（显示mlist）将以下表的形式显示矩阵：

--> M
 M  = 

      colA         colB         colC   
        ft           in           lb   

   0.4720517   0.6719395   0.5628382
   0.0623731   0.1360619   0.5531093
   0.0854401   0.2119744   0.0768984
   0.0134564   0.4015942   0.5360758
   0.3543002   0.4036219   0.0900212

下一个重载（提取和插入）将允许以简单矩阵M(i,j)的形式访问表。

提取功能还将允许列访问M，该M返回一个结构，例如：

--> M(2)
 ans  =

   name: "colB"
   unit: "in"
   data: [5x1 constant]

最后两个函数是问题中提到的重载。它们允许以结构形式更改列元数据。

--> M(2).name = "length"
 M  = 

      colA       length         colC   
        ft           in           lb   

   0.4720517   0.6719395   0.5628382
   0.0623731   0.1360619   0.5531093
   0.0854401   0.2119744   0.0768984
   0.0134564   0.4015942   0.5360758
   0.3543002   0.4036219   0.0900212

如何在Scilab的重载插入函数中使用“ 6”字符代码？

1 个答案: