Question

我有一个Excel工作表，其中包含随机数量的列和行（每次更改列/行的数量以及每列的位置），我需要在其中找到标题为“课程信息”的特定列，然后在该列中的所有行/单元格上使用CLEAN函数（课程的标题行除外）。

我有清洁功能的代码：

Set Rng = ShData.Range("AB2:AB" & LastRow)

For Each cell In Rng
    cell.Value = Application.WorksheetFunction.Clean(cell.Value)
Next cell

这里的问题是Rng设置为AB列，但并不总是该列。我还制作了LastRow和LastCol代码以计算行和列的数量，但除此之外，我还遇到了麻烦。

LastRow = ShData.Range(2, Rows.Count).End(xlUp).Row
LastCol = ShData.Range(1, Cols.Count).End(xlToLeft).Column

Answer 1

这里：

Option Explicit
Sub Test()

    Dim Rng As Range, Col As Long, cell As Range, LastRow As Long, LastCol As Long

    With ShData
        LastRow = .Range(.Rows.Count, 2).End(xlUp).Row
        LastCol = .Range(1, .Columns.Count).End(xlToLeft).Column
        Col = .Rows(1).Find("Course Info").Column 'this is to find the column number
        Set Rng = .Range(.Cells(2, Col), .Cells(LastRow, Col))
    End With

    For Each cell In Rng
        cell = Application.WorksheetFunction.Clean(cell)
    Next cell

End Sub

Answer 2

使用WorksheetFunction.Match method获取列号。

Option Explicit

Sub test()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Worksheets("Sheet1")

    Dim Col As Double
    On Error Resume Next 'next line throws error if "Course Info" was not found
    Col = Application.WorksheetFunction.Match("Course Info", ws.Rows(1), 0)
    On Error GoTo 0 'always re-activate error reporting

    If Col <> 0 Then 'only do it if "Course Info" was found
        Dim Cell As Range
        For Each Cell In ws.Range(ws.Cells(2, Col), ws.Cells(ws.Rows.Count, Col).End(xlUp))
            Cell.Value = Application.WorksheetFunction.Clean(Cell.Value)
        Next Cell
    End If
End Sub

找到特定的列并清理其下的所有行

2 个答案: