Question

我的树有两级节点 - 它是联系人列表样式树。

我的问题是，我希望在所有“联系人类别”中检查所有联系人。这是我现在看的联系人列表的截图（是的，我有权发布）

Contact List

如您所见， Todd Hirsch 在类别测试类别中进行了检查，但未在所有联系人中进行检查。我想要实现的目标是让联系人在每个类别中都具有相同的已检查状态。

示例：我在测试类别中检查Todd Hirsch - Todd Hirsch会自动在所有联系人（以及其他所有类别）中进行检查。如果我在所有联系人中查看Todd Hirsch，他也将在测试类别中进行检查。如果我在所有联系人中取消选中Todd Hirsch，他也将在测试类别中取消选中。

我尝试通过VirtualStringtree的OnChecking事件，通过循环遍历树中每个节点的整个树，但是当联系人列表很大（2000 +）时，它非常慢，当有5000+时，它甚至可能导致程序崩溃（应用程序已停止工作）

你有什么建议？

以下是我用来确保只检查一次联系人的代码。（这不是我现在想要的，但它正是我现在正在使用的。）

////////////////////////////////////////////////////////////////////////////////
/// HasDuplicateChecked
////////////////////////////////////////////////////////////////////////////////
Function HasDuplicateChecked(Node: PVirtualNode): PVirtualNode;
Var
  ParentNode, ChildNode: PVirtualNode;
  I, J: Integer;
Begin

  // IHCW
  Result := Nil;

  // Get the first node of the tree..
  ParentNode := VT.GetFirst;

  // Loop thru the parent nodes.
  for I := 0 to VT.RootNodeCount - 1 do
  begin
    // Get the first child node.
    ChildNode := ParentNode.FirstChild;
    // Loop thru the children..
    for J := 0 to ParentNode.ChildCount - 1 do
    begin
      // If the ChildNode is checked...
      if NodeIsChecked(ChildNode) then
        // And it is NOT the passed node..
        if ChildNode <> Node then
          // but the data matches..
          if GetData(ChildNode).SkypeID = GetData(Node).SkypeID then
          begin
            // Then pass the Childnode as a result, and EXIT!
            Result := ChildNode;
            Exit;
          end;
      // Next child..
      ChildNode := ChildNode.NextSibling;
    end;
    // Next parent...
    ParentNode := ParentNode.NextSibling;
  end;

End;


////////////////////////////////////////////////////////////////////////////////
/// vtSkypeChecking
////////////////////////////////////////////////////////////////////////////////
procedure TSkypeListEventHandler.vtSkypeChecking(Sender: TBaseVirtualTree;
  Node: PVirtualNode; var NewState: TCheckState; var Allowed: Boolean);
Var
  Level: Integer;
  I: Integer;
  Child: PVirtualNode;
begin
  // Allow the checking..
  Allowed := True;
  // Get the Level..
  Level := Sender.GetNodeLevel(Node);

  // If the level is 0 (Category Level)
  if Level = 0 then
  begin
    // And if the Node's Childcount is more than 0
    if Node.ChildCount > 0 then
    Begin
      // Get the first child..
      Child := Node.FirstChild;
      // Loop thru the children..
      for I := 0 to Node.ChildCount - 1 do
      begin
        // Set the checkstate, and go next..
        Child.CheckState := NewState;
        Child := Child.NextSibling;
      end;
    End;
  end;


  // If the level is 1 (User Level)
  if Level = 1 then
  begin
    // and if the Node's parent is not Nil..
    if Node.Parent <> nil then
    begin
      // aaand, if the new state is Unchecked...
      if (NewState = csUncheckedNormal) or (NewState = csUncheckedPressed) then
      begin
        // .. and if the node checkstate is checked..
        if NodeIsChecked(Node) then
        Begin
          // Set the PARENT node's checkstate to Unchecked!
          Node.Parent.CheckState := csUncheckedNormal;
        End;

      end;
      // BUT, if there is a DUPLICATE of the node, screw the above, and
      // forbid the checking!
      if HasDuplicateChecked(Node) <> nil then
        Allowed := False;

    end;
  end;

  // Uncheck all the duplicates.
  UncheckDuplicates;

  // Refresh the Tree
  Sender.Refresh;

end;

Answer 1

首先，OnChecking是要处理的错误事件。你想要OnChecked。 OnChecking真的只是问，“这个节点的检查状态是否允许改变？”它不意味着要关闭并检查其他节点。请使用OnChecked。

其次，您不需要处理类别节点的检查状态。打开toAutoTristateTracking选项，控件将自动调整所有相关子节点和父节点的状态。（更改父级，所有子级都更改。更改子级，父级更改为“不确定”。）

但是，您的代码似乎在正确的轨道上。当子节点发生更改时，您需要在树的其余部分中找到该节点的所有其他副本，并更改其检查状态以匹配刚更改的节点的新状态。执行该操作所花费的时间应该是树中节点数量的线性 - 节点数量的两倍，并且它应该花费大约两倍的时间来查找所有重复项。但即使有几千个节点，也应该在眨眼之间完成。如果需要更长时间，还有一些其他耗时的操作，你没有在这里显示。尝试使用分析器来发现瓶颈。

下面的代码遍历树中的所有节点。它暂时禁用OnChecked事件处理程序，否则，每次更改其中一个重复项的状态时，事件将再次运行。如果新检查状态与当前状态相同，则事件不会运行，因此不存在无限递归的危险，但禁用该事件会阻止它在树中执行大量冗余遍历。

procedure PropagateCheckState(Tree: TVirtualStringTree; Node: PVirtualNode);
var
  Data: PNodeData;
  TargetID: string;
  Parent: PVirtualNode;
  FoundOne: Boolean;
begin
  Data := Tree.GetNodeData(Node);
  TargetID := Data.SkypeID;

  Parent := Tree.GetFirst;
  while Assigned(Parent) do begin
    // Assume no user appears twice in the same category
    if Parent <> Tree.NodeParent[Node] then begin
      FoundOne := False;
      Child := Tree.GetFirstChild(Parent);
      while Assigned(Child) and not FoundOne do begin
        Data := Tree.GetNodeData(Child);
        if Data.SkypeID = TargetID then begin
          // Found a duplicate. Sync it with Node.
          Tree.CheckState[Child] := Tree.CheckState[Node];
          FoundOne := True;
        end;
        Child := Tree.GetNextSibling(Child);
      end;
    end;
    Parent := Tree.GetNextSibling(Parent);
  end;
end;

procedure TSkypeListEventHandler.vtSkypeChecked(Sender: TBaseVirtualTree; Node: PVirtualNode);
var
  CheckedEvent: TVTChangeEvent;
begin
  if Sender.GetNodeLevel(Node) = 0 then
    exit; // The tree cascades changes automatically

  Assert(Sender.GetNodeLevel(Node) = 1, 'Unexpected node level');
  // We'll be accessing members that are protected in TBaseVirtualTree, but
  // they're public in TVirtualStringTree, so make sure we're still operating
  // on the same tree.
  Assert(Sender = vtSkype);

  CheckedEvent := vtSkype.OnChecked;
  vtSkype.OnChecked := nil;
  try
    PropagateCheckState(vtSkype, Node);
  finally
    vtSkype.OnChecked := CheckedEvent;
  end;
end;

如果您的数据结构包含与给定用户ID关联的所有节点的列表，那么它将更加直截了当：

procedure PropagateCheckState(Tree: TVirtualStringTree; Node: PVirtualNode);
var
  Data: PNodeData;
  i: Integer;
begin
  Data := Tree.GetNodeData(Node);

  for i := 0 to Pred(Data.User.Nodes.Count) do
    Tree.CheckState[Data.User.Nodes[i]] := Tree.CheckState[Node];
end;

即使您继续将所有数据存储在树控件本身（您多次被告知这是一个坏主意），您仍然可以使用辅助数据结构充当索引用于树节点，键入用户ID。如果您有最新的Delphi版本，则可以使用TDictionary<string, TList<PVirtualNode>>。然后PropagateCheckState可能如下所示：

uses Generics.Collections;

var
  UserNodes: TDictionary<string, TList<PVirtualNode>>;

procedure PropagateCheckState(Tree: TVirtualStringTree; Node: PVirtualNode);
var
  Data: PNodeData;
  Nodes: TList<PVirtualNode>;
  i: Integer;
begin
  Data := Tree.GetNodeData(Node);

  if not UserNodes.TryGetValue(Data.SkypeID, Nodes) then
    exit; // Weird. The node's ID isn't in the index at all.

  for i := 0 to Pred(Nodes.Count) do
    Tree.CheckState[Nodes[i]] := Tree.CheckState[Node];
end;

确保在添加或删除类别中的用户时更新UserNodes索引。

Answer 2

为简单起见，我假设“Todd”包含在TreeView用于创建条目的类中。只要您的TreeView从该类请求它的信息，您就可以通过在类本身中添加布尔检查并使树视图无效来实现。当树重新绘制时，它将使用您的类来相应地设置复选框。

我知道VirtualTreeView足够快，可以在几秒钟内对数千个条目执行此操作。

Answer 3

对于所有节点上的遍历可能是有用的函数GetNext（PVirtualNode，bool childs）喜欢（C ++代码的借口）

TVirtualNode* parent=NULL;
TVirtualNode* node=VST->GetFirst();
 while (node)
    {
    data=static_cast<TreeItemData*>(VST->GetNodeData(node));
    //doo something with node, data
    node=VST->GetNext(node, true);
    }

如何使多个虚拟树视图节点的检查状态保持同步？

3 个答案: