Question

我正在玩Haskell的Data和Typeable，而我一直在试图获取函数的参数而上下文中没有类型变量。

让我澄清一下我的意思。只要我对类型变量a进行了如下量化，就可以使用fromConstr并根据需要获取DataType或TypeRep的列表：

constrArgs :: forall a. Data a => Constr -> [DataType]
constrArgs c = gmapQ f (fromConstr c :: a)
  where f :: forall d. Data d => d -> DataType
        f _ = dataTypeOf @d undefined

（我意识到undefined和fromConstr并不合计，但懒惰在这里节省了我们的时间。）

但是，如果我尝试避免对a进行量化，则无法再对fromConstr的结果进行类型归因。我想知道是否可以使用以下类型签名来编写函数：

constrArgs' :: Constr -> [DataType]

我的最终目标是编写一个函数，该函数给出DataType列表的列表，每个构造函数的子列表，每个子列表包含该构造函数的参数类型。使用第一个版本，编写带有类型签名的函数并不难：（取消定义）

allConstrArgs :: forall a. Data a => [[DataType]]

问题是我无法将allConstrArgs应用于自身的结果，因为没有办法将DataType转换为类型级别的值。

因此，为了对此进行修改，我们可以编写具有以下类型的函数吗？

allConstrsArgs' :: DataType -> [[DataType]]

我在基本库中环顾四周，但是看不到如何实现。

Answer 1

您无法从Constr中获取参数类型的列表，因为其中没有足够的数据：这是一串字符串，仅此而已。

但是，有一种方法可以实现更大的目标：您只需要随身携带Data字典，还有什么比现有类型更好的方法！

data D = forall a. Data a => D a

allConstrArgs :: D -> [[D]]
allConstrArgs d = constrArgs d <$> allConstrs d

constrArgs :: D -> Constr -> [D]
constrArgs (D a) c = gmapQ D $ mkConstr a c
    where
        mkConstr :: forall a. Data a => a -> Constr -> a
        mkConstr _ = fromConstr

allConstrs :: D -> [Constr]
allConstrs (D a) = case dataTypeRep $ dataTypeOf a of
    AlgRep constrs -> constrs
    _ -> []

mkD :: forall a. Data a => D
mkD = D (undefined :: a)

这里，类型D仅用于包装Data字典-实际值a将始终为undefined，并且从未进行实际求值，所以很好。因此，值D用作类型的值级别表示，以便在解构时在范围内获得该类型的Data实例。

函数constrArgs采用类型表示形式D和构造函数Constr，并返回该构造函数的参数列表，每个参数也表示为D-现在您可以将其输出反馈回其输入！它通过使用gmapQ来做到这一点，它的第一个参数类型完全适合D构造函数。

mkD只是一个实用程序功能，旨在隐藏undefined的不愉快之处并与TypeApplications一起使用，例如mkD @Int。

这是用法：

data X = X0 Int | X1 String deriving (Typeable, Data)
data Y = Y0 String | Y1 Bool | Y2 Char deriving (Typeable, Data)
data Z = ZX X | ZY Y deriving (Typeable, Data)

typName :: D -> String
typName (D a) = dataTypeName $ dataTypeOf a

main = do
    -- Will print [["Prelude.Int"],["Prelude.[]"]]
    print $ map typName <$> allConstrArgs (mkD @X)

    -- Will print [["Prelude.[]"],["Bool"],["Prelude.Char"]]
    print $ map typName <$> allConstrArgs (mkD @Y)

    -- Will print [["X"],["Y"]]
    print $ map typName <$> allConstrArgs (mkD @Z)

请注意，您将需要以下扩展才能正常工作：ScopedTypeVariables, DeriveDataTypeable, GADTs, AllowAmbiguousTypes, TypeApplications

使用Data和Typeable获取构造函数的参数类型

1 个答案: