Question

我正在使用TRichEdit来保存电子邮件客户端的正文。我已经为用户提供了简单的格式设置功能（粗体，斜体，下划线，左，中和右段落对齐方式和项目符号。这很好地适用于按照雷米（Remy）的代码here使用Indy以html格式发送文本的文本。

我使用

将TRichEdit文本提取为html。

function GetHTML(RichEdit:TRichEdit): string;
var
    htmlstrings : Tstringlist;
    JvRichEditToHtml1  :TJvRichEditToHtml;
begin
 htmlstrings := Tstringlist.create;
 JvRichEditToHtml1 := TJvRichEditToHtml.create(nil);
 try
   JvRichEditToHtml1.ConvertToHtmlStrings(RichEdit,htmlstrings);
   result := htmlstrings.Text;
 finally
   htmlstrings.free ;
   JvRichEditToHtml1.free;
 end;
end;

就在我发送电子邮件之前，我使用代码在TRichEdit中将称呼字符串作为新的顶行插入，然后是两个空行。电子邮件系统使用它来个性化电子邮件，并且效果很好。

问题是，如果用户在输入正文的第一行时设置了格式，例如假设他们将前几行设为项目符号列表，那么当电子邮件到达。

如何使用代码在TRichEdit的顶部插入一行而没有段落或字体格式，而又保留用户可能已应用于（手动输入的）第一行的任何格式？

我现在用来插入称呼字符串的代码在下面，但是我的称呼仍然获得用户应用的格式样式。（最初，我只有三个插入行，但在类似的问题here中，在思想之后添加了其他代码）。大写标识符是在其他地方定义的常量。

procedure AddRecipientVarableToBody( var Body: TRichEdit);
  begin  
  //remove formatting from the (new) first paragraph
  Thebody.Paragraph.Numbering := nsnone;
  Thebody.Paragraph.Alignment := taLeftJustify;

  //add the three new top lines (two blank plus a recipient)
  //done backwards as we insert a new line zero each time
  TheBody.lines.Insert(0,EMPTY_STRING);  // two blank lines
  TheBody.lines.Insert(0,EMPTY_STRING);
  TheBody.lines.Insert(0,'To: ' + RECIPIENT_VARIABLE_SALUTATION); 

 //Remove any formatting from first three lines
   TheBody.SelStart:=0;
   TheBody.SelLength:= length(TheBody.Lines[0]) + length(TheBody.Lines[1]) + length(TheBody.Lines[2]);
   TheBody.SelAttributes.Style  :=  [];
   end;

附录：

我设法通过延迟称呼插入直到设置好准备传递给Indy的参数并将整个TRichEdit HTML附加到简单文本字符串（即代替

Params.Add('html=' +  GetHTML(body));

我用过

Params.Add('html=' +  'To: ' + RECIPIENT_VARIABLE_SALUTATION + GetHTML(body));

其中的主体是TRichEdit。

但是，我仍然想知道是否可以通过将新行直接插入TRichEdit来解决我的难题。

Answer 1

您可以为RichEdit定义DefAttributes。然后，您可以通过

轻松地返回使用此设置

RE.SelAttributes := RE.DefAttributes;

所以，这是对您情况的考验。首先定义DefAttributes，例如在OnFormCreate()中：

procedure TForm1.FormCreate(Sender: TObject);
begin
  // Initialize to what you want to return to, or use as default
  RE.DefAttributes.Charset := ANSI_CHARSET;
  RE.DefAttributes.Color := clBlack;
  RE.DefAttributes.Height := -16;
  RE.DefAttributes.Name := 'Segoe UI';
  RE.DefAttributes.Size := 12;
  RE.DefAttributes.Style := [];
end;

请注意，上面不涉及项目符号，它们是分开处理的。

在下面的代码中，我们模拟用户可能写的内容...

procedure TForm1.Button1Click(Sender: TObject);
begin
  RE.Lines.Add('Final reminder');
  RE.Lines.Add('Please, fill the form below, and send it immediately.');

  RE.SelStart := 0;
  RE.SelLength := Length(RE.Lines[0]);
  RE.SelAttributes.Color := clRed;
  RE.SelAttributes.Name := 'Algerian';
  RE.SelAttributes.Size := 15;

  RE.SelStart :=  Length(RE.Lines[0]);
  RE.SelLength :=  Length(RE.Lines[1]);
  RE.SelAttributes := RE.DefAttributes;
end;

...以及可能添加的特殊属性Bold，Italic，Underline和Strikeout以及第一行的项目符号。这些在我的测试表单中添加了按钮。

最后，如何将三行添加到开头并确保独立的格式。

procedure AltAddRecipientVarableToBody( var RE: TRichEdit);
begin
  RE.lines.Insert(0,EMPTY_STRING);  // two blank lines
  RE.lines.Insert(0,EMPTY_STRING);
  RE.lines.Insert(0,'To: ' + RECIPIENT_VARIABLE_SALUTATION);

  // Select
  RE.SelStart := 0;
  RE.SelLength:= length(RE.Lines[0]) + 1
               + length(RE.Lines[1]) + 1
               + length(RE.Lines[2]) + 1;
  // Clear attributes
  RE.SelAttributes := RE.DefAttributes;
  // Clear bullets
  RE.Paragraph.Numbering := nsNone;
end;

每行添加1个字符用于换行符。请注意，由于项目符号是段落的属性，因此不能在DefAttributes中定义它们，而必须单独处理。

结果是，添加的三行以DefAttributes进行了格式设置，并且原始文本保持了其原有格式。

如何在TRichEdit的顶部插入新的，未格式化的行

1 个答案: