如何修复错误的Blinn-Phong照明

Question

我正在尝试为Vulkan着色器中的单个光源实现Blinn-Phong着色，但是我得到的结果不是我期望的。

输出如下所示：

灯光位置应在相机右侧的后面，该位置正确地显示在头上，而不是圆圈上。我不希望圆圈中间有高强度的点。

灯光位置位于坐标（10、10、10）。

圆圈中心的高强度点是（0,0,0）。

顶点着色器：

#version 450
#extension GL_ARB_separate_shader_objects : enable

layout(binding = 0) uniform MVP {
    mat4 model;
    mat4 view;
    mat4 proj;
} mvp;

layout(location = 0) in vec3 inPosition;
layout(location = 1) in vec3 inColor;
layout(location = 2) in vec2 inTexCoord;
layout(location = 3) in vec3 inNormal;

layout(location = 0) out vec3 fragColor;
layout(location = 1) out vec2 fragTexCoord;
layout(location = 2) out vec3 Normal;
layout(location = 3) out vec3 FragPos;
layout(location = 4) out vec3 viewPos;

void main() {
    gl_Position = mvp.proj * mvp.view * mvp.model * vec4(inPosition, 1.0);
    fragColor = inColor;
    fragTexCoord = inTexCoord;
    Normal = inNormal;
    FragPos = inPosition;
    viewPos = vec3(mvp.view[3][0], mvp.view[3][1], mvp.view[3][2]);
}

片段着色器：

#version 450
#extension GL_ARB_separate_shader_objects : enable

layout(binding = 1) uniform sampler2D texSampler;
layout(binding = 2) uniform LightUBO{
    vec3 position;
    vec3 color;
} Light;

layout(location = 0) in vec3 fragColor;
layout(location = 1) in vec2 fragTexCoord;
layout(location = 2) in vec3 Normal;
layout(location = 3) in vec3 FragPos;
layout(location = 4) in vec3 viewPos;

layout(location = 0) out vec4 outColor;

void main() {
    vec3 color = texture(texSampler, fragTexCoord).rgb;
    // ambient
    vec3 ambient = 0.2 * color;

    // diffuse
    vec3 lightDir = normalize(Light.lightPos - FragPos);
    vec3 normal = normalize(Normal);
    float diff = max(dot(lightDir, normal), 0.0);
    vec3 diffuse = diff * color;

    // specular
    vec3 viewDir = normalize(viewPos - FragPos);
    vec3 reflectDir = reflect(-lightDir, normal);
    float spec = 0.0;
    vec3 halfwayDir = normalize(lightDir + viewDir);  
    spec = pow(max(dot(normal, halfwayDir), 0.0), 32.0);

    vec3 specular = vec3(0.25) * spec;
    outColor = vec4(ambient + diffuse + specular, 1.0);
}

注意： 我正在尝试将this教程中的着色器实现到Vulkan。

Answer 1

这似乎只是使用正确的坐标系的问题。由于您的问题中缺少一些重要信息，因此我必须做一些假设。首先，基于您拥有一个模型矩阵并且场景中显然有多个对象这一事实，我将假设您的世界空间和对象空间通常并不相同。此外，我将假设您的model矩阵从对象空间转换为世界空间，您的view矩阵从世界空间转换为视图空间，而您的proj矩阵从视图空间转换为剪辑空间。我还将假设您的inPosition和inNormal属性在对象空间坐标中。

基于所有这些，您的viewPos仅占据视图矩阵的最后一列，该列将不包含相机在世界空间中的位置。最后一行也不会。视图矩阵从世界空间转换为视图空间。从相机的角度看，它的最后一列对应于指向世界空间起源的向量。您的FragPos和Normal将位于对象空间中。而且，根据您在问题中所说的，您的照明位置位于世界空间中。因此，最后，您只是将所有相对于完全不同的坐标系的坐标混合在一起。例如：

vec3 lightDir = normalize(Light.lightPos - FragPos);

在这里，您要从世界空间位置减去对象空间位置，这将产生完全无意义的结果。然后将此无意义的结果归一化并用对象空间方向标出点

float diff = max(dot(lightDir, normal), 0.0);

而且，即使viewPos是世界相机的位置，也是如此

vec3 viewDir = normalize(viewPos - FragPos);

由于FragPos是在对象空间坐标中给出的，因此仍然没有意义。

只有在所有涉及的向量都相对于同一坐标系时，坐标向量上的操作才有意义。选择哪个坐标系并不重要。但是您必须选择一个。确保所有向量实际上都相对于该坐标系，例如世界空间。如果某些矢量尚未恰好位于该坐标系中，则必须将其转换为该坐标系。只有所有向量都在同一坐标系中，阴影计算才有意义...

要获取viewPos，您可以获取逆视图矩阵的最后一列（如果由于某种原因碰巧已经在某个位置放置了该列），或者只是将相机位置作为附加制服传递。另外，不要将模型视图和投影矩阵一次又一次地相乘，而应考虑将组合的模型视图-投影矩阵传递给着色器……

除此之外：请注意，如果表面实际上是朝向光的，您很可能只希望具有镜面反射分量。