Question

我有一组这样的数据

{
  "data": [
    {
      "target_group_id": "1234",
      "target_group_name": "abc",
      "targets": [
        {
          "target_id": "456",
          "target_name": "john"
        }
      ]
    },
    {
      "target_group_id": "56789",
      "target_group_name": "cdes",
      "targets": [
        {
          "target_id": "0987",
          "target_name": "john"
        }
      ]
    },
    {
      "target_group_id": "1234",
      "target_group_name": "abc",
      "targets": [
        {
          "target_id": "789",
          "target_name": "doe"
        }
      ]
    }
  ]
}

，并希望通过按目标组ID分组和合并数据进行转换，以便将同一target_group_id中的目标添加到现有目标组中，并将数据的关键根从“数据”更改为“ target_groups”

{
  "target_groups": [
    {
      "target_group_id": "1234",
      "target_group_name": "abc",
      "targets": [
        {
          "target_id": "456",
          "target_name": "john"
        },
        {
          "target_id": "789",
          "target_name": "doe"
        }
      ]
    },
    {
      "target_group_id": "56789",
      "target_group_name": "cdes",
      "targets": [
        {
          "target_id": "0987",
          "target_name": "john"
        }
      ]
    }
  ]
}

自从我的原始代码使用php并使用了大量的“ if子句”和“ foreach”以来，是否有任何有效的方法可以使用clojure？谢谢...

Answer 1

这是我的处理方式：

(ns tst.demo.core
  (:use demo.core tupelo.core tupelo.test)
  (:require
    [clojure.string :as str]
    [tupelo.string :as ts]
    [tupelo.core :as t]))

(def data-json
"{ 'data': [
    { 'target_group_id': '1234',
      'target_group_name': 'abc',
      'targets': [
        { 'target_id': '456',
          'target_name': 'john' }
      ]
    },
    { 'target_group_id': '56789',
      'target_group_name': 'cdes',
      'targets': [
        { 'target_id': '0987',
          'target_name': 'john'  }
      ]
    },
    {
      'target_group_id': '1234',
      'target_group_name': 'abc',
      'targets': [
        { 'target_id': '789',
          'target_name': 'doe'  }
      ]
    }
  ]
} " )

具有转换：

(dotest
  (let [data-edn (t/json->edn
                   (ts/quotes->double data-json))
        d2       (t/it-> data-edn
                   (:data it) ; unnest from :data key
                   (group-by :target_group_id it ) )
        d3       (t/forv [[tgt-id entries] d2]
                   {:tgt-group-id   tgt-id
                    :tgt-group-name (:target_group_name (first entries))
                    :targets-all    (mapv :targets entries)}) ]

和结果/测试：

    (is= data-edn
      {:data
       [{:target_group_id   "1234",
         :target_group_name "abc",
         :targets           [{:target_id "456", :target_name "john"}]}
        {:target_group_id   "56789",
         :target_group_name "cdes",
         :targets           [{:target_id "0987", :target_name "john"}]}
        {:target_group_id   "1234",
         :target_group_name "abc",
         :targets           [{:target_id "789", :target_name "doe"}]}]})

    (is= d2
      {"1234"
       [{:target_group_id   "1234",
         :target_group_name "abc",
         :targets           [{:target_id "456", :target_name "john"}]}
        {:target_group_id   "1234",
         :target_group_name "abc",
         :targets           [{:target_id "789", :target_name "doe"}]}],
       "56789"
       [{:target_group_id   "56789",
         :target_group_name "cdes",
         :targets           [{:target_id "0987", :target_name "john"}]}]})

    (is= d3
      [{:tgt-group-id   "1234",
        :tgt-group-name "abc",
        :targets-all    [[{:target_id "456", :target_name "john"}]
                         [{:target_id "789", :target_name "doe"}]]}
       {:tgt-group-id   "56789",
        :tgt-group-name "cdes",
        :targets-all    [[{:target_id "0987", :target_name "john"}]]}]) ))

Answer 2

仅使用核心clojure（与data.json库一起使用）。

首先，获取并解包我们的数据：

(def data (-> "grouping-and-merging.json"
              slurp
              clojure.data.json/read-str 
              (get "data")))

当我们处理目标组时，我们将需要将它们连接起来。我正在进行此内联，但是在reduce中看起来很杂乱，所以这里有一个辅助函数：

(defn concat-targets [acc item]
  (update acc "targets" concat (item "targets")))

那就让我们开始吧！

(def output (->> data
                 (group-by #(get % "target_group_id"))
                 vals
                 (map #(reduce concat-targets %))
                 (assoc {} "target_groups")
                 clojure.data.json/write-str))

我很幸运能够摆脱如此出色的线程宏工作，尽管您会注意到，我不得不在两个阶段之间从预线程切换为后线程。通常，我发现自己想要像Alan的答案中使用的Tupelo it->这样的东西。

我还感觉到减少是有点作弊-我假设不会有任何微妙之处，并且只要从第一项中获取任何额外的键就足够了。

Answer 3

进行转换的另一种方法：

{"target_groups" (map merge-vector (-> "data.json"
                                       slurp
                                       json/read-str
                                       (get "data")
                                       (set/index ["target_group_id" "target_group_name"])
                                       vals))}

;; =>
{"target_groups"
 ({"target_group_id" "1234",
   "target_group_name" "abc",
   "targets"
   ({"target_id" "789", "target_name" "doe"}
    {"target_id" "456", "target_name" "john"})}
  {"target_group_id" "56789",
   "target_group_name" "cdes",
   "targets" [{"target_id" "0987", "target_name" "john"}]})}

中间数据结构是set的序列，该序列由组ID和组名索引（例如使用group-by）。即

(-> "data.json"
    slurp
    json/read-str
    (get "data")
    (set/index ["target_group_id" "target_group_name"])
    vals)

;; =>
(#{{"target_group_id" "1234",
    "target_group_name" "abc",
    "targets" [{"target_id" "789", "target_name" "doe"}]}
   {"target_group_id" "1234",
    "target_group_name" "abc",
    "targets" [{"target_id" "456", "target_name" "john"}]}}
 #{{"target_group_id" "56789",
    "target_group_name" "cdes",
    "targets" [{"target_id" "0987", "target_name" "john"}]}})

然后将targets（即vector）与concat一起merge-vector：

(def merge-vector
  (partial apply
           merge-with
           (fn [& xs] (if (every? vector? xs) (apply concat xs) (last xs)))))

使用Clojure按值分组和合并？

3 个答案: