Question

我刚刚开始使用Dlang，对于想要更安全的C语言的人们来说，它似乎是理想的选择。此外，它还具有现代范例，例如函数式编程。

我正在尝试下面的代码将数字列表作为字符串转换为整数列表：

import std.stdio; 
import std.array;
import std.conv;

int[] list_str2int(char[][] slist){     // this function should convert a list of numbers as char[] to integers
    int[100] intcol; 
    int N = cast(int)slist.length; 
    foreach(int i; 0..N){
        char[] temp = slist[i];
        temp = split(temp, ".")[0];   // effectively this is floor; to!int does not work if '.' is there; 
        intcol[i] = to!int(temp);   // not working; 
    }
    return intcol;                  // error from this statement; 
}

void main(){
    char[][] strlist = cast(char[][])["1.1","2.1","3.2","4.4"]; 
    int[] newintlist = list_str2int(strlist); 
    writeln("Converted list: ", newintlist); 
}

但是出现以下错误：

$ rdmd testing.d 

testing.d(13): Error: returning cast(int[])intcol escapes a reference to local variable intcol
Failed: ["/usr/bin/dmd", "-v", "-o-", "testing.d", "-I."]

我不明白为什么变量为int []的第一个函数的返回行会出错。

问题出在哪里，如何解决？感谢您的帮助。

Answer 1

int[100]是一个静态数组（值类型），位于list_str2int的堆栈框架上-因此一旦函数返回，它将不再存在。函数的返回值int[]是一个片（引用类型），它不保存任何数据，但是引用内存中某个位置的连续整数。语句return intcol;因此占用了静态数组的一个切片，但是，返回该切片无效，因为该切片将指向该函数返回后不再有效的内存。

您有几种选择：

也将返回类型声明为int[100]。将其设置为值类型后，整数将被复制到调用方的堆栈框架中。
通过将数组声明为auto intcol = new int[100];并将其初始化为程序，在程序堆中分配该数组。这将使intcol成为堆中的一部分内存。堆中的内存归垃圾收集器所有，并且有效地具有无限的生存期。

除了上述内容之外，更现代的D语言更常用的一种选择是使用范围。您的程序可以重写为单个语句，如下所示：

import std.algorithm.iteration;
import std.stdio; 
import std.array;
import std.conv;

void main()
{
    ["1.1", "2.1", "3.2", "4.4"]
        .map!(item => item
            .split(".")[0]
            .to!int
        )
        .array // optional, writeln and co can write ranges
        .writefln!"Converted list: %s";
}

Answer 2

int[]是一个分片，可以使用动态分配。

int[100]是100个元素的数组。它是在堆栈上分配的

就像在C语言中一样，您无法从函数返回本地内存，也无法返回intcol，因为函数返回后，其背后的内存将变为无效。

如果您要使用动态数组或静态数组，这对我来说似乎是未知的。如果要使用动态数组，请坚持使用它们。

import std.stdio; 
import std.array;
import std.conv;

int[] list_str2int(char[][] slist){     // this function should convert a list of numbers as char[] to integers
    int N = cast(int)slist.length; 
    int[] intcol = new int[N];
    foreach(int i; 0..N){
        char[] temp = slist[i];
        temp = split(temp, ".")[0];   // effectively this is floor; to!int does not work if '.' is there; 
        intcol[i] = to!int(temp);   // not working; 
    }
    return intcol;                  // error from this statement; 
}

void main(){
    char[][] strlist = cast(char[][])["1.1","2.1","3.2","4.4"]; 
    int[] newintlist = list_str2int(strlist); 
    writeln("Converted list: ", newintlist); 
}

将输出：

 Converted list: [1, 2, 3, 4]

为什么函数的return语句不是通常的int []

2 个答案: