Question

我有一个BFS的实现，我在其他地方稍微修改过，但我的输入有问题它需要一个图表，并将其视为'（（a b c）（b c）（c d））但是我给它的输入是一个加权图...我知道它对BFS没有用，但是后来我使用了更重要的权重。此输入看起来像是 '( (a (b 3) (c 1)) (b (a 3) (d 1)) (c (a 1) (d2) (e 2)) )
等等。

我的代码：

(defun shortest-path (start end net)  
      (BFS end (list (list start)) net))

(defun BFS (end queue net)  
  (if (null queue)  
      nil  
      (expand-queue end (car queue) (cdr queue) net)))

(defun expand-queue (end path queue net)  
  (let ((node (car path)))  
        (if (eql node end)  
        (reverse path)  
        (BFS end
             (append queue  
                     (new-paths path node net))  
             net))))

(defun new-paths (path node net)  
  (mapcar #'(lambda (n)  
              (cons n path))  
          (cdr (assoc node net))))

我只是不确定我最需要修改它以接受新的样式列表，或者使用帮助函数来正确格式化它？

Answer 1

您需要指定代表图表的列表的含义。目前您只提供了一个示例列表。

图表的语法如下：

graph = (node*)

node = (name nextnodename*)

name = SYMBOL

nextnodename = SYMBOL

然后转换函数可能是：

(defun convert-graph (graph)
  (mapcar (lambda (node)
            (destructuring-bind (name . nodes) node
              (cons name (mapcar #'first nodes))))
          graph))

或者如果您可能需要其他提取功能：

(defun convert-graph (graph &key (key #'first))
  (mapcar (lambda (node)
            (destructuring-bind (name . nodes) node
              (cons name (mapcar key nodes))))
          graph))

示例：

(convert-graph '((a (b 3) (c 1))
                 (b (a 3) (d 1))
                 (c (a 1) (d 2) (e 2)))
               :key #'first)

((A B C) (B A D) (C A D E))

现在您可能需要删除重复的链接。但这取决于图形描述的语法和语义。

LISP - 广度优先搜索

1 个答案: