Question

使用NSIS文本框的用户界面使用户易于将参数传递给程序时，存在一个问题。

它可以在C＃Winform中实现，但是不熟悉如何在NSIS中使用它。

我想通过以下两种方式之一寻求帮助。

1。一个：

我想创建一个文本框，然后将要粘贴的文本用连字符分隔。

示例：

（1）您要在文本框中输入的值：12341234123412341234（   总共19到20位数字）

（2）复制12341234123412341234（   总计19到20位数字）

（3）插入文本框   1234-1234-1234-1234-1234（   自动完成连字，以4位数为单位）

（4）   实际参数值：12341234123412341234

UI中的可见值：1234-1234-1234-1234-1234

图片描述：

Assuming the cmd input window ...

Text Box to show in real UI

2。两个

（1）复制12341234123412341234

（2）粘贴到“文本”框的第一个框中

4位数字自动完成

NSIS Text Box sample

当前我的代码正在尝试方法2。

我的代码：

Function Test
  !insertmacro MUI_INSTALLOPTIONS_READ $0 "pageInputLicenseInfo.ini" "Settings" "State"
  ${If} $0 == 9 # btton 
    !insertmacro MUI_INSTALLOPTIONS_READ $R0 "pageInputLicenseInfo.ini" "Field 1" "State"
    !insertmacro MUI_INSTALLOPTIONS_READ $R1 "pageInputLicenseInfo.ini" "Field 2" "State"
    !insertmacro MUI_INSTALLOPTIONS_READ $R2 "pageInputLicenseInfo.ini" "Field 3" "State"
    !insertmacro MUI_INSTALLOPTIONS_READ $R3 "pageInputLicenseInfo.ini" "Field 4" "State"
    !insertmacro MUI_INSTALLOPTIONS_READ $R4 "pageInputLicenseInfo.ini" "Field 5" "State"
    !insertmacro MUI_INSTALLOPTIONS_READ $R5 "pageInputLicenseInfo.ini" "Field 6" "State"

    nsExec::ExecToStack '$INSTDIR\ParamterTestConsole.exe ${PRODUCT_NAME} $R0 $R1$R2$R3$R4$R5'

    Pop $2 ; Exit code
    Pop $3 ; console OUTPUT

    Blah blah..........

FunctionEnd

NSIS INI文件：

; Ini file generated by the HM NIS Edit IO designer.
[Settings]
NumFields=14
Title=test

[Field 1]
Type=Text
Text=1
Left=29
Right=275
Top=46
Bottom=57

[Field 2]
Type=Text
Text=123
Left=30
Right=60
Top=67
Bottom=78
MaxLen=4

[Field 3]
Type=Text
Text=123
Left=74
Right=103
Top=67
Bottom=78
MaxLen=4

[Field 4]
Type=Text
Text=123
Left=121
Right=149
Top=67
Bottom=78
MaxLen=4

[Field 5]
Type=Text
Text=123
Left=164
Right=193
Top=67
Bottom=78
MaxLen=4

[Field 6]
Type=Text
Text=123
Left=206
Right=236
Top=67
Bottom=78

[Field 7]
Type=Label
Text=IP
Left=1
Right=15
Top=48
Bottom=56

[Field 8]
Type=Label
Text=Key
Left=1
Right=20
Top=70
Bottom=78

[Field 9]
Type=Button
Text=enter
Flags=NOTIFY
Left=225
Right=275
Top=92
Bottom=105

[Field 10]
Type=Label
Text=※ 
Enter four digits.
Left=0
Right=152
Top=26
Bottom=43

[Field 11]
Type=Label
Text=-
Left=154
Right=160
Top=68
Bottom=80

[Field 12]
Type=Label
Text=-
Left=199
Right=205
Top=68
Bottom=76

[Field 13]
Type=Label
Text=-
Left=110
Right=116
Top=68
Bottom=76

[Field 14]
Type=Label
Text=-
Left=64
Right=70
Top=68
Bottom=76

Answer 1

PassDialog plug-in有一个串行对话框，当一个对话框被填满时，它将自动移至下一个编辑域。我不认为它支持粘贴，但是您也许可以要求作者添加此功能。

我认为InstallOptions不支持编辑框上的通知回调，但是nsDialogs可以，您可以使用它创建经典的串行输入对话框：

Var Serial

!include LogicLib.nsh
!include WinMessages.nsh
!include nsDialogs.nsh
Page Custom MyDialogCreate MyDialogLeave
Page InstFiles

Function onSerialEditChange
Pop $R0
SendMessage $R0 ${EM_GETLIMITTEXT} 0 0 $R1
SendMessage $R0 ${WM_GETTEXTLENGTH} 0 0 $R2
${If} $R2 >= $R1
    SendMessage $hWndParent ${WM_NEXTDLGCTL} 0 0 ; Tab to next
${ElseIf} $R2 = 0
    SendMessage $hWndParent ${WM_NEXTDLGCTL} 1 0 ; Tab to previous
${EndIf}
FunctionEnd

Function MyDialogCreate
nsDialogs::Create 1018
Pop $0

!macro CreateSerialEdit x var limit
${NSD_CreateText} ${x} 10u 30u 12u ""
Pop ${var}
${NSD_OnChange} ${var} onSerialEditChange
${NSD_Edit_SetTextLimit} ${var} ${limit}
${NSD_AddStyle} ${var} ${ES_NUMBER} ; Limit to numbers
!macroend
!insertmacro CreateSerialEdit 10u $1 4
!insertmacro CreateSerialEdit 50u $2 4
!insertmacro CreateSerialEdit 90u $3 4

SendMessage $hWndParent ${WM_NEXTDLGCTL} $1 1
nsDialogs::Show
FunctionEnd

Function MyDialogLeave
StrCpy $Serial ""
${NSD_GetText} $1 $0
StrCpy $Serial "$Serial$0"
${NSD_GetText} $2 $0
StrCpy $Serial "$Serial$0"
${NSD_GetText} $3 $0
StrCpy $Serial "$Serial$0"
StrLen $0 $Serial
${If} $0 < 12
    MessageBox mb_iconstop "Enter a valid serial!"
    Abort
${EndIf}
FunctionEnd

Section
MessageBox mb_ok Serial=$Serial
SectionEnd

如果您绝对需要具有所描述的确切行为，则需要创建一个自定义插件，该子类将编辑框作为子类...

NSIS如何通过在字段中插入连字符或在文本框中添加文本框来复制和粘贴文本，并用fieldnum分隔

1 个答案: