根据模式匹配突出显示整行

Question

如果屏幕上存在匹配项，我试图进入vim或nvim突出显示整个gui行。

我不知道如何着手解决这个问题或寻找什么。

我可以根据模式匹配使vim达到最高水平，但是我希望它像上面显示的那样在屏幕底部（黑色）突出显示整个gui宽度。

我该如何实现？

Answer 1

据我所知，除sign功能外，无法突出显示整行。以下示例使用@/寄存器值查找最后搜索的行，并将在其上显示Search高亮。

function! s:ToggleHighlightSearchLines()
    if !exists('s:id')
        let s:id = localtime()
        let lc = [line('.'), col('.')]
        call cursor([1, 1])
        let s:sc = &signcolumn
        let &signcolumn = 'no'
        sign define hlsLines linehl=Search
        let s:sp = 0
        while 1
            let ln = search(@/, 'W')
            if ln == 0 | break | endif
            execute 'sign place ' . s:id . ' line=' . ln . ' name=hlsLines'
            let s:sp += 1
        endwhile
        call cursor(lc)
    else
        while 0 < s:sp
            execute 'sign unplace ' . s:id
            let s:sp -= 1
        endwhile
        sign undefine hlsLines
        let &signcolumn = s:sc
        unlet s:id s:sp s:sc
    endif
endfunction
command! ToggleHLSLines call s:ToggleHighlightSearchLines()