Question

大家好请原谅任何滥用语言的行为

我需要创建myPermutation（L1，L2）。给出一个列表L1（其中包含许多连续出现的元素）返回一个列表L2，它是L1排序的方式，没有两个相同的元素是相同的）

示例：给定列表L1 [1,1,1,1,1,2,2,3,3,4,4,5,5] L2应为[1,2,1,5,1， 3,1,4,1,2,3,5,4] 我已经尝试了随机排列并检查每个排列的一致性，但它非常慢（对于超过12个元素的L1，aprox 24 cpus）

唯一可行的解决方案是进行一致的排列，而不是检查一个但我怎么能这样做？

即使使用标准序言也可以完成probalby，但由于我对逻辑编程的理解很差，我无法理解它

谢谢你：D

Answer 1

您可以构建检查列表的这种排列。

myPermutation([], []).
myPermutation(L, [H|P]):-
  select(H, L, NL), % Select one item from the list
  myPermutation(NL, H, P).

myPermutation([], _, []).
myPermutation(L, H, [I|P]):-
  select(I, L, NL), % Select another item
  I \= H, % Enforce restriction of no duplicate consecutive items
  myPermutation(NL, I, P).

此代码将在回溯时提供所有有效排列。我会把你作为一种练习来放弃重复的排列。

Answer 2

您可以使用dif/2快速执行此操作，这会使两个变量在不事先知道这些值的情况下具有不同的值：

?- dif(X,Y).
dif(X, Y).

?- dif(X,Y), X=1.
X = 1,
dif(1, Y).

?- dif(X,Y), X=1, Y=1.
false.

使用它，您可以创建一个约束列表的谓词，使得两个元素不相同：

conseq_dif([]).
conseq_dif([_]).
conseq_dif([X,Y|Xs]) :-
    dif(X,Y),
    conseq_dif([Y|Xs]).

现在找到你想要的约束排列：

constrained_perm(Lst,Prm) :-
    length(Lst,N),
    length(Prm,N),           % make list of N unbound variables
    conseq_dif(Prm),
    permutation(Lst,Prm).    % "ordinary" (library) permutation finding

我不确定dif/2是否是标准的Prolog，但是主要的实现都有它。

Answer 3

我们根据same_length/2定义my_perm/2， list_permuted/2，dif和mapadj/2：

my_perm(Xs,Ys) :-
   same_length(Xs,Ys),
   mapadj(dif,Ys),
   list_permuted(Xs,Ys).

多才多艺的meta-predicate mapadj/2可以这样定义：

:- meta_predicate mapadj(2,?), list_mapadj(?,2), list_prev_mapadj(?,?,2).
mapadj(P_2,Xs) :-
   list_mapadj(Xs,P_2).

list_mapadj([],_).
list_mapadj([A|As],P_2) :-
   list_prev_mapadj(As,A,P_2).

list_prev_mapadj([],_,_).
list_prev_mapadj([A1|As],A0,P_2) :-
   call(P_2,A0,A1),
   list_prev_mapadj(As,A1,P_2).

以下是OP给出的示例查询^1,2。

我们使用call_time/2来测量运行时间，单位为毫秒T_ms。

?- call_time(my_perm([1,1,1,1,1,2,2,3,3,4,4,5,5],[1,2,1,5,1,3,1,4,1,2,3,5,4]),T_ms).
T_ms = 0.

我们需要多长时间才能找到前几个解决方案？

?- call_time(my_perm([1,2,1,5,1,3,1,4,1,2,3,5,4],Xs),T_ms).
  T_ms =  0, Xs = [1,2,1,5,1,3,1,4,1,2,3,5,4]
; T_ms =  0, Xs = [1,2,1,5,1,3,1,4,1,2,3,4,5]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,5,3,4]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,4,3,5]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,5,4,3]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,2,4,5,3]
; T_ms = 10, Xs = [1,2,1,5,1,3,1,4,1,3,2,5,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,3,2,4,5]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,5,2,3,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,4,2,3,5]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,5,2,4,3]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,4,2,5,3]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,3,5,2,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,3,4,2,5]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,5,3,2,4]
; T_ms = 20, Xs = [1,2,1,5,1,3,1,4,1,4,3,2,5]
; T_ms = 30, Xs = [1,2,1,5,1,3,1,4,1,5,4,2,3]
; T_ms = 30, Xs = [1,2,1,5,1,3,1,4,1,4,5,2,3]
...

请注意T_ms单调增长：它衡量自首次调用指定目标以来所花费的时间。

枚举所有解决方案需要多长时间？

?- call_time(\+((my_perm([1,1,1,1,1,2,2,3,3,4,4,5,5],_),false)),T_ms).
T_ms = 4030.

有多少个解决方案？

?- use_module(library(aggregate)),
   aggregate(count,Xs,my_perm([1,2,1,5,1,3,1,4,1,2,3,5,4],Xs),N).
N = 197664.

^{脚注1：使用SICStus Prolog版本4.3.2（x86_64-linux-glibc2.12）。

脚注2：为了便于阅读，Prolog处理器给出的答案序列已经过调整。
功能}

具有多个相同元素的列表的排列Prolog

3 个答案: