Question

如何洗牌矩阵的内容并将其保存为矩阵？随机播放功能适用于列表，但不适用于矩阵

show shuffle [1 2 3 4 5]
1 2 3 5 4

set m matrix:from-row-list
  [[1 2 3 4 5]]

show shuffle m

SHUFFLE预期输入为列表，但得到了 org.nlogo.extensions.matrix.MatrixExtension $ LogoMatrix {{matrix：[[ 1 2 3 4 5]]}}代替。

Answer 1

也许有一种更简单的方法，但是您可以跳到列表，随机播放，然后根据原始矩阵的尺寸返回到矩阵。

extensions [ matrix ]

to setup
  ca
  let m matrix:from-row-list [ [ 1 2 3 ] [ 4 5 6 ] [ 7 8 9 ] ]
  let sm shuffled-matrix m
  print matrix:pretty-print-text sm
  reset-ticks
end

; Reporter returns a shuffled matrix
to-report shuffled-matrix [ mat ]
  ; Get the number of columns
  let cols last matrix:dimensions mat

  ; Shuffle the matrix values as a list
  let shuf-vals shuffle reduce sentence matrix:to-row-list mat 

  ; Use the shuffled values to generate a new matrix
  ; with the same dimensions as the original
  report matrix:from-row-list ( subsetter shuf-vals cols )
end

; Reporter returns a list cut into sublists 
; based on the len value passed
to-report subsetter [ ls len ]
  ; Generate subsetting indices for the sublists
  let vals ( range 0 ( length ls ) len )

  ; Make subsets of ls based on the subsetting indices
  report map [ i -> sublist ls i ( i + len ) ] vals
end

setup的一些示例输出：

[[ 1  6  7 ]
 [ 9  5  8 ]
 [ 3  4  2 ]]

[[ 4  6  8 ]
 [ 1  9  2 ]
 [ 7  5  3 ]]

[[ 2  9  4 ]
 [ 6  3  8 ]
 [ 5  1  7 ]]

如何在NetLogo中调整矩阵的顺序？

1 个答案: