Question

我试图定义默认的方法实现，但前提是该类的类型变量派生某些其他类。

我尝试使用=>创建类型相关的实例（我是否正确使用了它？），但出现“重复实例声明错误”：（https://repl.it/@solly_ucko/Distributions）

{-# LANGUAGE FlexibleInstances, FunctionalDependencies, MultiParamTypeClasses, InstanceSigs #-}

import Data.Int
import Data.Ratio
import Data.Set
import System.Random

duplicate :: a -> (a, a)
duplicate a = (a, a)

listRange :: Enum a => a -> a -> [a]
listRange a b = [a..b]

class Fractional w => Distribution d v w where
    probability :: d v w -> v -> w

    probabilityOfRange :: Ord v => d v w -> v -> v -> w

    ranges :: (Ord v) => d v w -> Set (v, v)
    ranges = (Data.Set.map duplicate) . values

    sample :: RandomGen g => d v w -> g -> (v, g)
    --sample d g = (scanl1 (+) $ flip Prelude.map $ probability d, g) -- Will need to implement some sort of binary tree, most likely.

    sampleIO :: d v w -> IO v
    sampleIO = getStdRandom . sample

    values :: d v w -> Set v

instance (Ord v, Fractional w) => Distribution d v w where
    probability d v = probabilityOfRange d v v

instance Enum v => Distribution d v w where
    probabilityOfRange d v1 v2 = sum $ Prelude.map (probability d) [v1..v2]

instance (Enum v, Ord v) => Distribution d v w where
    values = fromList . (concatMap $ uncurry listRange) . toList . ranges

然后我尝试添加真实实例（并注释掉我先前创建的一些“实例”，以便编译器可以达到该点）时，它给我一个关于实例冲突的错误。

data Empty v w = Empty

instance Distribution Empty v (Ratio Int8) where
    sample _ g = (undefined, g)
    sampleIO _ = return undefined
    probabilityOfRange _ _ _ = 0
    values _ = empty

data Singleton v w = Singleton v

instance Distribution Singleton v Integer where
    sample (Singleton v) g = (v, g)
    sampleIO (Singleton v) = return v
    probabilityOfRange (Singleton v1) v2 v3
        | v2 <= v1 && v1 <= v3 = 1
        | otherwise        = 0

data Uniform v w = Uniform (Set v)

为了澄清，我的目标是为所有probability定义values和Distributions，并为所有probabilityOfRange定义Distributions衍生自Ord的值。我还希望在遇到其他约束时提供默认值，因为没有它们，就不可能有合理的默认值（基于其他方法）。

Answer 1

尝试使用以下方法为单个方法指定默认值：

instance (Ord v, Fractional w) => Distribution d v w where
    probability d v = probabilityOfRange d v v

不起作用。 Haskell实例不会“累积”。对于给定的三类d v w，最多将应用一个instance Distribution d v w子句。（如果由于“重叠”实例而可能应用多个子句，则存在选择“最佳”匹配项的机制，但是没有直接的机制来组合多个实例子句中的方法。）

通常，如果您有类方法：

class Distribution d v w where
    probability :: d v w -> v w

，而您想定义一个具有更严格类型签名的默认方法（即，对某些类型有约束）：

probability :: (Ord v) => d v w -> v -> w
probability d v = probabilityOfRange d v v

有两种方法。

第一个是利用DefaultSignatures扩展名。这使您可以将方法的类型签名与 default 方法的（可能更具限制性的）类型签名分开。语法为：

class Fractional w => Distribution d v w where
    probability :: d v w -> v -> w
    default probability :: (Ord v) => d v w -> v -> w
    probability d v = probabilityOfRange d v v
    ...

这里的警告是，如果定义的实例不覆盖默认方法，则它必须满足约束Ord v，否则就不会进行类型检查。 / p>

如果您想更多地控制使用默认方法的时间，那么通常的方法是将默认定义分离为一个单独的函数，该函数必须明确地包含在希望使用它的实例中。因此，您将拥有：

class Fractional w => Distribution d v w where
    probability :: d v w -> v -> w

probabilityDefault :: (Distribution d v w, Ord v) => d v w -> v -> w
probabilityDefault d v = probabilityOfRange d v v

并且希望使用默认值的实例必须明确地这样做：

instance Distribution Whatever Int w where
    probability = probabilityDefault

Haskell中依赖于类型变量的默认方法实现

1 个答案: