Question

我有一系列规则和一组初始（assert）事实。现在，我要添加这些事实，运行规则，然后应用另一组规则，以检查(run)之后的当前现有事实是否包含正确的事实，并且没有其他任何内容，而无需再触发以前的规则并且不破坏当前规则事实。然后，我要继续应用新事实，运行新规则并测试新插入的事实，等等。

我该怎么做？我的测试（批处理）文件类似于：

(clear) ; just in case
(load constructs.clp) ; All loaded in the MAIN module.

(assert (blabla))
(assert (blabla2))
(run)

;; Code (rules/functions... I'm still wondering how to do it) to check
;; current facts

(assert (blabla3))
(assert (blabla4))
(run)

;; More tests.

(exit)

我尝试为每个deftemplate T创建一个具有相同插槽的deftemplate T-copy，并且它们应用(assert (testing))事实来首先制作副本。然后，我出于测试目的和更高的显着性而触发了一组规则，这些规则会在完成(run)时“停止”执行，以避免触发先前的规则（我正在测试的规则）。除了需要太多步骤之外，这种方法的问题在于我不知道原始规则的重要性，因此我不确定测试规则将具有更高的优先级。

我知道defmodule的构造和焦点堆栈，但是我还不了解它们。如果我的猜测是正确的，我想我可以将所有测试规则放在一个特定的模块中，并将重点放在该模块上，以避免执行任何MAIN规则。如果有问题，我会(halt) 在其中一种测试规则中执行或仅(exit)个批处理脚本中执行。如果一切正确，我弹出测试模块以返回到MAIN，再次添加更多断言，(run)，然后他们使用新的测试再次推动测试模块以查看一切是否仍然正确。

但是我不确定我的假设是否正确，我想举一个例子，说明如何进行测试。

PD：另外，我的CLIPS版本不支持事实集查询。

Answer 1

一般的想法是将核心规则组与进行测试的规则分离到单独的模块中，然后使用 focus 命令执行测试规则。

CLIPS> (defmodule MAIN (export ?ALL))
CLIPS> (deftemplate MAIN::point (slot x) (slot y))
CLIPS> 
(defrule MAIN::r1
   =>
   (assert (point (x 1) (y 2)))
   (assert (point (x 1) (y 5))))
CLIPS> (defmodule TESTING (import MAIN ?ALL))
CLIPS> 
(defrule TESTING::horizontal
   (point (x ?x1) (y ?y))
   (point (x ?x2&:(< ?x2 ?x1)) (y ?y))
   =>
   (printout t "Horizonal issue " ?y crlf))
CLIPS> (reset)
CLIPS> (agenda)
0      r1: *
For a total of 1 activation.
CLIPS> (run)
CLIPS> (facts)
f-0     (initial-fact)
f-1     (point (x 1) (y 2))
f-2     (point (x 1) (y 5))
For a total of 3 facts.
CLIPS> (focus TESTING)
TRUE
CLIPS> (agenda)
CLIPS> (run)
CLIPS> 
(defrule MAIN::r2
   =>
   (assert (point (x 3) (y 2))))
CLIPS> (run)
CLIPS> (facts)
f-0     (initial-fact)
f-1     (point (x 1) (y 2))
f-2     (point (x 1) (y 5))
f-3     (point (x 3) (y 2))
For a total of 4 facts.
CLIPS> (focus TESTING)
TRUE
CLIPS> (run)
Horizonal issue 2
CLIPS> 
(defrule TESTING::vertical
   (point (x ?x) (y ?y1))
   (point (x ?x) (y ?y2&:(< ?y2 ?y1)))
   =>
   (printout t "Vertical issue " ?x crlf))
CLIPS> (focus TESTING)
TRUE
CLIPS> (agenda)
0      vertical: f-2,f-1
For a total of 1 activation.
CLIPS> (run)
Vertical issue 1
CLIPS>

片段：测试正确的事实

1 个答案: