Question

我需要在过程中的集合中向表中插入一些值，但出现ORA-00902: invalid datatype错误。

这是目标表：

create table t_test (col01 number, col02 number);

我在包中定义集合的类型和流水线函数：

create or replace package p_test is 
  type t_num is table of number;
  function rtn(arg_tn t_num) return t_num PIPELINED;
end p_test;
/
create or replace package body p_test is 
  function rtn(arg_tn t_num) return t_num PIPELINED is 
      tn_row number;
    begin 
      for i in arg_tn.first .. arg_tn.last loop
        tn_row := arg_tn(i);
        pipe row(tn_row);
      end loop;
      return;
  end;
end p_test;

这是我的PL / SQL过程：

declare
  tn_test p_test.t_num := p_test.t_num(10,20,30);
  n_num number := 69;
begin
  insert into T_TEST(col01, col02) select n_num, column_value from table(tn_test);
end;

结果表如下所示：

 col01 | col02
-------|-------
 69    | 10
 69    | 20
 69    | 30

这是我得到的错误：

我在做什么错？如何解决？我本可以在for周期中完成此操作，但是对于所需的目的来说效率不是很低吗？

Answer 1

我在做什么错？如何解决？我可以在一个循环，但对于所需的目的来说效率是否太低？

如果正确检查错误，则可以看到错误。错误提示：

SQL语句中不允许使用本地集合类型

在您的执行块中意味着什么：

插入T_TEST（col01，col02）从中选择n_num，column_value 表（tn_test）;

以上声明为NOT ALLOWED。

直到Oracle 11g，如果在块内使用的Type语句正下方的PLSQL块之前，您不能使用在范围内声明的SQL。您需要在Type范围之外更改PLSQL的声明范围。也就是说，您需要REMOVE

type t_num is table of number;（来自包装规范），并在TYPE范围之外创建SQL。

因此您可以这样做：

Create or replace type t_num is table of number;

请参见下面的演示

create table t_test (col01 number, col02 number);

-- Moving the type decalration under the scope of SQL.
Create or replace type t_num is table of number;

create or replace package p_test is
--  type t_num is table of number; --<-- Commenting the declaration since this is not allowed until 11g.
  function rtn(arg_tn t_num) 
    return t_num  PIPELINED;
end p_test;
/

create or replace package body p_test is
  function rtn(arg_tn t_num) 
    return t_num PIPELINED 
   is
    tn_row number;
  begin
    for i in arg_tn.first .. arg_tn.last
    loop
      tn_row := arg_tn(i);
      pipe row(tn_row);
    end loop;
    return;
  end;
end p_test;

执行：

declare
  tn_test t_num := t_num(10, 20, 30);
  n_num   number := 69;
begin
  insert into T_TEST
    (col01,
     col02)
    select n_num,
           column_value
    from   table(tn_test);
    commit;
end;

测试：

 SQL> Select * from T_TEST;

     COL01      COL02
---------- ----------
        69         10
        69         20
        69         30

Answer 2

本地定义的PL / SQL集合类型不能在非查询DML语句中使用（例如，作为表函数的参数）。只需将测试数据的初始化移至表函数即可。考虑以下示例：

create or replace package p_test is 
    type t_num is table of number;
    function rtn return t_num pipelined;
end p_test;
/
create or replace package body p_test is 
    function rtn return t_num pipelined is 
        tn_test t_num := t_num (10, 20, 30);
    begin 
        for i in 1..tn_test.count loop
            pipe row (tn_test (i));
        end loop;
        return;
    end;
end p_test;
/

begin
    insert into t_test (col01, col02) 
    select rownum, column_value from table (p_test.rtn ())
    ;
    dbms_output.put_line (sql%rowcount||' rows inserted.');  
end;
/
select * from t_test;     

3 rows inserted.

     COL01      COL02
---------- ----------
         1         10
         2         20
         3         30

如果必须使用集合类型的参数，请使用FORALL语句或@XING answer中建议的SQL数据类型。

按照问题中的说明演示软件包，

declare 
    sources p_test.t_num := p_test.t_num (10,20,30);
    targets p_test.t_num; 
    retrows p_test.t_num; 
    n_num number := 69;
begin
    select * bulk collect into targets
    from table (p_test.rtn (sources))
    ;
    forall i in indices of targets
    insert into t_test (col01, col02) values (n_num, targets (i)) 
    returning col01 bulk collect into retrows
    ;
    dbms_output.put_line (retrows.count||' rows inserted.'); 
end;
/

3 rows inserted.

select * from t_test;

     COL01      COL02
---------- ----------
        69         10
        69         20
        69         30

Answer 3

因为INSERT和col02中的column_value和number中的one-dimensional array语句存在类型不匹配。如果将迭代应用于该数组，则将为每个迭代步骤导出单个数字。可以通过使用cursor来对其进行管理：

declare
  tn_test p_test.t_num := p_test.t_num(10,20,30);
  n_num number := 69;
begin
  for c in ( select row_number() over (order by 0) rn, column_value from table(tn_test) t)
  loop
    insert into t_test(col01,col02) values(n_num, tn_test(c.rn));
  end loop;
end;

那样，您会得到

select * from t_test;

+------+------+
|col01 |col02 |
+------+------+
|  69  | 10   |
|  69  | 20   |
|  69  | 30   |
+------+------+

流水线函数不会返回有错误的表

3 个答案: