Question

我正在编写一个简单的函数来从堆栈中打印浮点值。此函数已生成，因此未优化。程序在printf调用时崩溃。

;input: float32 as dword ptr ebp+8
printfloat32:
 push   ebp
  mov   ebp,    esp
  sub   esp,    16
;local ptr variable k at dword ptr ebp-4
  mov   dword ptr ebp-4,    lpcstr4 ;which is "%f"

movss       xmm0,           dword ptr ebp+8
cvtss2sd    xmm0,           xmm0
  sub       esp,            8
movsd       qword ptr esp,  xmm0
 push       dword ptr ebp-4
 call       printstr
  add       esp,            12

  mov   esp,    ebp
  pop   ebp
  ret

printstr是printf。这是完整的生成代码：https://pastebin.com/g0Wff0JY

Answer 1

看图片，我发现可能是一个潜在的问题，但我不知道fasm语法：

        call    [printstr]     ;syntax used for the first call
        ...
        call    printstr       ;syntax used for the second call that fails

如果printstr是该函数的基于内存的指针，则第二个调用语法可能正在尝试调用该指针的存储位置，而不是通过使用内存中的值作为函数的指针来调用实际函数

对于最新版本的Visual Studio，默认的printf和scanf有效地内联到C / C ++代码中，语法相当复杂。除了解决这个问题，还有一些可调用的旧版本需要以下includelib语句：

        includelib      legacy_stdio_definitions.lib    ;for scanf, printf, ...

我将代码从问题转换为masm语法，将printstr更改为printf，并在Windows 7 Pro 64位上使用Visual Studio 2015测试了32位版本（该版本为32位，因此已在32位模式下运行）。我没有与此代码的任何问题。我使用调试器逐步检查了代码，没有发现任何有关如何将内容存储在堆栈中的问题。我怀疑问题出在第二次调用printstr而不带括号的问题，我已将其更正为转换为masm语法的一部分。

        .data
varf    real4   123.75
lpcstr4 db      "%f",00ah,0             ;added new line
        .code
        extern  printf:near             ;instead of printstr

printfloat32 proc
        push    ebp
        mov     ebp,esp
        sub     esp,16
        mov     dword ptr [ebp-4], offset lpcstr4
        movss   xmm0,dword ptr [ebp+8]
        cvtss2sd xmm0,xmm0
        sub     esp,8
        movsd   qword ptr [esp],xmm0
        push    dword ptr [ebp-4]
        call    printf                  ;was printstr
        add     esp,12
        mov     esp,ebp
        pop     ebp
        ret
printfloat32 endp

main    proc
        push    varf            ;test printfloat32 function
        call    printfloat32
        add     esp,4
        xor     eax,eax
        ret
main    endp
        end

使用printstr作为指向printf的指针。 Masm不需要括号，因为它知道printstr是dd（指向printf的指针）。

        .code
        extern  printf:near
printstr dd     printf          ;masm doesn't need brackets

printfloat32 proc
;       ...
        call    printstr        ;masm doesn't need brackets
;       ...
printfloat32 endp

如果printstr在此源文件外部，则masm语法为

        extrn   printstr:ptr    ; or extern   printstr:dword

调用printf后汇编程序崩溃

1 个答案: