Question

我正在使用XSLT 1.0将输入XML转换为所需的输出，但是这样做没有成功。XSlt代码应跳过带有“：”的标记。请在这里帮助我。

我有一个输入XML：-

<Request name="BXML">
    <first>10</first>
    <second>20</second>
    <third>:</third>
    <fourth>:::</fourth>
</Request>

我想要这样的输出XML：-

<Request name="BXML">
    <first>10</first>
    <second>20</second>
</Request>

Answer 1

要删除任何包含冒号的元素：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[contains(text(), ':')]"/>

</xsl:stylesheet>

要删除任何仅包含冒号的元素：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[not(translate(., ':', ''))]"/>

</xsl:stylesheet>

Answer 2

您可以使用translate来达到以下目的：

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="no" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*" />
    </xsl:copy>
</xsl:template>

<xsl:template match="Request">
    <Request>
        <xsl:apply-templates select="@*" />
        <xsl:for-each select="*">
            <xsl:if test="translate(., ':', '') != ''">
                <xsl:copy>
                    <xsl:apply-templates />
                </xsl:copy>
            </xsl:if>
        </xsl:for-each>
    </Request>
</xsl:template>

</xsl:stylesheet>

http://xsltfiddle.liberty-development.net/gWvjQfC

注意：translate函数用其他单个字符替换字符串中的单个字符。因此，在这种情况下，translate()将用'（空白）字符替换每个'：'（冒号）字符，并检查标记是否仍然包含文本或为空。基于此，它将填充标签。

如何使用XSLT在XML中跳过带有冒号（：）等字符的标签？

2 个答案: