Question

我正在实现一个多进程库，该库为共享内存提供数据结构。但是我现在遇到了麻烦，我在子进程中修改了共享的Hash对象，但父进程仍未读取更改后的值。

示例代码：https://play.crystal-lang.org/#/r/6n34

用相同的指针修改，为什么无效？

Answer 1

在派生一个进程时，将在保留相同虚拟内存地址的同时复制其内存。

您只是将一个指针放在共享内存部分中，因此派生之前的内存布局是：

 +--------------------+    +--------------------+
 |    Shared memory   |    |     Parent heap    |
 |                    |    |                    |
 |                    |    |                    |
 |  Virtual address   |    |  +---------+       |
 |        of  --------------> | Hash    |       |
 |                    |    |  +---------+       |
 |                    |    |                    |
 +--------------------+    +--------------------+

在派生之后，指针分别指向每个进程的私有内存：

 +--------------------+    +--------------------+
 |    Shared memory   |    |     Parent heap    |
 |                    |    |                    |
 |                    |    |                    |
 |  Virtual address   |    |  +---------+       |
 |        of  --------------> | Hash    |       |
 |                 |  |    |  +---------+       |
 |                 |  |    |                    |
 +--------------------+    +--------------------+
                   |
                   |
                   |       +--------------------+
                   |       |     Child heap    |
                   |       |                    |
                   |       |                    |
                   |       |  +---------+       |
                   +--------> | Hash    |       |
                           |  +---------+       |
                           |                    |
                           +--------------------+

因此，当取消引用子代中的指针时，您仅在子代堆中触摸对象。

您要做的是将所有实际数据放入共享内存中。对于标准的Crystal数据类型，这样做很棘手，因为它们依赖于能够请求新内存并由垃圾收集器对其进行管理。因此，您需要实现一个可以在共享内存上工作的GC。

但是，如果您只有固定数量的数据（例如几个数字或固定大小的字符串），则可以利用Crystal的值类型使事情变得更好：

module SharedMemory
  def self.create(type : T.class, size : Int32) forall T
    protection = LibC::PROT_READ | LibC::PROT_WRITE
    visibility = LibC::MAP_ANONYMOUS | LibC::MAP_SHARED
    ptr = LibC.mmap(nil, size * sizeof(T), protection, visibility, 0, 0).as(T*)
    Slice(T).new(ptr, size)
  end
end

record Data, point : Int32 do
  setter point
end

shared_data = SharedMemory.create(Data, 1)
shared_data[0] = Data.new 23

child = Process.fork
if child
  puts "Parent read: '#{shared_data[0].point}'"
  child.wait
  puts "Parent read: '#{shared_data[0].point}'"
else
  puts "Child read: '#{shared_data[0].point}'"
  # Slice#[] returns the object rather than a pointer to it, 
  # so given Data is a value type, it's copied to the local 
  # stack and the update wouldn't be visible in the shared memory section.
  # Therefore we need to get the pointer using Slice#to_unsafe 
  # and dereference it manually with Pointer#value
  shared_data.to_unsafe.value.point = 42
  puts "Child changed to: '#{shared_data[0].point}'"
end

Parent read: '23'
Child read: '23'
Child changed to: '42'
Parent read: '42'

https://play.crystal-lang.org/#/r/6nfn

这里的缺点是，您不能将任何Reference或String之类的Hash类型放入结构中，因为它们又只是每个进程的私有地址空间的指针。 Crystal提供了类型和API，以使共享（例如，Slice和String#to_slice等字符串更容易些，但是每次传递时都必须在共享内存之间进行复制）或分别将其转换回去，您必须事先知道（最大）字符串长度。

我无法使用mmap在进程之间共享哈希

1 个答案: