Question

对Haskell绝对零经验，我需要拿出与该Python等效的代码：

from random import choice, sample

def random_subset():
    return tuple(sample(('N', 'S', 'W', 'E'), choice((1, 2, 3, 4))))

def form_grid(n):
    return [[random_subset() for _ in range(n)] for _ in range(n)]

form_grid(10)

产生如下内容：

N     ESWN  SNEW  NSE   EWSN  E     ENSW  N     NSWE  WES   
NE    WNS   SWEN  EWN   ENWS  WEN   WS    W     ENSW  NW    
WENS  NWE   SNEW  ES    E     S     ES    SENW  EW    WEN   
NSE   NE    WNE   NEWS  SNE   W     SWNE  NSWE  SNEW  EN    
S     SNW   WNES  S     WESN  E     ES    N     ESN   ES    
SWEN  S     WSNE  NEWS  WESN  E     S     SE    E     N     
NEW   S     NEW   WS    W     EN    N     NWS   E     WENS  
WN    NWE   S     SEW   NESW  EWSN  WENS  ES    NWS   WN    
W     NWE   N     N     ES    E     E     WN    SWNE  NES   
WENS  NWE   NW    WESN  SW    NES   ENWS  SE    N     SWNE

出于对上帝的爱，我无法为Haskell的IO概念（尤其是随机性）所困扰。我能想到的最好的方法是：

import Data.Random hiding (shuffle, sample)
import Data.Random.Source.Std
import Data.Random.Extras

randSubset :: IO [Char]
randSubset = do
    len <- runRVar (choice [1..4]) StdRandom :: IO Int
    subset <- runRVar (sample len ['N', 'S', 'W', 'E']) StdRandom :: IO [Char]
    return subset

formGrid :: Int -> [[IO [Char]]]
formGrid n = [[subset | _ <- [0..(n - 1)], subset <- randSubset] | _ <- [0..(n - 1)]]

仍然没有这样做的

error:
    * Couldn't match expected type `[IO [Char]]'
                  with actual type `IO [Char]'
    * In the expression: randSubset
      In a stmt of a list comprehension: subset <- randSubset
      In the expression:
        [subset | _ <- [0 .. (n - 1)], subset <- randSubset]
   |
12 | formGrid n = [[subset | _ <- [0..(n - 1)], subset <- randSubset] | _ <- [0..(n - 1)]]
   |                                                      ^^^^^^^^^^

快速谷歌搜索并没有太大帮助-我可能没有使用最准确的关键字来解决我遇到的这个问题。进行随机更改并希望达到最佳效果变得非常沮丧，但是我确实没有时间也没有精力适当地投入Haskell（尽管这很遗憾），所以就目前而言，我希望有人能指出我的意思。此代码有误。

Answer 1

就像错误已经说过的那样，您的列表理解器具有生成器：

formGrid n = [[subset | _ <- [0..(n - 1)], subset <- randSubset] | _ <- [0..(n - 1)]]

因此，这意味着它期望randSubset是某物的列表，但它不是某物的列表，它是某物的列表的IO。因此，您不能使用它。

您的函数类型也有点问题，您使用[[IO [Char]]]，因此是IO [Char] s的矩阵。

您可能正在寻找replicateM :: Monad m => Int -> m a -> m [a]，因此您的程序如下所示：

import Control.Monad(replicateM)

formGrid :: Int -> IO [[[Char]]]
formGrid n = replicateM n (replicateM n randSubset)

例如：

Main> formGrid 3
[["WSNE","WNS","S"],["WN","SN","WEN"],["SEWN","ESN","NESW"]]

Answer 2

为补充Willem的回答，我要补充一点，您的randSubset看起来很复杂。这是一个更简单的选择

randSubset :: IO String
randSubset = do
  n <- sample (Uniform 1 4)        -- choose how many elements
  sample (shuffleNofM n 4 "NSWE")  -- take that many elements

（顺便说一下，这是sample的{{1}}）

您应该检查这确实是子集的预期分布。请注意，这不是统一的分布：Data.Random比N更有可能（甚至是NS和NS的总和）。还要注意，同一子集的每个排列都可能发生，因此我们并不是在真正采样“子集”。我不知道您的Python代码使用哪种发行版-毕竟可能是相同的。

如果您在SN内部工作，我认为使用IO而不是在sample (someDistribution)的较低级别工作会更简单。

此后，您可以使用RVar生成网格，如Willem所示。

Answer 3

您试图一次跳得太远。从小处着手

formRow :: Int -> IO [[Char]]
formRow 0 = return [] 
formRow n = do { 
     subset  <- randSubset ;     -- subset :: [Char]   <-  randSubset :: IO [Char]
     subsets <- formRow (n-1) ;  --           ~~~~~~                        ~~~~~~
     return (subset : subsets)   -- IO [[Char]]
     }

...在这里，仅使用您已有的东西。然后对行执行相同操作

formGrid :: Int -> IO [[[Char]]]
formGrid 0 = return [] 
formGrid n = do { 
     row  <- formRow n ;        -- row :: [[Char]]   <-  formRow n :: IO [[Char]]
     rows <- formGrid (n-1) ;   --        ~~~~~~~~                       ~~~~~~~~
     return (row : rows)        -- IO [[[Char]]]
     }

您就完成了。不要担心 do 表示法，它是您的朋友。编程很容易，因为它是它的全部目的。

对下一个Monadic组合器进行编码后，请检查其类型on Hoogle，并查看它是否已在库中。

实际上，我们已经重新实现了

replicateM :: Monad m => Int -> m a -> m [a]

formRow n = replicateM n randSubset 
formGrid n = replicateM n (formRow n)
           = replicateM n (replicateM n randSubset)

（正如Willem的回答所说；但是现在我们知道了如何和为什么）。

使用Haskell的元素随机网格

3 个答案: