Question

如何使用XSLT 1.0仅输出最后一个重复节点？我使用xsltproc处理器。

Input.xml

<testng-results>
    <suite>
        <test>
            <class name="system.apps.CreateTerritory">
                <test-method status="PASS"  name="initTest" is-config="true"> </test-method>
                <test-method status="FAIL"  name="ABC"> </test-method>
            </class>
            <class name="system.apps.CreateAccount">
                <test-method status="PASS"  name="initTest" is-config="true"> </test-method>
                <test-method status="SKIP"  name="DEF"> </test-method>
                <test-method status="PASS"  name="initTest" is-config="true"> </test-method>
                <test-method status="FAIL"  name="DEF"> </test-method>
            </class>
        </test>
    </suite>
</testng-results>

我当前的XSL：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:str="http://exslt.org/strings" extension-element-prefixes="str" version="1.0">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
    <xsl:strip-space elements="*" />
    <xsl:template match="/">
        <Suite>
            <xsl:for-each select="testng-results/suite/test/class">
                 <xsl:for-each select="test-method">
                     <xsl:if test="not(@is-config)">
                             <Test>
                                 <Method_Name>
                                     <xsl:value-of select="@name"/>
                                 </Method_Name>
                                 <Status>
                                     <xsl:value-of select="@status"/>
                                 </Status>
                             </Test>
                     </xsl:if>
                 </xsl:for-each>
            </xsl:for-each>
        </Suite>
    </xsl:template>
</xsl:stylesheet>

注意：我无法更改完成嵌套匹配的方式（对于每个类，然后对于每个测试方法，由于其他原因，我需要这样做）

当前Output.xml：

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <Test>
    <Method_Name>ABC</Method_Name>
    <Status>FAIL</Status>
  </Test>
  <Test>
    <Method_Name>DEF</Method_Name>
    <Status>SKIP</Status>
  </Test>
  <Test>
    <Method_Name>DEF</Method_Name>
    <Status>FAIL</Status>
  </Test>
</Suite>

预期的Output.xml（对于每个重复的测试方法仅输出最后一个节点）：

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <Test>
    <Method_Name>ABC</Method_Name>
    <Status>FAIL</Status>
  </Test>
  <Test>
    <Method_Name>DEF</Method_Name>
    <Status>FAIL</Status>
  </Test>
</Suite>

Answer 1

如果您使用的是xsltproc（即libxslt处理器），则可以利用EXSLT set:distinct()扩展功能来利用{{3 }}：

XSLT 1.0（+ EXSLT）

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:set="http://exslt.org/sets"
extension-element-prefixes="set">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="test-by-name" match="test-method[not(@is-config)]" use="@name" />

<xsl:template match="/testng-results">
    <xsl:variable name="tests" select="suite/test/class/test-method[not(@is-config)]" />
    <Suite>
        <xsl:for-each select="set:distinct($tests/@name)">
            <Test>
                <Method_Name>
                    <xsl:value-of select="."/>
                </Method_Name>
                <Status>
                    <xsl:value-of select="key('test-by-name', .)[last()]/@status"/>
                </Status>
            </Test>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>

或者，如果您愿意，也可以在纯XSLT 1.0中执行以下操作：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="test-by-name" match="test-method[not(@is-config)]" use="@name" />

<xsl:template match="/testng-results">
    <Suite>
        <xsl:for-each select="suite/test/class/test-method[not(@is-config)][count(. | key('test-by-name', @name)[last()]) = 1]">
            <Test>
                <Method_Name>
                    <xsl:value-of select="."/>
                </Method_Name>
                <Status>
                    <xsl:value-of select="@status"/>
                </Status>
            </Test>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>

请注意使用[last()]谓词，而不是通常的[1]。

XSLT 1.0（xsltproc）-仅输出最后一个重复的节点

1 个答案: