Question

我从代码开始，在按下按钮时使LED点亮。那行得通。但是后来我尝试对其进行调整，以使按钮的作用类似于“开-关”开关，在此开关中，您只需按下一次即可在状态之间进行切换。

led适用于较旧的代码（如下），因此我认为它与接线无关。仅供参考，我跳过了设置功能，它与我眨眼时一样。

// constants won't change. They're used here to
// set pin numbers:
const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin

// variables will change:
int buttonState = 0;         // variable for reading the pushbutton status
int switcher = 0;

void loop() {
  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed.
  // if it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    if (switcher = 0) {
      switcher = 1;
      delay(500);
    }
    else if (switcher = 1) {
      switcher = 0;
      delay(500);
    }
  }
  if (switcher == 1) {
    digitalWrite(ledPin, HIGH);
  }
  /*
  else {
    digitalWrite(ledPin, LOW);
  }
  */

}

Answer 1

基于https://www.arduino.cc/en/Tutorial/StateChangeDetection

/*
  State change detection (edge detection)

  Often, you don't need to know the state of a digital input all the time, but
  you just need to know when the input changes from one state to another.
  For example, you want to know when a button goes from OFF to ON. This is called
  state change detection, or edge detection.

  This example shows how to detect when a button or button changes from off to on
  and on to off.

  The circuit:
  - pushbutton attached to pin 2 from +5V
  - 10 kilohm resistor attached to pin 2 from ground
  - LED attached from pin 13 to ground (or use the built-in LED on most
    Arduino boards)

  created  27 Sep 2005
  modified 30 Aug 2011
  by Tom Igoe

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/ButtonStateChange
*/

// this constant won't change:
const int  buttonPin = 2;    // the pin that the pushbutton is attached to
const int ledPin = 13;       // the pin that the LED is attached to

// Variables will change:
int buttonPushCounter = 0;   // counter for the number of button presses
int buttonState = 0;         // current state of the button
int lastButtonState = 0;     // previous state of the button

void setup() {
  // initialize the button pin as a input:
  pinMode(buttonPin, INPUT);
  // initialize the LED as an output:
  pinMode(ledPin, OUTPUT);
  // initialize serial communication:
  Serial.begin(9600);
}


void loop() {
  // read the pushbutton input pin:
  buttonState = digitalRead(buttonPin);

  // compare the buttonState to its previous state
  if (buttonState != lastButtonState) {
    // if the state has changed, increment the counter
    if (buttonState == HIGH) {
      // if the current state is HIGH then the button went from off to on:
      buttonPushCounter++;
      Serial.println("on");
      Serial.print("number of button pushes: ");
      Serial.println(buttonPushCounter);
    } else {
      // if the current state is LOW then the button went from on to off:
      Serial.println("off");
    }
    // Delay a little bit to avoid bouncing
    delay(50);
  }
  // save the current state as the last state, for next time through the loop
  lastButtonState = buttonState;


  // turns on the LED every two button pushes by checking the modulo of the
  // button push counter. the modulo function gives you the remainder of the
  // division of two numbers:
  if (buttonPushCounter % 2 == 0) {
    digitalWrite(ledPin, HIGH);
  } else {
    digitalWrite(ledPin, LOW);
  }

}

Answer 2

使用此代码，当您按下按钮Led时将打开，而再次按下按钮Led时将始终处于关闭状态。

const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin

int switchState = 0; // actual read value from pin4
int oldSwitchState = 0; // last read value from pin4
int lightsOn = 0; // is the switch on = 1 or off = 0


void setup() {
  Serial.begin(9600);
  pinMode(ledPin, OUTPUT);   // declare LED as output
  pinMode(buttonPin, INPUT); // declare push button as input
}

void loop() {

  switchState = digitalRead(buttonPin); // read the pushButton State

  if (switchState != oldSwitchState) // catch change
  {
    oldSwitchState = switchState;
    if (switchState == HIGH)
    {
      // toggle
      lightsOn = !lightsOn; // invert the values
    }
  }

  if (lightsOn)
  {
    digitalWrite(ledPin, HIGH); // set the LED on
    Serial.println("LED Turned ON");
  } else {
    digitalWrite(ledPin, LOW); // set the LED off
    Serial.println("LED Turned Off");
  }
}

Answer 3

Delay仅在您希望整个系统停止时使用。在Arduino生涯初期，它也用于学习目的。在实际的应用程序中，您将使用延迟库或使用计时。如果您在应用程序中使用延迟，那么您将无法读取按钮HIGH事件，这意味着仅在延迟500毫秒后才可以在501毫秒内准确读取按钮，您将拥有一个1毫秒或更短的窗口，对于人类而言，几乎是不可能的。无论如何，您应该查看Arduino的“ Blink Without Delay”示例。

此外，必须在设置中为按钮使用上拉电阻或为INPUT_PULLUP声明一个pinMode，以避免弹跳，请参见下面的示例。

这是您解决代码的方法：

// defined constants in Arduino don’t take up any program memory space on the chip.
#define buttonPin 2;
#define ledPin 13;

// bytes are half the size of int's, but restricted to a max value of 255
byte value;
byte oldValue = 0;
byte state = 0;

void setup()
{
  pinMode(buttonPin , INPUT_PULLUP);
  pinMode(ledPin, OUTPUT);
}

void loop()
{
  value = digitalRead(buttonPin );
  if(value && !oldValue) // same as if(button == high && oldValue == low)
  {
    //we have a new button press
    if(state == 0) // if the state is off, turn it on
    {
      digitalWrite(ledPin, HIGH);
      state = 1;
    }
    else // if the state is on, turn it off
    {
      digitalWrite(ledPin, LOW);
      state = 0;
    }
    oldValue = 1;
  }
  else if(!value && oldValue) // same as if(button == low && oldValue == high)
  {
    // the button was released
    oldValue = 0;
  }
}

我正在尝试使按钮打开和关闭LED，但是它只是保持关闭状态

3 个答案:

这是您解决代码的方法：