Question

我有一个XML文件。我应该从field3找到相同的field2开始（最小）日期和结束（最大）日期。也许xsl有一些功能可以找到它。因为我尝试这样做试图找到最小月和最小日和最大月，最大日。 XML：

<document>
    <line id="0">
        <field id="2">X111</field>
        <field id="3">2011-03-31</field>
    </line>
    <line id="1">
        <field id="2">X111</field>
        <field id="3">2011-04-04</field>
    </line>
    <line id="2">
        <field id="2">X111</field>
        <field id="3">2011-04-02</field>
    </line>
    <line id="3">
        <field id="2">X222</field>
        <field id="3">2011-04-04</field>
    </line>
    <line id="4">
        <field id="2">X222</field>
        <field id="3">2011-04-01</field>
    </line>
    <line id="4">
        <field id="2">X333</field>
        <field id="3">2011-04-01</field>
    </line>
</document>

输出：

<document>
<Message>
    <ID>X111</ID>
    <dateStart>2011-03-31</dateStart>
    <dateEnd>2011-04-04</dateEnd>
</Message>
<Message>
    <ID>X222</ID>
    <dateStart>2011-04-01</dateStart>
    <dateEnd>2011-04-04</dateEnd>
</Message>
<Message>
    <ID>X333</ID>
    <dateStart>2011-04-01</dateStart>
    <dateEnd>2011-04-01</dateEnd>
</Message>
</document>

请帮忙解决。我正在使用样式表版本=“1.0”。

Answer 1

这可能是优化的，但它会返回请求的结果：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    <xsl:key name="test" match="line" use="field[@id=2]"/>
    <xsl:template match="/">
        <document>
            <xsl:for-each select="//line[generate-id()=generate-id(key('test',field[@id=2]))]">
                <xsl:sort select="field[@id=2]"/>
                <Message>
                    <ID>
                        <xsl:value-of select="field[@id=2]"/>
                    </ID>
                    <xsl:apply-templates select="key('test',field[@id=2])">
                        <xsl:sort select="field[@id=3]"/>
                    </xsl:apply-templates>
                </Message>
            </xsl:for-each>
        </document>
    </xsl:template>
    <xsl:template match="line">
        <xsl:if test="position()=1">
            <dateStart>
                <xsl:value-of select="field[@id=3]"/>
            </dateStart>
        </xsl:if>
        <xsl:if test="position()=last()">
            <dateEnd>
                <xsl:value-of select="field[@id=3]"/>
            </dateEnd>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Answer 2

我赞成了@ mousio的回答，但我更希望看到每个line类型中的第一个在自己的模板中处理。所以，本着TMTOWTDI的精神，我就是这样做的：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />
    <xsl:key name="byField2" match="line" use="field[@id=2]" />
    <xsl:template match="/">
        <document>
            <xsl:apply-templates select="document/line" />
        </document>
    </xsl:template>
    <xsl:template match="line[count(.|key('byField2', field[@id=2])[1])=1]">
        <Message>
            <ID><xsl:value-of select="field[@id=2]" /></ID>
            <xsl:apply-templates select="key('byField2', field[@id=2])" mode="m">
                <xsl:sort select="field[@id=3]" />
            </xsl:apply-templates>
        </Message>
    </xsl:template>
    <xsl:template match="line" mode="m">
        <xsl:if test="position()=1">
            <dateStart><xsl:value-of select="field[@id=3]" /></dateStart>
        </xsl:if>
        <xsl:if test="position()=last()">
            <dateEnd><xsl:value-of select="field[@id=3]" /></dateEnd>
        </xsl:if>
    </xsl:template>
    <xsl:template match="line" />
</xsl:stylesheet>

我认为这更容易阅读（并且在大型文档上可能更有效，因为它不会滥用//）。

Answer 3

此转换显示了如何找到所需的最小值和最大值：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <xsl:apply-templates select="line">
       <xsl:sort select="field[@id=3]"/>
     </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="line">
  <xsl:if test="position()=1">
   Earliest:
   <xsl:copy-of select="."/>
  </xsl:if>
  <xsl:if test="position()=last()">
   Latest:
   <xsl:copy-of select="."/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档：

<document>
    <line id="0">
        <field id="2">X111</field>
        <field id="3">2011-03-31</field>
    </line>
    <line id="1">
        <field id="2">X111</field>
        <field id="3">2011-04-04</field>
    </line>
    <line id="2">
        <field id="2">X111</field>
        <field id="3">2011-04-02</field>
    </line>
    <line id="3">
        <field id="2">X222</field>
        <field id="3">2011-04-04</field>
    </line>
    <line id="4">
        <field id="2">X222</field>
        <field id="3">2011-04-01</field>
    </line>
    <line id="4">
        <field id="2">X333</field>
        <field id="3">2011-04-01</field>
    </line>
</document>

<强>产生：

   Earliest:
   <line id="0">
   <field id="2">X111</field>
   <field id="3">2011-03-31</field>
</line>
   Latest:
   <line id="3">
   <field id="2">X222</field>
   <field id="3">2011-04-04</field>
</line>

<强>解释：

从排序的节点列表中选择第一个和最后一个元素。日期采用“良好”格式，因此它们按字符串排序。

如何在xml文件中查找开始（最小）和结束（最大）日期？

3 个答案: