Question

我正在尝试从具有消息且每个消息都有其日期/时间的XML创建JSON。

XML

  <messages>
    <message>
        <messageText>test message1</messageText>
        <displayScheduleContainer>
<startDate>22/05/2019</startDate>
<startTimeHrs>12</startTimeHrs>
<startTimeMins>45</startTimeMins>
            <noEndDate>true</noEndDate>
        </displayScheduleContainer>
    </message>
    <message>
        <messageText>test message2</messageText>
        <displayScheduleContainer>
<startDate>22/06/2019</startDate>
<startTimeHrs>12</startTimeHrs>
<startTimeMins>45</startTimeMins>
            <noEndDate>true</noEndDate>
        </displayScheduleContainer>
    </message>
    <message>
        <messageText>test message3</messageText>
        <displayScheduleContainer>
<startDate>22/06/2019</startDate>
<startTimeHrs>12</startTimeHrs>
<startTimeMins>45</startTimeMins>
            <noEndDate>false</noEndDate>
        </displayScheduleContainer>
    </message>
</messages>

XSLT内部的逻辑读取日期和时间以激活消息

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common" xmlns:java="java"  xmlns:xalan="http://xml.apache.org/xalan"
extension-element-prefixes="exsl">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="/messages">
    <!-- first pass -->
    <xsl:variable name="eligible-messages">
        <xsl:for-each select="message">

            <xsl:if test="displayScheduleContainer/noEndDate = 'true'">
              <xsl:variable name="messageInDateTime">
        <xsl:call-template name="noEndDateTemplate">
           <xsl:with-param name="startDateTime" select="concat(displayScheduleContainer/startDate, ' ', displayScheduleContainer/startTimeHrs, ':', displayScheduleContainer/startTimeMins)" />
         </xsl:call-template>
        </xsl:variable>
      <xsl:if test="$messageInDateTime = 'true'" >
                    <xsl:copy-of select="messageText/text()" />
                    <xsl:if test="position() &lt; last()">,</xsl:if>

                 </xsl:if>
            </xsl:if>

        </xsl:for-each>
    </xsl:variable>
    <!-- output -->
<xsl:value-of select="$eligible-messages" />
</xsl:template>

<xsl:template name="noEndDateTemplate">
        <xsl:param name="startDateTime" />
        <xsl:variable name="sdf" select="java:text.SimpleDateFormat.new('dd/MM/yyyy hh:mm')" />
        <xsl:variable name="currentDateTime" select="java:util.Date.new()" />
        <xsl:choose>
            <xsl:when test="java:compareTo(java:parse($sdf, $startDateTime), $currentDateTime) &lt; 0">
                <xsl:text>true</xsl:text>
            </xsl:when>
            <xsl:otherwise>
                <xsl:text>false</xsl:text>
            </xsl:otherwise>
        </xsl:choose>


    </xsl:template>

</xsl:stylesheet>

我在这里面临的问题是，如果最后一个值是false，我最终会得到逗号。因为我正在检查最后一个位置并添加逗号。因此，整个JSON已损坏。在这种情况下，它会添加逗号，因为我仅在文本为true时才显示文本。

收到输出

test message1,

Answer 1

您没有正确实现在p revious question上收到的答案。恐怕我无法验证您的Java代码，但是我相信使用以下命令会得到正确的结果：

XSLT 1.0（+ EXSLT + Java）

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common" xmlns:java="java"  
extension-element-prefixes="exsl">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="/messages">
    <!-- first pass -->
    <xsl:variable name="eligible-messages">
        <xsl:for-each select="message[displayScheduleContainer/noEndDate = 'true']">
            <xsl:variable name="messageInDateTime">
                <xsl:call-template name="noEndDateTemplate">
                    <xsl:with-param name="startDateTime" select="concat(displayScheduleContainer/startDate, ' ', displayScheduleContainer/startTimeHrs, ':', displayScheduleContainer/startTimeMins)" />
                </xsl:call-template>
            </xsl:variable>
            <xsl:if test="$messageInDateTime = 'true'" >
                <xsl:copy-of select="." />
            </xsl:if>
        </xsl:for-each>
    </xsl:variable>
    <!-- output -->
    <xsl:for-each select="exsl:node-set($eligible-messages)/message">
        <xsl:value-of select="messageText" />
        <xsl:if test="position() &lt; last()">,</xsl:if>
    </xsl:for-each>
</xsl:template>

<xsl:template name="noEndDateTemplate">
    <xsl:param name="startDateTime" />
    <xsl:variable name="sdf" select="java:text.SimpleDateFormat.new('dd/MM/yyyy hh:mm')" />
    <xsl:variable name="currentDateTime" select="java:util.Date.new()" />
    <xsl:value-of select="java:compareTo(java:parse($sdf, $startDateTime), $currentDateTime) &lt; 0"/>  
</xsl:template>

</xsl:stylesheet>

为每个循环中的最后一个元素去除逗号

1 个答案: