Question

我正在ARM项目上实现现代Cmake。我有3个不同的CMakeLists：

顶部CMakeLists：包含要编译的应用程序文件（main.c）+ 2 目标依赖项（算法和硬件）

target_link_libraries(app_target PUBLIC algo_target hardware_target)

算法CMakeLists仅具有C文件仅计算（algo.c）
硬件CMakeLists 有关硬件依赖项的所有文件（hardware.c）和编译选项，具体取决于硬件-mcpu -mthumb -mfloat-abi -mfpu

target_compile_options(hardware_target -mcpu=${CPU} -mthumb -mfloat-abi=hard -mfpu=${FPU})

问题是，编译选项会传播到顶部，但不会传播到algo_target上。我遇到以下错误：

app使用VFP寄存器参数，而algo.a（algo.cpp.obj）不使用

如何在所有目标上传播编译选项？我不想在编译选项变量中设置编译选项，以后，该应用程序将在2个不同的硬件目标上运行

Answer 1

因为您没有提供最低限度的工作示例，所以我可能不能完全回答您的问题。但是，由于CMake都是关于目标以及这些目标之间的依赖关系管理的，所以我猜想，任何需要与另一个目标进行某些设置/依赖的目标都应依赖于该目标。

假设我们具有以下目录结构：

.
├── algo
│   ├── CMakeLists.txt
│   ├── include
│   │   └── algo.hpp
│   └── src
│       └── algo.cpp
├── CMakeLists.txt
├── hardware
│   ├── CMakeLists.txt
│   ├── include
│   │   └── hardware.hpp
│   └── src
│       └── hardware.cpp
└── main.cpp

6 directories, 8 files

，其中包含algo

的以下文件内容

# algo/CMakeLists.txt
add_library(algo
  include/algo.hpp
  src/algo.cpp
)
target_include_directories(algo
  PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
)

# if (TARGET hardware)
#   target_link_libraries(algo PRIVATE hardware)
# endif()

/* algo/include/algo.hpp */
#pragma once

double func1(const double);

/* algo/src/algo.cpp */
#include "algo.hpp"

double func1(const double x) {
#ifdef IMPORTANT_DEF
  return 2 * x;
#else
  return x;
#endif
}

hardware

# hardware/CMakeLists.txt
add_library(hardware
  include/hardware.hpp
  src/hardware.cpp
)
target_include_directories(hardware
  PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
)
target_compile_definitions(hardware
  PUBLIC
    IMPORTANT_DEF
)

/* hardware/include/hardware.hpp */
#pragma once

#ifdef IMPORTANT_DEF
double func2(const double, const double);
#else
int func2(int, const int);
#endif

/* hardware/src/hardware.cpp */
#include "hardware.hpp"

#ifdef IMPORTANT_DEF
double func2(const double x, const double y) { return x + y; }
#else
int func2(int x, const int y) { return x - y; }
#endif

最后是app

# CMakeLists.txt
cmake_minimum_required(VERSION 3.9)

project(propagate LANGUAGES C CXX)

add_subdirectory(hardware)
add_subdirectory(algo)

add_executable(app main.cpp)
target_link_libraries(app
  PRIVATE
    hardware
    algo
)

/* main.cpp */
#include <iostream>
using namespace std;

#include "hardware.hpp"
#include "algo.hpp"

int main(int argc, char* argv[]) {
  cout << func1(5) << '\n';
  cout << func2(5, 3) << '\n';
  return 0;
}

构建上面的项目并运行它时，我们得到

./app
5
8

这是因为我们没有告诉CMake algo取决于hardware。当我们取消注释该部分

# if (TARGET hardware)
#   target_link_libraries(algo PRIVATE hardware)
# endif()

在algo/CMakeLists.txt中并重建项目，这次我们得到了

./app
10
8

基本上，target_*命令用于定义应该或不应该传播到目标消费者的依赖项。因此，我们应该使algo目标成为hardware目标的消费者。

还请注意，要进行传播，target_*个朋友也需要填充目标的INTERFACE_*属性，即target_*命令需要将属性定义为PUBLIC（出现在头文件和实现文件中）或INTERFACE（仅出现在头文件中），而不是PRIVATE（仅出现在实现文件中）。

如何将编译选项从目标传播到Cmake上的所有其他选项

1 个答案: