Question

我在Clojure中创建记录，并希望使用默认值设置一些字段。我怎么能这样做？

Answer 1

使用构造函数。

(defrecord Foo [a b c])

(defn make-foo
  [& {:keys [a b c] :or {a 5 c 7}}]
  (Foo. a b c))

(make-foo :b 6)
(make-foo :b 6 :a 8)

当然有各种各样的变化。例如，您可以要求某些字段是非可选字段而不是默认字段。

(defn make-foo
  [b & {:keys [a c] :or {a 5 c 7}}]
  (Foo. a b c))

(make-foo 6)
(make-foo 6 :a 8)

因人而异。

Answer 2

通过扩展映射构建它时，您可以非常轻松地将初始值传递给记录：

(defrecord Foo [])

(def foo (Foo. nil {:bar 1 :baz 2}))

鉴于此，我通常创建一个构造函数，它合并了一些默认值（您可以根据需要进行覆盖）：

(defn make-foo [values-map]
  (let [default-values {:bar 1 :baz 2}]
    (Foo. nil (merge default-values values-map))))

(make-foo {:fiz 3 :bar 8})
=> #:user.Foo{:fiz 3, :bar 8, :baz 2}

Answer 3

在有了同样的问题后，我最终使用宏将defrecord和工厂函数包装成一个单独的定义。

宏：

(defmacro make-model
  [name args & body]
  (let [defaults (if (map? (first body)) (first body) {})
        constructor-name (str/lower-case (str "make-" name))]
    `(do (defrecord ~name ~args ~@(if (map? (first body)) (rest body) body))
         (defn ~(symbol constructor-name)
           ([] (~(symbol constructor-name) {}))
           ([values#] (~(symbol (str "map->" name)) (merge ~defaults values#)))))))

用法

(make-model User [firstName lastName] {:lastName "Smith"})
=> #'user/make-user
(make-user {:firstName "John"})
=> #user.User{:firstName "John", :lastName "Smith"}

如何在Clojure中为记录中的字段设置默认值？

3 个答案: